git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.2svn)
  30
  31 DEFINES=""
  32 AC_SUBST(DEFINES)
  33
  34 dnl Remember if the user explicity set CXXFLAGS
  35 if test -n "${CXXFLAGS}"; then
  36   user_set_cxxflags=yes
  37 fi
  38
  39 LF_CONFIGURE_CC
  40 LF_CONFIGURE_CXX
  41 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  42
  43 dnl The three macros above are known to override CXXFLAGS if the user
  44 dnl didn't specify them.  Though I'm sure somebody thought this was
  45 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  46 dnl selected files.  Thus we "undo" the damage here...
  47 dnl
  48 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  49 dnl the output of swig use use -O1 if we're using g++.
  50 dnl See Makefile.common for the rest of the magic.
  51 if test "$user_set_cxxflags" != yes; then
  52   autoconf_default_CXXFLAGS="$CXXFLAGS"
  53   if test "$GXX" = yes; then
  54     case "$host_cpu" in
  55         powerpc*)
  56            dnl "-O1" is broken on the PPC for some reason
  57            dnl (at least as of g++ 4.1.1)
  58            swig_CXXFLAGS="-g1 -O2 -Wno-strict-aliasing -Wno-parentheses"
  59         ;;
  60         *)
  61         swig_CXXFLAGS="-g -O1 -Wno-strict-aliasing -Wno-parentheses"
  62         ;;
  63     esac
  64   fi
  65 fi
  66 AC_SUBST(autoconf_default_CXXFLAGS)
  67 AC_SUBST(swig_CXXFLAGS)
  68
  69
  70 dnl add ${prefix}/lib${gr_libdir_suffix}/pkgconfig to the head of the PKG_CONFIG_PATH
  71 if test x${PKG_CONFIG_PATH} = x; then
  72     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig
  73 else
  74     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig:${PKG_CONFIG_PATH}
  75 fi
  76 export PKG_CONFIG_PATH
  77
  78
  79 GR_SET_GPROF
  80 GR_SET_PROF
  81 AM_PROG_AS
  82 AC_PROG_LN_S
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PROG_MKDIR_P
  86 AC_PATH_PROG([RM_PROG], [rm])
  87
  88 AC_LIBTOOL_WIN32_DLL
  89 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  90 AC_ENABLE_SHARED        dnl do build shared libraries
  91 AC_DISABLE_STATIC       dnl don't build static libraries
  92 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
  93 GR_FORTRAN
  94
  95 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  96 GR_SCRIPTING
  97
  98 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  99 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
 100
 101 dnl Checks for libraries.
 102 AC_CHECK_LIB(socket,socket)
 103
 104 dnl check for omnithreads (will soon be removed)
 105 GR_OMNITHREAD
 106 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 107 CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
 108
 109 dnl Set the c++ compiler that we use for the build system when cross compiling
 110 if test x$CXX_FOR_BUILD = x
 111 then
 112   if test x$cross_compiling = xno; then
 113     CXX_FOR_BUILD=${CXX}
 114   else
 115     CXX_FOR_BUILD=g++
 116   fi
 117 fi
 118 AC_SUBST(CXX_FOR_BUILD)
 119
 120 dnl Check for SysV shm (mandatory)
 121 dnl FIXME this is no longer mandatory.  Check the macro.
 122 GR_SYSV_SHM
 123
 124 dnl Checks for header files.
 125 AC_HEADER_STDC
 126 AC_HEADER_SYS_WAIT
 127 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 128 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 129 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h malloc.h)
 130 AC_CHECK_HEADERS(netinet/in.h)
 131 AC_CHECK_HEADERS(windows.h)
 132 AC_CHECK_HEADERS(vec_types.h)
 133
 134 dnl Checks for typedefs, structures, and compiler characteristics.
 135 AC_C_CONST
 136 AC_C_INLINE
 137 AC_TYPE_SIZE_T
 138 AC_HEADER_TIME
 139 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 140 AC_SUBST(GR_ARCH_BIGENDIAN)
 141 AC_STRUCT_TM
 142
 143 dnl Checks for library functions.
 144 AC_FUNC_ALLOCA
 145 GR_CHECK_MEMALIGN
 146 AC_FUNC_SETVBUF_REVERSED
 147 AC_FUNC_VPRINTF
 148 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 149 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 150 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 151 AC_CHECK_FUNCS([sched_setaffinity])
 152
 153 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 154 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 155 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 156 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 157 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 158 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 159 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 160 #AC_FUNC_MKTIME
 161
 162 AH_BOTTOM([
 163 #ifndef HAVE_TRUNC
 164 #include <math.h>
 165 inline static double trunc(double x)
 166 {
 167   return x >= 0 ? floor(x) : ceil(x);
 168 }
 169 #endif
 170
 171 #ifndef HAVE_EXP10
 172 #include <math.h>
 173 inline static double exp10(double x)
 174 {
 175   return pow(10.0, x);
 176 }
 177 #endif
 178
 179 #ifdef HAVE_WINDOWS_H
 180 #define NOMINMAX
 181 #endif
 182 ])
 183
 184 GR_CHECK_SHM_OPEN
 185 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 186 GR_CHECK_CREATEFILEMAPPING
 187
 188 dnl Check for Mingw support
 189 GR_PWIN32
 190
 191 dnl Do we have "dot", part of the graphviz package from AT&T?
 192 dnl Doxgen will use it to draw pretty diagrams ;-)
 193 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 194
 195 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 196 AC_SUBST(FFTW3F_LIBS)
 197
 198 dnl conditional build stuff
 199 GR_CHECK_DOXYGEN
 200 GR_SET_MD_CPU
 201
 202 dnl Define where to look for cppunit includes and libs
 203 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 204 dnl Try using pkg-config first, then fall back to cppunit-config.
 205 PKG_CHECK_EXISTS(cppunit,
 206   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 207   [AM_PATH_CPPUNIT([1.9.14],[],
 208                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 209
 210 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 211 AC_SUBST(CPPUNIT_INCLUDES)
 212
 213 dnl see if GUILE is installed
 214 AC_PATH_PROG(GUILE,guile)
 215
 216 dnl
 217 dnl We require the boost headers, thread lib and date_time lib.
 218 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 219 dnl
 220 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 221 AX_BOOST_BASE([1.35])
 222
 223 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 224 AX_BOOST_THREAD
 225 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 226 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 227
 228 dnl
 229 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 230 dnl
 231 AX_BOOST_DATE_TIME
 232 dnl AX_BOOST_FILESYSTEM
 233 dnl AX_BOOST_IOSTREAMS
 234 AX_BOOST_PROGRAM_OPTIONS
 235 dnl AX_BOOST_REGEX
 236 dnl AX_BOOST_SERIALIZATION
 237 dnl AX_BOOST_SIGNALS
 238 dnl AX_BOOST_SYSTEM
 239 dnl AX_BOOST_TEST_EXEC_MONITOR
 240 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 241 dnl AX_BOOST_WSERIALIZATION
 242
 243
 244 dnl If this is being done from a subversion tree, create variables
 245 GR_SUBVERSION
 246
 247 dnl Component specific configuration
 248 dnl The order of the GR_ macros determines the order of compilation
 249 dnl For -any- checks on $enable_all_components
 250 dnl use the following guidelines:
 251 dnl   yes : --enable-all-components was specified, so error out if any
 252 dnl         components do not pass configuration checks.
 253 dnl   no  : --disable-all-components was specified, so try to build the
 254 dnl         --enable'd components, and error out if any do not pass
 255 dnl         configuration checks.
 256 dnl   ""  : this option was not specified on the command line; try to
 257 dnl         build all components that are not --with'd, but don't
 258 dnl         error out if any component does not pass configuration checks.
 259 dnl
 260 dnl For each --enable-foo component, if that flag is not specified on
 261 dnl the command line, the related variable $enable_foo will be set to
 262 dnl $enable_all_components .
 263
 264 AC_ARG_ENABLE(
 265     [all-components],
 266     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 267 )
 268
 269 build_dirs="config"
 270 GRC_GRUEL                       dnl must come first
 271 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 272 GRC_GCELL
 273 GRC_GNURADIO_CORE
 274 GRC_PMT
 275 GRC_MBLOCK                      dnl this must come after GRC_PMT
 276 GRC_USRP
 277 GRC_USRP2
 278 GRC_GR_USRP                     dnl this must come after GRC_USRP
 279 GRC_GR_USRP2
 280 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 281 GRC_GR_MSDD6000
 282 GRC_GR_AUDIO_ALSA
 283 GRC_GR_AUDIO_JACK
 284 GRC_GR_AUDIO_OSS
 285 GRC_GR_AUDIO_OSX
 286 GRC_GR_AUDIO_PORTAUDIO
 287 GRC_GR_AUDIO_WINDOWS
 288 GRC_GR_ATSC
 289 GRC_GR_COMEDI
 290 GRC_GR_CVSD_VOCODER
 291 GRC_GR_GPIO
 292 GRC_GR_GSM_FR_VOCODER
 293 GRC_GR_PAGER
 294 GRC_GR_RADAR_MONO
 295 GRC_GR_RADIO_ASTRONOMY
 296 GRC_GR_TRELLIS
 297 GRC_GR_VIDEO_SDL
 298 GRC_GR_WXGUI
 299 GRC_GR_QTGUI
 300 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 301 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 302 GRC_GNURADIO_EXAMPLES           dnl must come after all GRC_GR_*
 303 GRC_GRC
 304
 305 # Each component is now either to be built, was skipped, will be
 306 # included from pre-installed libraries and includes, or failed
 307 # dependencies.
 308 AC_SUBST([build_dirs], [$build_dirs])
 309 AC_SUBST([skipped_dirs], [$skipped_dirs])
 310 AC_SUBST([with_dirs], [$with_dirs])
 311
 312 # fix for older autotools that don't define these by default
 313 AC_SUBST(abs_top_srcdir)
 314 AC_SUBST(abs_top_builddir)
 315 AC_SUBST(MKDIR_P)
 316
 317 # 'with' variables - the pre-installed libraries, includes, and paths
 318 # - must always come last in the lists, so they require special
 319 # treatment.
 320 AC_SUBST(with_INCLUDES)
 321 AC_SUBST(with_SWIG_INCLUDES)
 322 AC_SUBST(with_PYDIRPATH)
 323 AC_SUBST(with_SWIGDIRPATH)
 324 AC_SUBST(with_LIBDIRPATH)
 325
 326 # Local files tweaked by AC
 327 AC_CONFIG_FILES([\
 328     Makefile \
 329     run_tests.sh \
 330     config/Makefile \
 331 ])
 332
 333 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 334 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 335
 336 dnl Enable warnings as the last thing before generating output, since
 337 dnl this may add -Werror to CFLAGS which can cause various configure
 338 dnl checks to fail.
 339 LF_SET_WARNINGS
 340
 341 AC_OUTPUT
 342
 343 echo
 344 echo "*********************************************************************"
 345 echo The following GNU Radio components have been successfully configured:
 346 echo
 347 for dir in $build_dirs
 348 do
 349     echo $dir
 350 done
 351 echo
 352 echo You my now run the 'make' command to build these components.
 353 echo
 354 if test "$skipped_dirs" != ""; then
 355     echo "*********************************************************************"
 356     echo The following components were skipped either because you asked not
 357     echo to build them or they didn\'t pass configuration checks:
 358     echo
 359     for dir in $skipped_dirs
 360     do
 361         echo $dir
 362     done
 363     echo
 364     echo These components will not be built.
 365     echo
 366 fi
 367 if test "$with_dirs" != ""; then
 368     echo "*********************************************************************"
 369     echo The following components will be included from pre-installed
 370     echo libraries and includes:
 371     echo
 372     for dir in $with_dirs
 373     do
 374         echo $dir
 375     done
 376     echo
 377     echo These components will not be built.
 378     echo
 379 fi