git.gag.com Git - debian/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.14.90], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([config])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_PROG_YACC
  33 AC_SYS_LARGEFILE
  34 AC_ISC_POSIX
  35 AC_C_INLINE
  36
  37 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  38   sgtty.h string.h \
  39   sys/param.h sys/device.h sys/gentape.h \
  40   sys/inet.h sys/io/trioctl.h \
  41   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  42   unistd.h)
  43
  44 AC_CHECK_HEADERS([sys/buf.h], [], [],
  45 [#if HAVE_SYS_PARAM_H
  46 #include <sys/param.h>
  47 #endif])
  48
  49 AC_HEADER_SYS_WAIT
  50 AM_STDBOOL_H
  51
  52 AC_HEADER_DIRENT
  53 AC_HEADER_MAJOR
  54 AC_HEADER_STAT
  55 AC_HEADER_STDC
  56 AC_STRUCT_ST_BLKSIZE
  57 AC_STRUCT_ST_BLOCKS
  58 AC_MSG_CHECKING([for st_fstype string in struct stat])
  59 AC_CACHE_VAL(diff_cv_st_fstype_string,
  60   [AC_TRY_COMPILE([#include <sys/types.h>
  61 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  62    diff_cv_st_fstype_string=yes,
  63    diff_cv_st_fstype_string=no)])
  64 AC_MSG_RESULT($diff_cv_st_fstype_string)
  65 if test $diff_cv_st_fstype_string = yes; then
  66   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  67     [Define if struct stat has a char st_fstype[] member.])
  68 fi
  69
  70 AC_TYPE_SIGNAL
  71 AC_TYPE_MODE_T
  72 AC_TYPE_PID_T
  73 AC_TYPE_OFF_T
  74 AC_TYPE_SIZE_T
  75 AC_TYPE_UID_T
  76 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  77                                    [Type of major device numbers.]))
  78 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  79                                    [Type of minor device numbers.]))
  80 AC_CHECK_TYPE(dev_t, unsigned)
  81 AC_CHECK_TYPE(ino_t, unsigned)
  82
  83 gt_TYPE_SSIZE_T
  84 gl_AC_TYPE_INTMAX_T
  85 jm_AC_TYPE_UINTMAX_T
  86
  87 # gnulib modules
  88 tar_GNULIB
  89
  90
  91 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
  92                  [
  93 #include <sys/types.h>
  94 #include <sys/stat.h>])
  95
  96 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
  97 # programs in the package would end up linked with that potentially-shared
  98 # library, inducing unnecessary run-time overhead.
  99
 100 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 101 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 102 tar_save_LIBS=$LIBS
 103   LIB_CLOCK_GETTIME=
 104   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 105   case "$ac_cv_search_clock_gettime" in
 106     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 107   esac
 108   AC_SUBST(LIB_CLOCK_GETTIME)
 109   AC_CHECK_FUNCS(clock_gettime)
 110 LIBS=$tar_save_LIBS
 111
 112 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 113 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 114 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 115 AC_CHECK_DECLS([time],,, [#include <time.h>])
 116
 117 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 118 tar_save_LIBS=$LIBS
 119   LIB_SETSOCKOPT=
 120   AC_SEARCH_LIBS(setsockopt, [socket], ,
 121     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 122   AC_SEARCH_LIBS(setsockopt, [nsl])
 123
 124   case "$ac_cv_search_setsockopt" in
 125     -l*) LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 126   esac
 127   AC_SUBST(LIB_SETSOCKOPT)
 128 LIBS=$tar_save_LIBS
 129
 130 AC_REPLACE_FUNCS(waitpid)
 131
 132 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 133   [if test -n "$RSH"; then
 134     tar_cv_path_RSH=$RSH
 135   else
 136     tar_cv_path_RSH=no
 137     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 138         /usr/bin/nsh /usr/bin/rcmd
 139     do
 140       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 141       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 142       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 143       if test -f $ac_file; then
 144         if (test -h $ac_file) 2>/dev/null; then
 145           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 146         else
 147           tar_cv_path_RSH=$ac_file
 148           break
 149         fi
 150       fi
 151     done
 152   fi])
 153 if test $tar_cv_path_RSH = no; then
 154   AC_CHECK_HEADERS(netdb.h)
 155 else
 156   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 157     [Define to the full path of your rsh, if any.])
 158 fi
 159
 160 AC_MSG_CHECKING(for default archive format)
 161
 162 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 163            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 164
 165 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 166   DEFAULT_ARCHIVE_FORMAT="GNU"
 167 fi
 168 case $DEFAULT_ARCHIVE_FORMAT in
 169   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 170   *) AC_MSG_ERROR(Invalid format name);;
 171 esac
 172 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 173   [By default produce archives of this format])
 174 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 175
 176 AC_MSG_CHECKING(for default archive)
 177
 178 AC_ARG_VAR([DEFAULT_ARCHIVE],
 179            [Set the name of the default archive (default: -)])
 180 if test -z "$DEFAULT_ARCHIVE"; then
 181   DEFAULT_ARCHIVE=-
 182 else
 183   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 184     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 185   fi
 186   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 187   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 188   # FIXME: Rearrange, here.
 189   case $DEFAULT_ARCHIVE in
 190     *[[0-7][lmh]])
 191       AC_DEFINE(DENSITY_LETTER, 1,
 192         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 193       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 194       ;;
 195     *[[0-7]])
 196       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 197       ;;
 198     *)
 199       device_prefix=
 200       ;;
 201   esac
 202   case "$device_prefix" in
 203     ?*)
 204       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 205         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 206       ;;
 207   esac
 208 fi
 209 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 210   [Define to a string giving the full name of the default archive file.])
 211 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 212
 213 AC_ARG_VAR([DEFAULT_BLOCKING],
 214            [Define default blocking factor (default: 20)])
 215 AC_MSG_CHECKING(for default blocking)
 216 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 217 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 218   [Define to a number giving the default blocking size for archives.])
 219 AC_MSG_RESULT($DEFAULT_BLOCKING)
 220
 221 PU_RMT
 222
 223 # Gettext.
 224 AM_GNU_GETTEXT([external], [need-ngettext])
 225 AM_GNU_GETTEXT_VERSION(0.12.1)
 226
 227 # Iconv
 228 AM_ICONV
 229 AC_CHECK_HEADERS(iconv.h)
 230 AC_CHECK_TYPE(iconv_t,:,
 231               AC_DEFINE(iconv_t, int,
 232                         [Conversion descriptor type]),
 233               [
 234 #ifdef HAVE_ICONV_H
 235 # include <iconv.h>
 236 #endif
 237 ])
 238
 239 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 240 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 241 AC_ARG_ENABLE(backup-scripts,
 242               AC_HELP_STRING([--enable-backup-scripts],
 243                              [Create and install backup and restore scripts]),
 244               [case $enableval in
 245                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 246                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 247                     ;;
 248                esac])
 249
 250 AC_SUBST(BACKUP_SED_COND)
 251 if date +%Y-%m-%d 2>/dev/null >&2; then
 252         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 253 else
 254         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 255 fi
 256
 257
 258 AC_OUTPUT([Makefile\
 259            doc/Makefile\
 260            lib/Makefile\
 261            po/Makefile.in\
 262            scripts/Makefile\
 263            rmt/Makefile\
 264            src/Makefile\
 265            tests/Makefile\
 266            tests/preset])