git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.3svn)
  30
  31 DEFINES=""
  32 AC_SUBST(DEFINES)
  33
  34 dnl Remember if the user explicity set CFLAGS
  35 if test -n "${CFLAGS}"; then
  36   user_set_cflags=yes
  37 fi
  38 dnl Remember if the user explicity set CXXFLAGS
  39 if test -n "${CXXFLAGS}"; then
  40   user_set_cxxflags=yes
  41 fi
  42
  43
  44 LF_CONFIGURE_CC
  45 LF_CONFIGURE_CXX
  46 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  47
  48
  49 dnl The three macros above are known to override CFLAGS if the user
  50 dnl didn't specify them.  Though I'm sure somebody thought this was
  51 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  52 dnl selected files.  Thus we "undo" the damage here...
  53 dnl
  54 dnl If the user specified CFLAGS, we use them.
  55 dnl See Makefile.common for the rest of the magic.
  56 if test "$user_set_cflags" != yes; then
  57   autoconf_default_CFLAGS="$CFLAGS"
  58   CFLAGS=""
  59 fi
  60 AC_SUBST(autoconf_default_CFLAGS)
  61
  62
  63 dnl The three macros above are known to override CXXFLAGS if the user
  64 dnl didn't specify them.  Though I'm sure somebody thought this was
  65 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  66 dnl selected files.  Thus we "undo" the damage here...
  67 dnl
  68 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  69 dnl the output of swig use use -O1 if we're using g++.
  70 dnl See Makefile.common for the rest of the magic.
  71 if test "$user_set_cxxflags" != yes; then
  72   autoconf_default_CXXFLAGS="$CXXFLAGS"
  73   CXXFLAGS=""
  74   if test "$GXX" = yes; then
  75     case "$host_cpu" in
  76         powerpc*)
  77            dnl "-O1" is broken on the PPC for some reason
  78            dnl (at least as of g++ 4.1.1)
  79            swig_CXXFLAGS="-g1 -O2 -Wno-strict-aliasing -Wno-parentheses"
  80         ;;
  81         *)
  82         swig_CXXFLAGS="-g -O1 -Wno-strict-aliasing -Wno-parentheses"
  83         ;;
  84     esac
  85   fi
  86 fi
  87 AC_SUBST(autoconf_default_CXXFLAGS)
  88 AC_SUBST(swig_CXXFLAGS)
  89
  90 dnl add ${prefix}/lib${gr_libdir_suffix}/pkgconfig to the head of the PKG_CONFIG_PATH
  91 if test x${PKG_CONFIG_PATH} = x; then
  92     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig
  93 else
  94     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig:${PKG_CONFIG_PATH}
  95 fi
  96 export PKG_CONFIG_PATH
  97
  98 LF_SET_WARNINGS
  99 GR_SET_GPROF
 100 GR_SET_PROF
 101 AM_PROG_AS
 102 AC_PROG_LN_S
 103 AC_PROG_MAKE_SET
 104 AC_PROG_INSTALL
 105
 106 # AC_PROG_MKDIR_P
 107 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P.
 108 # Remove this macro when we can assume autoconf >= 2.60.
 109 m4_ifdef([AC_PROG_MKDIR_P], [], [
 110   AC_DEFUN([AC_PROG_MKDIR_P],
 111     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 112      MKDIR_P='$(mkdir_p)'
 113      AC_SUBST([MKDIR_P])])
 114 ])
 115 AC_PROG_MKDIR_P
 116
 117 AC_PATH_PROG([RM_PROG], [rm])
 118
 119 AC_LIBTOOL_WIN32_DLL
 120 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
 121 AC_ENABLE_SHARED        dnl do build shared libraries
 122 AC_DISABLE_STATIC       dnl don't build static libraries
 123 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
 124 GR_FORTRAN
 125
 126 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
 127 GR_SCRIPTING
 128
 129 # Allow user to choose whether to generate SWIG/Python
 130 # Default is enabled
 131 AC_ARG_ENABLE([python],
 132   [AS_HELP_STRING([--enable-python],
 133     [generate SWIG/Python components (default is yes)])],
 134   [case "${enableval}" in
 135      yes) enable_python=yes ;;
 136      no) enable_python=no ;;
 137      *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 138    esac],
 139   [enable_python=yes]
 140 )
 141 AM_CONDITIONAL([PYTHON], [test x$enable_python = xyes])
 142
 143 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
 144 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
 145
 146 dnl Checks for libraries.
 147 AC_CHECK_LIB(socket,socket)
 148
 149 dnl check for omnithreads (will soon be removed)
 150 GR_OMNITHREAD
 151
 152 dnl Set the c++ compiler that we use for the build system when cross compiling
 153 if test x$CXX_FOR_BUILD = x
 154 then
 155   if test x$cross_compiling = xno; then
 156     CXX_FOR_BUILD=${CXX}
 157   else
 158     CXX_FOR_BUILD=g++
 159   fi
 160 fi
 161 AC_SUBST(CXX_FOR_BUILD)
 162
 163 dnl Check for SysV shm (mandatory)
 164 dnl FIXME this is no longer mandatory.  Check the macro.
 165 GR_SYSV_SHM
 166
 167 dnl Checks for header files.
 168 AC_HEADER_STDC
 169 AC_HEADER_SYS_WAIT
 170 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 171 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 172 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h malloc.h)
 173 AC_CHECK_HEADERS(netinet/in.h)
 174 AC_CHECK_HEADERS(windows.h)
 175 AC_CHECK_HEADERS(vec_types.h)
 176
 177 dnl Checks for typedefs, structures, and compiler characteristics.
 178 AC_C_CONST
 179 AC_C_INLINE
 180 AC_TYPE_SIZE_T
 181 AC_HEADER_TIME
 182 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 183 AC_SUBST(GR_ARCH_BIGENDIAN)
 184 AC_STRUCT_TM
 185
 186 dnl Checks for library functions.
 187 AC_FUNC_ALLOCA
 188 GR_CHECK_MEMALIGN
 189 AC_FUNC_SETVBUF_REVERSED
 190 AC_FUNC_VPRINTF
 191 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 192 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 193 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 194 AC_CHECK_FUNCS([sched_setaffinity])
 195
 196 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 197 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 198 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 199 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 200 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 201 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 202 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 203 #AC_FUNC_MKTIME
 204
 205 AH_BOTTOM([
 206 #ifndef HAVE_TRUNC
 207 #include <math.h>
 208 inline static double trunc(double x)
 209 {
 210   return x >= 0 ? floor(x) : ceil(x);
 211 }
 212 #endif
 213
 214 #ifndef HAVE_EXP10
 215 #include <math.h>
 216 inline static double exp10(double x)
 217 {
 218   return pow(10.0, x);
 219 }
 220 #endif
 221
 222 #ifdef HAVE_WINDOWS_H
 223 #define NOMINMAX
 224 #endif
 225 ])
 226
 227 GR_CHECK_SHM_OPEN
 228 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 229 GR_CHECK_CREATEFILEMAPPING
 230
 231 dnl Check for Mingw support
 232 GR_PWIN32
 233
 234 dnl Do we have "dot", part of the graphviz package from AT&T?
 235 dnl Doxgen will use it to draw pretty diagrams ;-)
 236 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 237
 238 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 239 AC_SUBST(FFTW3F_LIBS)
 240
 241 dnl conditional build stuff
 242 GR_CHECK_DOXYGEN
 243 GR_SET_MD_CPU
 244
 245 dnl Define where to look for cppunit includes and libs
 246 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 247 dnl Try using pkg-config first, then fall back to cppunit-config.
 248 PKG_CHECK_EXISTS(cppunit,
 249   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 250   [AM_PATH_CPPUNIT([1.9.14],[],
 251                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 252
 253 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 254 AC_SUBST(CPPUNIT_INCLUDES)
 255
 256 dnl see if GUILE is installed
 257 AC_PATH_PROG(GUILE,guile)
 258
 259 dnl
 260 dnl We require the boost headers, thread lib and date_time lib.
 261 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 262 dnl
 263 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 264 AX_BOOST_BASE([1.35])
 265
 266 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 267 AX_BOOST_THREAD
 268 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 269 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 270
 271 dnl
 272 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 273 dnl
 274 AX_BOOST_DATE_TIME
 275 dnl AX_BOOST_FILESYSTEM
 276 dnl AX_BOOST_IOSTREAMS
 277 AX_BOOST_PROGRAM_OPTIONS
 278 dnl AX_BOOST_REGEX
 279 dnl AX_BOOST_SERIALIZATION
 280 dnl AX_BOOST_SIGNALS
 281 dnl AX_BOOST_SYSTEM
 282 dnl AX_BOOST_TEST_EXEC_MONITOR
 283 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 284 dnl AX_BOOST_WSERIALIZATION
 285
 286
 287 dnl If this is being done from a subversion tree, create variables
 288 GR_SUBVERSION
 289 BUILD_DATE=`date -R`
 290 AC_SUBST(BUILD_DATE)
 291
 292 dnl Component specific configuration
 293 dnl The order of the GR_ macros determines the order of compilation
 294 dnl For -any- checks on $enable_all_components
 295 dnl use the following guidelines:
 296 dnl   yes : --enable-all-components was specified, so error out if any
 297 dnl         components do not pass configuration checks.
 298 dnl   no  : --disable-all-components was specified, so try to build the
 299 dnl         --enable'd components, and error out if any do not pass
 300 dnl         configuration checks.
 301 dnl   ""  : this option was not specified on the command line; try to
 302 dnl         build all components that are not --with'd, but don't
 303 dnl         error out if any component does not pass configuration checks.
 304 dnl
 305 dnl For each --enable-foo component, if that flag is not specified on
 306 dnl the command line, the related variable $enable_foo will be set to
 307 dnl $enable_all_components .
 308
 309 AC_ARG_ENABLE(
 310     [all-components],
 311     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 312 )
 313
 314 build_dirs="config"
 315 GRC_GRUEL                       dnl must come first
 316 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 317 GRC_GCELL
 318 GRC_GNURADIO_CORE
 319 GRC_PMT
 320 GRC_MBLOCK                      dnl this must come after GRC_PMT
 321 GRC_USRP
 322 GRC_USRP2
 323 GRC_GR_USRP                     dnl this must come after GRC_USRP
 324 GRC_GR_USRP2
 325 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 326 GRC_GR_MSDD6000
 327 GRC_GR_AUDIO_ALSA
 328 GRC_GR_AUDIO_JACK
 329 GRC_GR_AUDIO_OSS
 330 GRC_GR_AUDIO_OSX
 331 GRC_GR_AUDIO_PORTAUDIO
 332 GRC_GR_AUDIO_WINDOWS
 333 GRC_GR_ATSC
 334 GRC_GR_COMEDI
 335 GRC_GR_CVSD_VOCODER
 336 GRC_GR_GPIO
 337 GRC_GR_GSM_FR_VOCODER
 338 GRC_GR_PAGER
 339 GRC_GR_RADAR_MONO
 340 GRC_GR_RADIO_ASTRONOMY
 341 GRC_GR_TRELLIS
 342 GRC_GR_VIDEO_SDL
 343 GRC_GR_WXGUI
 344 GRC_GR_QTGUI
 345 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 346 GRC_GR_UTILS                   dnl this must come after GRC_GR_WXGUI
 347 GRC_GNURADIO_EXAMPLES           dnl must come after all GRC_GR_*
 348 GRC_GRC
 349 GRC_DOCS                        dnl must be last
 350
 351 # Each component is now either to be built, was skipped, will be
 352 # included from pre-installed libraries and includes, or failed
 353 # dependencies.
 354 AC_SUBST([build_dirs], [$build_dirs])
 355 AC_SUBST([skipped_dirs], [$skipped_dirs])
 356 AC_SUBST([with_dirs], [$with_dirs])
 357
 358 # fix for older autotools that don't define these by default
 359 AC_SUBST(abs_top_srcdir)
 360 AC_SUBST(abs_top_builddir)
 361 AC_SUBST(MKDIR_P)
 362
 363 # 'with' variables - the pre-installed libraries, includes, and paths
 364 # - must always come last in the lists, so they require special
 365 # treatment.
 366 AC_SUBST(with_INCLUDES)
 367 AC_SUBST(with_SWIG_INCLUDES)
 368 AC_SUBST(with_PYDIRPATH)
 369 AC_SUBST(with_SWIGDIRPATH)
 370 AC_SUBST(with_LIBDIRPATH)
 371
 372 # Local files tweaked by AC
 373 AC_CONFIG_FILES([\
 374     Makefile \
 375     run_tests.sh \
 376     config/Makefile \
 377     debian/changelog \
 378 ])
 379
 380 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 381 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 382
 383 AC_OUTPUT
 384
 385 echo
 386 echo "*********************************************************************"
 387 echo The following GNU Radio components have been successfully configured:
 388 echo
 389 for dir in $build_dirs
 390 do
 391     echo $dir
 392 done
 393 echo
 394 echo You my now run the 'make' command to build these components.
 395 echo
 396 if test "$skipped_dirs" != ""; then
 397     echo "*********************************************************************"
 398     echo The following components were skipped either because you asked not
 399     echo to build them or they didn\'t pass configuration checks:
 400     echo
 401     for dir in $skipped_dirs
 402     do
 403         echo $dir
 404     done
 405     echo
 406     echo These components will not be built.
 407     echo
 408 fi
 409 if test "$with_dirs" != ""; then
 410     echo "*********************************************************************"
 411     echo The following components will be included from pre-installed
 412     echo libraries and includes:
 413     echo
 414     for dir in $with_dirs
 415     do
 416         echo $dir
 417     done
 418     echo
 419     echo These components will not be built.
 420     echo
 421 fi
 422