git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28 if test x$cross_compiling != xno; then
  29   AC_MSG_NOTICE([Configuring GNU Radio for cross compilation])
  30 else
  31   AC_MSG_NOTICE([Configuring GNU Radio for native compilation])
  32 fi
  33
  34 AM_INIT_AUTOMAKE(gnuradio,3.1svn)
  35
  36 dnl add ${prefix}/lib/pkgconfig to the head of the PKG_CONFIG_PATH
  37 if test [x]${PKG_CONFIG_PATH} = x; then
  38     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig
  39 else
  40     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig:${PKG_CONFIG_PATH}
  41 fi
  42 export PKG_CONFIG_PATH
  43
  44 DEFINES=""
  45 AC_SUBST(DEFINES)
  46
  47 dnl Remember if the user explicity set CXXFLAGS
  48 if test -n "${CXXFLAGS}"; then
  49   user_set_cxxflags=yes
  50 fi
  51
  52 GR_X86_64               dnl check for lib64 suffix
  53 LF_CONFIGURE_CC
  54 LF_CONFIGURE_CXX
  55
  56 dnl The three macros above are known to override CXXFLAGS if the user
  57 dnl didn't specify them.  Though I'm sure somebody thought this was
  58 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  59 dnl selected files.  Thus we "undo" the damage here...
  60 dnl
  61 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  62 dnl the output of swig use use -O1 if we're using g++.
  63 dnl See Makefile.common for the rest of the magic.
  64 if test "$user_set_cxxflags" != yes; then
  65   autoconf_default_CXXFLAGS="$CXXFLAGS"
  66   CXXFLAGS=""
  67   if test "$GXX" = yes; then
  68     case "$host_cpu" in
  69         powerpc*)
  70            dnl "-O1" is broken on the PPC for some reason
  71            dnl (at least as of g++ 4.1.1)
  72            swig_CXXFLAGS="-g1 -O2"
  73         ;;
  74         *)
  75         swig_CXXFLAGS="-g -O1"
  76         ;;
  77     esac
  78   fi
  79 fi
  80 AC_SUBST(autoconf_default_CXXFLAGS)
  81 AC_SUBST(swig_CXXFLAGS)
  82
  83 LF_SET_WARNINGS
  84 GR_SET_GPROF
  85 GR_SET_PROF
  86 AM_PROG_AS
  87 AC_PROG_LN_S
  88 AC_PROG_MAKE_SET
  89 AC_PROG_INSTALL
  90 AC_PATH_PROG([RM_PROG], [rm])
  91
  92 AC_LIBTOOL_WIN32_DLL
  93 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  94 AC_ENABLE_SHARED        dnl do build shared libraries
  95 AC_DISABLE_STATIC       dnl don't build static libraries
  96 AC_PROG_LIBTOOL
  97 GR_FORTRAN
  98
  99 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
 100 GR_SCRIPTING
 101
 102 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
 103 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
 104
 105 dnl Checks for libraries.
 106 AC_CHECK_LIB(socket,socket)
 107
 108 dnl check for threads (mandatory)
 109 GR_OMNITHREAD
 110 CFLAGS="${CFLAGS} $PTHREAD_CFLAGS"
 111 CXXFLAGS="${CXXFLAGS} $PTHREAD_CFLAGS"
 112
 113 if test x$CXX_FOR_BUILD = x
 114 then
 115   if test x$cross_compiling = xno; then
 116     CXX_FOR_BUILD=${CXX}
 117   else
 118     CXX_FOR_BUILD=g++
 119   fi
 120 fi
 121
 122 AC_SUBST(CXX_FOR_BUILD)
 123
 124 dnl Check for SysV shm (mandatory)
 125 dnl FIXME this is no longer mandatory.  Check the macro.
 126 GR_SYSV_SHM
 127
 128 dnl Checks for header files.
 129 AC_HEADER_STDC
 130 AC_HEADER_SYS_WAIT
 131 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 132 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 133 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h)
 134 AC_CHECK_HEADERS(netinet/in.h)
 135 AC_CHECK_HEADERS(windows.h)
 136
 137 dnl Checks for typedefs, structures, and compiler characteristics.
 138 AC_C_CONST
 139 AC_C_INLINE
 140 AC_TYPE_SIZE_T
 141 AC_HEADER_TIME
 142 AC_C_BIGENDIAN
 143 AC_STRUCT_TM
 144
 145 dnl Checks for library functions.
 146 AC_FUNC_ALLOCA
 147 AC_FUNC_SETVBUF_REVERSED
 148 AC_FUNC_VPRINTF
 149 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 150 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 151 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 152 AC_CHECK_FUNCS([sched_setaffinity])
 153
 154 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 155 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 156 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 157 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 158 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 159 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 160 #AC_FUNC_MKTIME
 161
 162 AH_BOTTOM([
 163 #ifndef HAVE_TRUNC
 164 #include <math.h>
 165 inline static double trunc(double x)
 166 {
 167   return x >= 0 ? floor(x) : ceil(x);
 168 }
 169 #endif
 170
 171 #ifndef HAVE_EXP10
 172 #include <math.h>
 173 inline static double exp10(double x)
 174 {
 175   return pow(10.0, x);
 176 }
 177 #endif
 178
 179 #ifdef HAVE_WINDOWS_H
 180 #define NOMINMAX
 181 #endif
 182 ])
 183
 184 GR_CHECK_SHM_OPEN
 185 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 186 GR_CHECK_CREATEFILEMAPPING
 187
 188 dnl Check for Mingw support
 189 GR_PWIN32
 190
 191 dnl Do we have "dot", part of the graphviz package from AT&T?
 192 dnl Doxgen will use it to draw pretty diagrams ;-)
 193 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 194
 195 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 196 AC_SUBST(FFTW3F_LIBS)
 197
 198 dnl conditional build stuff
 199 GR_CHECK_DOXYGEN
 200 GR_SET_MD_CPU
 201
 202 dnl Define where to look for cppunit includes and libs
 203 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 204 dnl Try using pkg-config first, then fall back to cppunit-config.
 205 PKG_CHECK_EXISTS(cppunit,
 206   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 207   [AM_PATH_CPPUNIT([1.9.14],[],
 208                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 209
 210 dnl see if GUILE is installed
 211 AC_PATH_PROG(GUILE,guile)
 212
 213 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 214 AC_SUBST(CPPUNIT_INCLUDES)
 215
 216 dnl Define where to find boost includes
 217 dnl defines BOOST_CFLAGS
 218 GR_REQUIRE_BOOST_INCLUDES
 219
 220 dnl If this is being done from a subversion tree, create variables
 221 GR_SUBVERSION
 222
 223 dnl Component specific configuration
 224 dnl The order of the GR_ macros determines the order of compilation
 225 dnl For -any- checks on $enable_all_components
 226 dnl use the following guildlines:
 227 dnl   yes : --enable-all-components was specified, so error out if any
 228 dnl         components do not pass configuration checks.
 229 dnl   no  : --disable-all-components was specified, so try to build the
 230 dnl         --enable'd components, and error out if any do not pass
 231 dnl         configuration checks.
 232 dnl   ""  : this option was not specified on the command line; try to
 233 dnl         build all components that are not --with'd, but don't
 234 dnl         error out if any component does not pass configuration checks.
 235 dnl
 236 dnl For each --enable-foo component, if that flag is not specified on
 237 dnl the command line, the related variable $enable_foo will be set to
 238 dnl $enable_all_components .
 239
 240 AC_ARG_ENABLE(
 241     [all-components],
 242     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 243 )
 244
 245 build_dirs="config"
 246 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 247 GRC_GNURADIO_CORE
 248 GRC_PMT
 249 GRC_MBLOCK                      dnl this must come after GRC_PMT
 250 GRC_USRP
 251 GRC_GR_USRP                     dnl this must come after GRC_USRP
 252 GRC_GR_MSDD6000
 253 GRC_GR_AUDIO_ALSA
 254 GRC_GR_AUDIO_JACK
 255 GRC_GR_AUDIO_OSS
 256 GRC_GR_AUDIO_OSX
 257 GRC_GR_AUDIO_PORTAUDIO
 258 GRC_GR_AUDIO_WINDOWS
 259 GRC_GR_ATSC
 260 GRC_GR_COMEDI
 261 GRC_GR_CVSD_VOCODER
 262 GRC_GR_GPIO
 263 GRC_GR_GSM_FR_VOCODER
 264 GRC_GR_PAGER
 265 GRC_GR_RADAR_MONO
 266 GRC_GR_RADIO_ASTRONOMY
 267 GRC_GR_TRELLIS
 268 GRC_GR_VIDEO_SDL
 269 GRC_GR_WXGUI
 270 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 271 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 272 GRC_GNURADIO_EXAMPLES           dnl must come last
 273
 274 # Each component is now either to be built, was skipped, will be
 275 # included from pre-installed libraries and includes, or failed
 276 # dependencies.
 277 AC_SUBST([build_dirs], [$build_dirs])
 278 AC_SUBST([skipped_dirs], [$skipped_dirs])
 279 AC_SUBST([with_dirs], [$with_dirs])
 280
 281 # fix for older autotools that don't define "abs_top_YYY" by default
 282 AC_SUBST(abs_top_srcdir)
 283 AC_SUBST(abs_top_builddir)
 284
 285 # 'with' variables - the pre-installed libraries, includes, and paths
 286 # - must always come last in the lists, so they require special
 287 # treatment.
 288 AC_SUBST(with_INCLUDES)
 289 AC_SUBST(with_SWIG_INCLUDES)
 290 AC_SUBST(with_PYDIRPATH)
 291 AC_SUBST(with_SWIGDIRPATH)
 292 AC_SUBST(with_LIBDIRPATH)
 293
 294 # Local files tweaked by AC
 295 AC_CONFIG_FILES([\
 296     Makefile \
 297     run_tests.sh \
 298     config/Makefile \
 299 ])
 300
 301 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 302 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 303
 304 AC_OUTPUT
 305
 306 echo
 307 echo "*********************************************************************"
 308 echo The following GNU Radio components have been successfully configured:
 309 echo
 310 for dir in $build_dirs
 311 do
 312     echo $dir
 313 done
 314 echo
 315 echo You my now run the 'make' command to build these components.
 316 echo
 317 if test "$skipped_dirs" != ""; then
 318     echo "*********************************************************************"
 319     echo The following components were skipped either because you asked not
 320     echo to build them or they didn\'t pass configuration checks:
 321     echo
 322     for dir in $skipped_dirs
 323     do
 324         echo $dir
 325     done
 326     echo
 327     echo These components will not be built.
 328     echo
 329 fi
 330 if test "$with_dirs" != ""; then
 331     echo "*********************************************************************"
 332     echo The following components will be included from pre-installed
 333     echo libraries and includes:
 334     echo
 335     for dir in $with_dirs
 336     do
 337         echo $dir
 338     done
 339     echo
 340     echo These components will not be built.
 341     echo
 342 fi