git.gag.com Git - debian/tar/blob - m4/readlink.m4

   1 # readlink.m4 serial 9
   2 dnl Copyright (C) 2003, 2007, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_READLINK],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_CHECK_FUNCS_ONCE([readlink])
  11   if test $ac_cv_func_readlink = no; then
  12     HAVE_READLINK=0
  13     AC_LIBOBJ([readlink])
  14     gl_PREREQ_READLINK
  15   else
  16     AC_CACHE_CHECK([whether readlink signature is correct],
  17       [gl_cv_decl_readlink_works],
  18       [AC_COMPILE_IFELSE(
  19          [AC_LANG_PROGRAM(
  20            [[#include <unistd.h>
  21       /* Cause compilation failure if original declaration has wrong type.  */
  22       ssize_t readlink (const char *, char *, size_t);]])],
  23          [gl_cv_decl_readlink_works=yes], [gl_cv_decl_readlink_works=no])])
  24     dnl Solaris 9 ignores trailing slash.
  25     dnl FreeBSD 7.2 dereferences only one level of links with trailing slash.
  26     AC_CACHE_CHECK([whether readlink handles trailing slash correctly],
  27       [gl_cv_func_readlink_works],
  28       [# We have readlink, so assume ln -s works.
  29        ln -s conftest.no-such conftest.link
  30        ln -s conftest.link conftest.lnk2
  31        AC_RUN_IFELSE(
  32          [AC_LANG_PROGRAM(
  33            [[#include <unistd.h>
  34 ]], [[char buf[20];
  35       return readlink ("conftest.lnk2/", buf, sizeof buf) != -1;]])],
  36          [gl_cv_func_readlink_works=yes], [gl_cv_func_readlink_works=no],
  37          [gl_cv_func_readlink_works="guessing no"])
  38       rm -f conftest.link conftest.lnk2])
  39     if test "$gl_cv_func_readlink_works" != yes; then
  40       AC_DEFINE([READLINK_TRAILING_SLASH_BUG], [1], [Define to 1 if readlink
  41         fails to recognize a trailing slash.])
  42       REPLACE_READLINK=1
  43       AC_LIBOBJ([readlink])
  44     elif test "$gl_cv_decl_readlink_works" != yes; then
  45       REPLACE_READLINK=1
  46       AC_LIBOBJ([readlink])
  47     fi
  48   fi
  49 ])
  50
  51 # Like gl_FUNC_READLINK, except prepare for separate compilation (no AC_LIBOBJ).
  52 AC_DEFUN([gl_FUNC_READLINK_SEPARATE],
  53 [
  54   AC_CHECK_FUNCS_ONCE([readlink])
  55   gl_PREREQ_READLINK
  56 ])
  57
  58 # Prerequisites of lib/readlink.c.
  59 AC_DEFUN([gl_PREREQ_READLINK],
  60 [
  61   :
  62 ])