git.gag.com Git - debian/gzip/blob - configure.ac

   1 # Configure template for gzip.
   2
   3 # Copyright (C) 1999, 2000, 2001, 2002, 2006 Free Software Foundation, Inc.
   4 # Copyright (C) 1992-1993 Jean-loup Gailly
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_PREREQ([2.60])
  22 AC_INIT([gzip], [1.3.8], [bug-gzip@gnu.org])
  23 AC_CONFIG_SRCDIR(gzip.c)
  24 AC_CONFIG_AUX_DIR(build-aux)
  25 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  26 AM_INIT_AUTOMAKE([gnits])
  27
  28 AC_PROG_CC_STDC
  29 AM_PROG_CC_C_O
  30 AC_PROG_CPP
  31 AC_PROG_LN_S
  32 AC_PROG_RANLIB
  33 AC_PROG_SHELL
  34
  35 gl_EARLY
  36 AC_SYS_LARGEFILE
  37
  38 gl_INIT
  39
  40 # cc -E produces incorrect asm files on SVR4, we must use /lib/cpp.
  41 test -z "$ASCPP" && test -f /lib/cpp && ASCPP=/lib/cpp
  42 test -z "$ASCPP" && ASCPP="$CPP"
  43
  44 AC_CACHE_CHECK([for underline in external names], [gzip_cv_underline],
  45   [gzip_cv_underline=yes
  46    AC_TRY_COMPILE([int foo() {return 0;}], [],
  47      [nm conftest.$OBJEXT | grep _foo >/dev/null 2>&1 ||
  48         gzip_cv_underline=no])])
  49 if test $gzip_cv_underline = no; then
  50   ASCPP="${ASCPP} -DNO_UNDERLINE"
  51 fi
  52 AC_OBJEXT
  53
  54 # Try to assemble match.S.
  55 # "gcc -E match.s" ignores -E, so we must use match_.s.
  56 AC_CACHE_CHECK([for assembler], [gzip_cv_assembler],
  57   [gzip_cv_assembler=no
  58    case " $DEFS " in
  59    *' NO_ASM '*) ;;
  60    *)
  61      if cp $srcdir/lib/match.c _match.S &&
  62         eval "$ASCPP _match.S > match_.s 2>/dev/null"; then
  63        if test ! -s match_.s || grep error < match_.s > /dev/null; then
  64          :
  65        elif eval "$CC -c match_.s >/dev/null 2>&1" &&
  66             test -f match_.$OBJEXT; then
  67          rm -f match_.$OBJEXT
  68          gzip_cv_assembler=yes
  69          if echo 'void foo (void) {}' > conftest.c &&
  70             eval "$CC -S conftest.c >/dev/null 2>&1" &&
  71             grep '\.note\.GNU-stack' conftest.s >/dev/null 2>&1 &&
  72             eval "$CC -c -Wa,--noexecstack match_.s >/dev/null 2>&1" &&
  73             test -f match_.$OBJEXT; then
  74            gzip_cv_assembler='yes, with -Wa,--noexecstack'
  75          fi
  76        fi
  77      fi
  78      rm -f conftest* _match.S match_.s match_.$OBJEXT;;
  79    esac])
  80 if test "$gzip_cv_assembler" != no; then
  81   AC_DEFINE(ASMV, ,
  82     [Define if an assembler version of longest_match is available.])
  83   AC_LIBOBJ(match)
  84 fi
  85 if test "$gzip_cv_assembler" = 'yes, with -Wa,--noexecstack'; then
  86   ASFLAGS_config='-Wa,--noexecstack'
  87 else
  88   ASFLAGS_config=
  89 fi
  90 AC_SUBST([ASFLAGS_config])
  91
  92 AC_ISC_POSIX
  93 AC_C_CONST
  94 AC_HEADER_STDC
  95 AC_CHECK_HEADERS_ONCE(fcntl.h limits.h memory.h time.h)
  96 AC_CHECK_FUNCS_ONCE([fchmod fchown fdopendir lstat siginterrupt])
  97 AC_HEADER_DIRENT
  98 AC_TYPE_SIGNAL
  99 AC_TYPE_SIZE_T
 100 AC_TYPE_OFF_T
 101
 102 AC_PREFIX_PROGRAM(gzip)
 103 AC_SUBST(ASCPP)dnl
 104
 105 AC_CONFIG_FILES([Makefile doc/Makefile lib/Makefile])
 106 AC_OUTPUT