git.gag.com Git - debian/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   5 # Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21
  22 AC_INIT([GNU tar], [1.26.90], [bug-tar@gnu.org])
  23 AC_CONFIG_SRCDIR([src/tar.c])
  24 AC_CONFIG_AUX_DIR([build-aux])
  25 AC_CONFIG_HEADERS([config.h])
  26 AC_PREREQ([2.63])
  27 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz dist-shar std-options silent-rules])
  28
  29 # Enable silent rules by default:
  30 AM_SILENT_RULES([yes])
  31
  32 AC_PROG_CC
  33 AC_EXEEXT
  34 AC_PROG_RANLIB
  35 AC_PROG_YACC
  36 gl_EARLY
  37
  38 AC_SYS_LARGEFILE
  39 AC_ISC_POSIX
  40 AC_C_INLINE
  41
  42 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  43   sgtty.h string.h \
  44   sys/param.h sys/device.h sys/gentape.h \
  45   sys/inet.h sys/io/trioctl.h \
  46   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  47   unistd.h locale.h)
  48
  49 AC_CHECK_HEADERS([sys/buf.h], [], [],
  50 [#if HAVE_SYS_PARAM_H
  51 #include <sys/param.h>
  52 #endif])
  53
  54 AC_HEADER_SYS_WAIT
  55
  56 AC_HEADER_DIRENT
  57 AC_HEADER_MAJOR
  58 AC_HEADER_STAT
  59 AC_HEADER_STDC
  60
  61 AC_MSG_CHECKING([for st_fstype string in struct stat])
  62 AC_CACHE_VAL(diff_cv_st_fstype_string,
  63   [AC_TRY_COMPILE([#include <sys/types.h>
  64 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  65    diff_cv_st_fstype_string=yes,
  66    diff_cv_st_fstype_string=no)])
  67 AC_MSG_RESULT($diff_cv_st_fstype_string)
  68 if test $diff_cv_st_fstype_string = yes; then
  69   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  70     [Define if struct stat has a char st_fstype[] member.])
  71 fi
  72
  73 AC_TYPE_SIGNAL
  74 AC_TYPE_MODE_T
  75 AC_TYPE_PID_T
  76 AC_TYPE_OFF_T
  77 AC_TYPE_SIZE_T
  78 AC_TYPE_UID_T
  79 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  80                                    [Type of major device numbers.]))
  81 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  82                                    [Type of minor device numbers.]))
  83 AC_CHECK_TYPE(dev_t, unsigned)
  84 AC_CHECK_TYPE(ino_t, unsigned)
  85
  86 gt_TYPE_SSIZE_T
  87
  88 # gnulib modules
  89 gl_INIT
  90 # paxutils modules
  91 tar_PAXUTILS
  92
  93 TAR_HEADERS_ATTR_XATTR_H
  94
  95 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
  96 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
  97 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
  98 AC_CHECK_DECLS([time],,, [#include <time.h>])
  99
 100 AC_REPLACE_FUNCS(waitpid)
 101
 102 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 103   [if test -n "$RSH"; then
 104     tar_cv_path_RSH=$RSH
 105   else
 106     tar_cv_path_RSH=no
 107     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 108         /usr/bin/nsh /usr/bin/rcmd
 109     do
 110       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 111       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 112       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 113       if test -f $ac_file; then
 114         if (test -h $ac_file) 2>/dev/null; then
 115           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 116         else
 117           tar_cv_path_RSH=$ac_file
 118           break
 119         fi
 120       fi
 121     done
 122   fi])
 123 if test $tar_cv_path_RSH = no; then
 124   AC_CHECK_HEADERS(netdb.h)
 125 else
 126   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 127     [Define to the full path of your rsh, if any.])
 128 fi
 129
 130 TAR_COMPR_PROGRAM(compress)
 131 TAR_COMPR_PROGRAM(gzip)
 132 TAR_COMPR_PROGRAM(bzip2)
 133 TAR_COMPR_PROGRAM(lzip)
 134 TAR_COMPR_PROGRAM(lzma)
 135 TAR_COMPR_PROGRAM(lzop)
 136 TAR_COMPR_PROGRAM(xz)
 137
 138 AC_MSG_CHECKING(for default archive format)
 139
 140 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 141            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 142
 143 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 144   DEFAULT_ARCHIVE_FORMAT="GNU"
 145 fi
 146 case $DEFAULT_ARCHIVE_FORMAT in
 147   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 148   *) AC_MSG_ERROR(Invalid format name);;
 149 esac
 150 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 151   [By default produce archives of this format])
 152 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 153
 154 AC_MSG_CHECKING(for default archive)
 155
 156 AC_ARG_VAR([DEFAULT_ARCHIVE],
 157            [Set the name of the default archive (default: -)])
 158 if test -z "$DEFAULT_ARCHIVE"; then
 159   DEFAULT_ARCHIVE=-
 160 else
 161   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 162     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 163   fi
 164   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 165   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 166   # FIXME: Rearrange, here.
 167   case $DEFAULT_ARCHIVE in
 168     *[[0-7][lmh]])
 169       AC_DEFINE(DENSITY_LETTER, 1,
 170         [Define to 1 if density may be indicated by [lmh] at end of device.])
 171       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 172       ;;
 173     *[[0-7]])
 174       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 175       ;;
 176     *)
 177       device_prefix=
 178       ;;
 179   esac
 180   case "$device_prefix" in
 181     ?*)
 182       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 183         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 184       ;;
 185   esac
 186 fi
 187 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 188   [Define to a string giving the full name of the default archive file.])
 189 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 190
 191 AC_ARG_VAR([DEFAULT_BLOCKING],
 192            [Define default blocking factor (default: 20)])
 193 AC_MSG_CHECKING(for default blocking)
 194 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 195 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 196   [Define to a number giving the default blocking size for archives.])
 197 AC_MSG_RESULT($DEFAULT_BLOCKING)
 198
 199 AC_MSG_CHECKING(for default quoting style)
 200
 201 m4_define([QUOTING_STYLES],dnl
 202           [literal|shell|shell-always|c|escape|locale|clocale])
 203 DEFAULT_QUOTING_STYLE="escape"
 204 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 205            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 206
 207 case $DEFAULT_QUOTING_STYLE in
 208 QUOTING_STYLES) ;;
 209 *)  AC_MSG_ERROR(Invalid quoting style);;
 210 esac
 211 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 212 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 213 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 214   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 215
 216 # Iconv
 217 AM_ICONV
 218 AC_CHECK_HEADERS(iconv.h)
 219 AC_CHECK_TYPE(iconv_t,:,
 220               AC_DEFINE(iconv_t, int,
 221                         [Conversion descriptor type]),
 222               [
 223 #ifdef HAVE_ICONV_H
 224 # include <iconv.h>
 225 #endif
 226 ])
 227
 228 # Gettext.
 229 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 230 AM_GNU_GETTEXT_VERSION([0.16])
 231
 232 # Initialize the test suite.
 233 AC_CONFIG_TESTDIR(tests)
 234 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 235 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 236
 237 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 238 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 239 AC_ARG_ENABLE(backup-scripts,
 240               AC_HELP_STRING([--enable-backup-scripts],
 241                              [Create and install backup and restore scripts]),
 242               [case $enableval in
 243                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 244                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 245                     ;;
 246                esac])
 247
 248 AC_SUBST(BACKUP_SED_COND)
 249 if date +%Y-%m-%d 2>/dev/null >&2; then
 250         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 251 else
 252         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 253 fi
 254
 255 AC_OUTPUT([Makefile\
 256            doc/Makefile\
 257            gnu/Makefile\
 258            lib/Makefile\
 259            po/Makefile.in\
 260            scripts/Makefile\
 261            rmt/Makefile\
 262            src/Makefile])