git.gag.com Git - debian/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 # Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.13.26], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([config])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.57])
  26 AM_INIT_AUTOMAKE([1.7.5 gnits dist-bzip2 dist-shar])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_AIX
  31 AC_MINIX
  32 AC_EXEEXT
  33 AC_PROG_RANLIB
  34 AC_SYS_LARGEFILE
  35 AC_ISC_POSIX
  36 AC_C_INLINE
  37
  38 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  39   sgtty.h string.h \
  40   sys/buf.h sys/device.h sys/gentape.h \
  41   sys/inet.h sys/io/trioctl.h \
  42   sys/mtio.h sys/tprintf.h sys/tape.h \
  43   unistd.h)
  44
  45 AC_HEADER_SYS_WAIT
  46 AM_STDBOOL_H
  47
  48 if test $ac_cv_header_sys_mtio_h = yes; then
  49   AC_CACHE_CHECK(for remote tape header files, tar_cv_header_rmt,
  50     [AC_TRY_CPP([
  51 #if HAVE_SGTTY_H
  52 # include <sgtty.h>
  53 #endif
  54 #include <sys/socket.h>],
  55     tar_cv_header_rmt=yes, tar_cv_header_rmt=no)])
  56   test $tar_cv_header_rmt = yes && RMT='rmt$(EXEEXT)'
  57   AC_SUBST(RMT)
  58 fi
  59
  60 AC_CACHE_CHECK(which ioctl field to test for reversed bytes,
  61   tar_cv_header_mtio_check_field,
  62   [AC_EGREP_HEADER(mt_model, sys/mtio.h,
  63   tar_cv_header_mtio_check_field=mt_model,
  64   tar_cv_header_mtio_check_field=mt_type)])
  65 AC_DEFINE_UNQUOTED(MTIO_CHECK_FIELD, $tar_cv_header_mtio_check_field,
  66   [Define to mt_model (v.g., for DG/UX), else to mt_type.])
  67
  68 AC_HEADER_DIRENT
  69 AC_HEADER_MAJOR
  70 AC_HEADER_STAT
  71 AC_HEADER_STDC
  72 AC_STRUCT_ST_BLKSIZE
  73 AC_STRUCT_ST_BLOCKS
  74 AC_MSG_CHECKING([for st_fstype string in struct stat])
  75 AC_CACHE_VAL(diff_cv_st_fstype_string,
  76   [AC_TRY_COMPILE([#include <sys/types.h>
  77 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  78    diff_cv_st_fstype_string=yes,
  79    diff_cv_st_fstype_string=no)])
  80 AC_MSG_RESULT($diff_cv_st_fstype_string)
  81 if test $diff_cv_st_fstype_string = yes; then
  82   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  83     [Define if struct stat has a char st_fstype[] member.])
  84 fi
  85
  86 AC_TYPE_SIGNAL
  87 AC_TYPE_MODE_T
  88 AC_TYPE_PID_T
  89 AC_TYPE_OFF_T
  90 AC_TYPE_SIZE_T
  91 AC_TYPE_UID_T
  92 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  93                                    [Type of major device numbers.]))
  94 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  95                                    [Type of minor device numbers.]))
  96 gt_TYPE_SSIZE_T
  97 jm_AC_TYPE_UINTMAX_T
  98
  99
 100 # gnulib modules
 101
 102 AM_FUNC_GETLINE
 103
 104 gl_BACKUPFILE
 105 gl_DIRNAME
 106 gl_ERROR
 107 gl_EXCLUDE
 108 gl_FILEBLOCKS
 109 gl_FUNC_ALLOCA
 110 gl_FUNC_FNMATCH_GNU
 111 gl_FUNC_MEMSET
 112 gl_FUNC_MKTIME
 113 gl_FUNC_RMDIR
 114 gl_FUNC_STRTOL
 115 gl_FUNC_STRTOUL
 116 gl_GETDATE
 117 gl_GETOPT
 118 gl_HASH
 119 gl_HUMAN
 120 gl_MODECHANGE
 121 gl_OBSTACK
 122 gl_PATHMAX
 123 gl_QUOTE
 124 gl_QUOTEARG
 125 gl_SAFE_READ
 126 gl_SAFE_WRITE
 127 gl_SAVE_CWD
 128 gl_SAVEDIR
 129 gl_STRCASE
 130 gl_XALLOC
 131 gl_XGETCWD
 132 gl_XSTRTOL
 133
 134 jm_FUNC_FTRUNCATE
 135 jm_FUNC_GLIBC_UNLOCKED_IO
 136 jm_FUNC_LCHOWN
 137 jm_FUNC_MALLOC
 138 jm_FUNC_REALLOC
 139 jm_FUNC_UTIME
 140 jm_XSTRTOUMAX
 141
 142
 143 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
 144 # programs in the package would end up linked with that potentially-shared
 145 # library, inducing unnecessary run-time overhead.
 146
 147 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 148 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 149 tar_save_LIBS=$LIBS
 150   LIB_CLOCK_GETTIME=
 151   AC_SEARCH_LIBS(clock_gettime, [rt posix4],
 152                  [LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime])
 153   AC_SUBST(LIB_CLOCK_GETTIME)
 154   AC_CHECK_FUNCS(clock_gettime)
 155 LIBS=$tar_save_LIBS
 156
 157 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink)
 158 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 159 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 160 AC_CHECK_DECLS([valloc])
 161
 162 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 163 tar_save_LIBS=$LIBS
 164   LIB_SETSOCKOPT=
 165   AC_SEARCH_LIBS(setsockopt, [socket], ,
 166     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 167   AC_SEARCH_LIBS(setsockopt, [nsl])
 168   if test " $LIBS" != " $tar_save_LIBS"; then
 169     LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 170   fi
 171   AC_SUBST(LIB_SETSOCKOPT)
 172 LIBS=$tar_save_LIBS
 173
 174 AC_REPLACE_FUNCS(waitpid)
 175
 176 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 177   [if test -n "$RSH"; then
 178     tar_cv_path_RSH=$RSH
 179   else
 180     tar_cv_path_RSH=no
 181     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 182         /usr/bin/nsh /usr/bin/rcmd
 183     do
 184       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 185       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 186       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 187       if test -f $ac_file; then
 188         if (test -h $ac_file) 2>/dev/null; then
 189           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 190         else
 191           tar_cv_path_RSH=$ac_file
 192           break
 193         fi
 194       fi
 195     done
 196   fi])
 197 if test $tar_cv_path_RSH = no; then
 198   AC_CHECK_HEADERS(netdb.h)
 199 else
 200   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 201     [Define to the full path of your rsh, if any.])
 202 fi
 203
 204 AC_MSG_CHECKING(for default archive format)
 205
 206 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 207   DEFAULT_ARCHIVE_FORMAT="GNU"
 208 fi
 209 case $DEFAULT_ARCHIVE_FORMAT in
 210   V7|OLDGNU|POSIX|GNU) ;;
 211   *) AC_MSG_ERROR(Invalid format name);;
 212 esac
 213 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 214   [By default produce archives of this format])
 215 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 216
 217 AC_MSG_CHECKING(for default archive)
 218
 219 if test -z "$DEFAULT_ARCHIVE"; then
 220   DEFAULT_ARCHIVE=-
 221 else
 222   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 223     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 224   fi
 225   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 226   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 227   # FIXME: Rearrange, here.
 228   case $DEFAULT_ARCHIVE in
 229     *[[0-7][lmh]])
 230       AC_DEFINE(DENSITY_LETTER, 1,
 231         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 232       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 233       ;;
 234     *[[0-7]])
 235       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 236       ;;
 237     *)
 238       device_prefix=
 239       ;;
 240   esac
 241   case "$device_prefix" in
 242     ?*)
 243       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 244         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 245       ;;
 246   esac
 247 fi
 248 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 249   [Define to a string giving the full name of the default archive file.])
 250 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 251
 252 AC_MSG_CHECKING(for default blocking)
 253 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 254 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 255   [Define to a number giving the default blocking size for archives.])
 256 AC_MSG_RESULT($DEFAULT_BLOCKING)
 257
 258 # Gettext.
 259 AM_GNU_GETTEXT([external], [need-ngettext])
 260 AM_GNU_GETTEXT_VERSION(0.12.1)
 261
 262 AC_OUTPUT([Makefile doc/Makefile lib/Makefile \
 263 m4/Makefile po/Makefile.in \
 264 scripts/Makefile src/Makefile tests/Makefile tests/preset])