git.gag.com Git - fw/openocd/blob - configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG_C
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 AC_PROG_LIBTOOL
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 119         [[xds110], [TI XDS110 Debug Probe], [XDS110]]])
 120
 121 m4_define([USB_ADAPTERS],
 122         [[[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 123         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 124         [[aice], [Andes JTAG Programmer], [AICE]]])
 125
 126 m4_define([USB0_ADAPTERS],
 127         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 128         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 129         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 130
 131 m4_define([HIDAPI_ADAPTERS],
 132         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
 133
 134 m4_define([HIDAPI_USB1_ADAPTERS],
 135         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 136
 137 m4_define([LIBFTDI_ADAPTERS],
 138         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 139         [[presto], [ASIX Presto Adapter], [PRESTO]],
 140         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 141
 142 m4_define([LIBJAYLINK_ADAPTERS],
 143         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 144
 145 m4_define([PCIE_ADAPTERS],
 146         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 147
 148
 149 AC_ARG_ENABLE([doxygen-html],
 150   AS_HELP_STRING([--disable-doxygen-html],
 151     [Disable building Doxygen manual as HTML.]),
 152   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 153 AC_SUBST([doxygen_as_html])
 154 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 155 AC_MSG_RESULT([$doxygen_as_html])
 156
 157 AC_ARG_ENABLE([doxygen-pdf],
 158   AS_HELP_STRING([--enable-doxygen-pdf],
 159     [Enable building Doxygen manual as PDF.]),
 160   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 161 AC_SUBST([doxygen_as_pdf])
 162 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 163 AC_MSG_RESULT([$doxygen_as_pdf])
 164
 165 AC_ARG_ENABLE([gccwarnings],
 166   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 167   [gcc_warnings=$enableval], [gcc_warnings=yes])
 168
 169 AC_ARG_ENABLE([wextra],
 170   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 171   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 172
 173 AC_ARG_ENABLE([werror],
 174   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 175   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 176
 177 # set default verbose options, overridden by following options
 178 debug_usb_io=no
 179 debug_usb_comms=no
 180
 181 AC_ARG_ENABLE([verbose],
 182   AS_HELP_STRING([--enable-verbose],
 183       [Enable verbose JTAG I/O messages (for debugging).]),
 184   [
 185   debug_usb_io=$enableval
 186   debug_usb_comms=$enableval
 187   ], [])
 188
 189 AC_ARG_ENABLE([verbose_usb_io],
 190   AS_HELP_STRING([--enable-verbose-usb-io],
 191       [Enable verbose USB I/O messages (for debugging)]),
 192   [debug_usb_io=$enableval], [])
 193
 194 AC_ARG_ENABLE([verbose_usb_comms],
 195   AS_HELP_STRING([--enable-verbose-usb-comms],
 196       [Enable verbose USB communication messages (for debugging)]),
 197   [debug_usb_comms=$enableval], [])
 198
 199 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 200 AC_MSG_RESULT([$debug_usb_io])
 201 AS_IF([test "x$debug_usb_io" = "xyes"], [
 202   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 203 ])
 204
 205 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 206 AC_MSG_RESULT([$debug_usb_comms])
 207 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 208   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 209 ])
 210
 211 debug_malloc=no
 212 AC_ARG_ENABLE([malloc_logging],
 213   AS_HELP_STRING([--enable-malloc-logging],
 214       [Include free space in logging messages (requires malloc.h).]),
 215   [debug_malloc=$enableval], [])
 216
 217 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 218 AC_MSG_RESULT([$debug_malloc])
 219 AS_IF([test "x$debug_malloc" = "xyes"], [
 220   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 221 ])
 222
 223 AC_ARG_ENABLE([dummy],
 224   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 225   [build_dummy=$enableval], [build_dummy=no])
 226
 227 m4_define([AC_ARG_ADAPTERS], [
 228   m4_foreach([adapter], [$1],
 229         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 230                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 231                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 232                 [], [ADAPTER_VAR([adapter])=$2])
 233   ])
 234 ])
 235
 236 AC_ARG_ADAPTERS([
 237   USB1_ADAPTERS,
 238   USB_ADAPTERS,
 239   USB0_ADAPTERS,
 240   HIDAPI_ADAPTERS,
 241   HIDAPI_USB1_ADAPTERS,
 242   LIBFTDI_ADAPTERS,
 243   LIBJAYLINK_ADAPTERS
 244   ],[auto])
 245
 246 AC_ARG_ENABLE([parport],
 247   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 248   [build_parport=$enableval], [build_parport=no])
 249
 250 AC_ARG_ENABLE([parport_ppdev],
 251   AS_HELP_STRING([--disable-parport-ppdev],
 252       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 253     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 254
 255 AC_ARG_ENABLE([parport_giveio],
 256     AS_HELP_STRING([--enable-parport-giveio],
 257       [Enable use of giveio for parport (for CygWin only)]),
 258     [parport_use_giveio=$enableval], [parport_use_giveio=])
 259
 260 AC_ARG_ENABLE([jtag_vpi],
 261   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 262   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 263
 264 AC_ARG_ENABLE([amtjtagaccel],
 265   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 266   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 267
 268 AC_ARG_ENABLE([zy1000_master],
 269   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 270   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 271
 272 AC_ARG_ENABLE([zy1000],
 273   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 274   [build_zy1000=$enableval], [build_zy1000=no])
 275
 276 AC_ARG_ENABLE([ioutil],
 277   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 278   [build_ioutil=$enableval], [build_ioutil=no])
 279
 280 AS_CASE(["${host_cpu}"],
 281   [arm*|aarch64], [
 282     AC_ARG_ENABLE([bcm2835gpio],
 283       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 284       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 285     AC_ARG_ENABLE([imx_gpio],
 286       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 287       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 288   ],
 289   [
 290     build_bcm2835gpio=no
 291     build_imx_gpio=no
 292 ])
 293
 294 AS_CASE(["${host_cpu}"],
 295   [arm*], [
 296     AC_ARG_ENABLE([ep93xx],
 297       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 298       [build_ep93xx=$enableval], [build_ep93xx=no])
 299
 300     AC_ARG_ENABLE([at91rm9200],
 301       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 302       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 303   ],
 304   [
 305     build_ep93xx=no
 306     build_at91rm9200=no
 307 ])
 308
 309 AC_ARG_ENABLE([gw16012],
 310   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 311   [build_gw16012=$enableval], [build_gw16012=no])
 312
 313 AC_ARG_ENABLE([oocd_trace],
 314   AS_HELP_STRING([--enable-oocd_trace],
 315   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 316   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 317
 318 AC_ARG_ENABLE([buspirate],
 319   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 320   [build_buspirate=$enableval], [build_buspirate=no])
 321
 322 AC_ARG_ENABLE([sysfsgpio],
 323   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 324   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 325
 326 AC_ARG_ENABLE([xlnx_pcie_xvc],
 327   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 328   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 329
 330 AS_CASE([$host_os],
 331   [linux*], [],
 332   [
 333     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 334       AC_MSG_ERROR([sysfsgpio is only available on linux])
 335     ])
 336
 337     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 338       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 339     ])
 340 ])
 341
 342 AC_ARG_ENABLE([minidriver_dummy],
 343   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 344   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 345
 346 AC_ARG_ENABLE([internal-jimtcl],
 347   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 348   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 349
 350 AC_ARG_ENABLE([internal-libjaylink],
 351   AS_HELP_STRING([--disable-internal-libjaylink],
 352   [Disable building internal libjaylink]),
 353   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 354
 355 AC_ARG_ENABLE([target64],
 356   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
 357     [build_target64=$enableval], [build_target64=yes])
 358
 359 build_minidriver=no
 360 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 361 AS_IF([test "x$build_zy1000" = "xyes"], [
 362   AS_IF([test "x$build_minidriver" = "xyes"], [
 363     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 364   ])
 365   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 366       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 367   build_minidriver=yes
 368 ])
 369 AC_MSG_RESULT([$build_zy1000])
 370
 371 AC_ARG_ENABLE([remote-bitbang],
 372   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 373   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 374
 375 AC_MSG_CHECKING([whether to enable dummy minidriver])
 376 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 377   AS_IF([test "x$build_minidriver" = "xyes"], [
 378     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 379   ])
 380   build_minidriver=yes
 381   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 382   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 383       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 384 ])
 385 AC_MSG_RESULT([$build_minidriver_dummy])
 386
 387 AC_MSG_CHECKING([whether standard drivers can be built])
 388 AS_IF([test "x$build_minidriver" = "xyes"], [
 389   AC_MSG_RESULT([no])
 390   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 391   sleep 2
 392 ], [
 393   AC_MSG_RESULT([yes])
 394 ])
 395
 396 AS_CASE(["${host_cpu}"],
 397   [i?86|x86*], [],
 398   [
 399     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 400       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 401     ])
 402     parport_use_ppdev=yes
 403 ])
 404
 405 AS_CASE([$host],
 406   [*-cygwin*], [
 407     is_win32=yes
 408     parport_use_ppdev=no
 409
 410     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 411       [is_mingw=yes],[is_mingw=no])
 412     AS_IF([test "x$is_mingw" = "xyes"], [
 413       AS_IF([test "x$parport_use_giveio" = "xno"], [
 414         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 415       ])
 416       parport_use_giveio=yes
 417       is_cygwin=no
 418     ], [
 419       is_cygwin=yes
 420       # sys/io.h needed under cygwin for parport access
 421       AS_IF([test "x$build_parport" = "xyes"], [
 422         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 423       ])
 424     ])
 425   ],
 426   [*-mingw* | *-msys*], [
 427     is_mingw=yes
 428     is_win32=yes
 429     parport_use_ppdev=no
 430
 431     AS_IF([test "x$parport_use_giveio" = "xno"], [
 432       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 433     ])
 434     parport_use_giveio=yes
 435
 436     AS_IF([test "x$build_buspirate" = "xyes"], [
 437       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 438     ])
 439
 440     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 441   ],
 442   [*darwin*], [
 443     is_darwin=yes
 444
 445     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 446       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 447     ])
 448     parport_use_giveio=no
 449   ],
 450   [
 451     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 452       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 453     ])
 454     parport_use_giveio=no
 455 ])
 456
 457 AS_IF([test "x$is_cygwin" = "xyes"], [
 458     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 459 ], [
 460     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 461 ])
 462
 463 AS_IF([test "x$is_mingw" = "xyes"], [
 464     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 465 ], [
 466     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 467 ])
 468
 469 AS_IF([test "x$is_win32" = "xyes"], [
 470     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 471 ], [
 472     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 473 ])
 474
 475 AS_IF([test "x$is_darwin" = "xyes"], [
 476     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 477 ], [
 478     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 479 ])
 480
 481 AS_IF([test "x$build_parport" = "xyes"], [
 482   build_bitbang=yes
 483   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 484 ], [
 485   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 486 ])
 487
 488 AS_IF([test "x$build_dummy" = "xyes"], [
 489   build_bitbang=yes
 490   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 491 ], [
 492   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 493 ])
 494
 495 AS_IF([test "x$build_ep93xx" = "xyes"], [
 496   build_bitbang=yes
 497   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 498 ], [
 499   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 500 ])
 501
 502 AS_IF([test "x$build_zy1000" = "xyes"], [
 503   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 504 ], [
 505   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 506 ])
 507
 508 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 509   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 510 ], [
 511   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 512 ])
 513
 514 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 515   build_bitbang=yes
 516   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 517 ], [
 518   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 519 ])
 520
 521 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 522   build_bitbang=yes
 523   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 524 ], [
 525   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 526 ])
 527
 528 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 529   build_bitbang=yes
 530   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 531 ], [
 532   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 533 ])
 534
 535 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 536   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 537 ], [
 538   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 539 ])
 540
 541 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 542   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 543 ], [
 544   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 545 ])
 546
 547 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 548   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 549 ], [
 550   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 551 ])
 552
 553 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 554   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 555 ], [
 556   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 557 ])
 558
 559 AS_IF([test "x$build_gw16012" = "xyes"], [
 560   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 561 ], [
 562   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 563 ])
 564
 565 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 566   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 567 ], [
 568   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 569 ])
 570
 571 AS_IF([test "x$build_buspirate" = "xyes"], [
 572   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 573 ], [
 574   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 575 ])
 576
 577 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 578   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 579     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 580   ], [
 581     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 582   ])
 583 ])
 584
 585 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 586   build_bitbang=yes
 587   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 588 ], [
 589   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 590 ])
 591
 592 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 593   build_bitbang=yes
 594   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 595 ], [
 596   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 597 ])
 598
 599 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 600   build_xlnx_pcie_xvc=yes
 601   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 602 ], [
 603   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 604 ])
 605
 606 AS_IF([test "x$build_target64" = "xyes"], [
 607   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
 608 ], [
 609   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
 610 ])
 611
 612
 613 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 614         use_libusb1=yes
 615         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 616         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 617                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 618                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 619         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 620         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 621         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 622                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 623   ], [
 624         use_libusb1=no
 625         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 626 ])
 627
 628 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 629
 630 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 631         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 632                 use_hidapi=yes
 633                 break
 634         ],[
 635                 use_hidapi=no
 636         ])
 637 done
 638
 639 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 640         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 641 ])
 642
 643 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 644         [use_libjaylink=yes], [use_libjaylink=no])
 645
 646 m4_define([PROCESS_ADAPTERS], [
 647   m4_foreach([adapter], [$1], [
 648         AS_IF([test "x$build_zy1000" = "xyes"], [
 649                 ADAPTER_VAR([adapter])=no
 650         ])
 651         AS_IF([test $2], [
 652                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 653                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 654                 ], [
 655                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 656                 ])
 657         ], [
 658                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 659                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 660                 ])
 661                 ADAPTER_VAR([adapter])=no
 662         ])
 663         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 664   ])
 665 ])
 666
 667 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 668 PROCESS_ADAPTERS([USB_ADAPTERS], ["x$use_libusb1" = "xyes" -o "x$use_libusb0" = "xyes"], [libusb-1.x or libusb-0.1])
 669 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 670 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 671 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 672 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 673 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 674
 675 AS_IF([test "x$build_openjtag" = "xyes"], [
 676   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 677     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 678     build_openjtag=no
 679   ])
 680 ])
 681
 682 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
 683         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 684 ], [
 685         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 686 ])
 687 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
 688
 689 AS_IF([test "x$enable_jlink" != "xno"], [
 690   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 691     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 692       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 693                 [--enable-subproject-build])
 694     ], [
 695       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 696     ])
 697   ])
 698 ])
 699
 700 # Presto needs the bitq module
 701 AS_IF([test "x$enable_presto" != "xno"], [
 702   build_bitq=yes
 703 ])
 704
 705 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 706 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 707 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 708 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 709 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 710 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 711 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 712 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 713 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 714 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 715 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 716 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 717 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 718 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 719 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 720 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 721 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 722 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 723 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 724 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 725 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 726 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 727 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 728 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 729 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 730 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 731 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 732 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 733 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 734 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 735 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 736 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
 737
 738 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 739 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 740
 741 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 742 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 743
 744 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 745 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 746 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 747 #define _GNU_SOURCE
 748 #include <unistd.h>
 749 #include <stdlib.h>
 750   ]], [[char **ep = environ;]]
 751   )], [
 752     AC_MSG_RESULT([yes])
 753     has_environ=yes
 754   ], [
 755     AC_MSG_RESULT([no])
 756
 757     # Possibility #2: can environ be found in an available library?
 758     AC_MSG_CHECKING([for extern environ])
 759     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 760     extern char **environ;
 761     ]], [[char **ep = environ;]]
 762       )], [
 763         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 764         has_environ=yes
 765       ], [
 766         has_environ=no
 767       ])
 768     AC_MSG_RESULT([${has_environ}])
 769   ])
 770
 771 AS_IF([test "x${has_environ}" != "xyes" ], [
 772   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 773 ])
 774
 775 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 776
 777 # set default gcc warnings
 778 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 779 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 780   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 781   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 782   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 783   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 784 ])
 785 AS_IF([test "x${gcc_werror}" = "xyes"], [
 786   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 787 ])
 788
 789 # override default gcc cflags
 790 AS_IF([test "x$gcc_warnings" = "xyes"], [
 791   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 792 ])
 793
 794 AC_CONFIG_FILES([
 795   Makefile
 796 ])
 797 AC_OUTPUT
 798
 799 echo
 800 echo
 801 echo OpenOCD configuration summary
 802 echo --------------------------------------------------
 803 m4_foreach([adapter], [USB1_ADAPTERS, USB_ADAPTERS, USB0_ADAPTERS,
 804         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 805         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 806         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 807         AS_CASE([$ADAPTER_VAR([adapter])],
 808                 [auto], [
 809                         echo "$s"yes '(auto)'
 810                 ],
 811                 [yes], [
 812                         echo "$s"yes
 813                 ],
 814                 [no], [
 815                         echo "$s"no
 816         ])
 817 ])
 818 echo
 819
 820 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 821   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 822   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 823   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 824   echo
 825 ])
 826
 827 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 828   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 829   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 830   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 831   echo 'Mailing List.'
 832   echo
 833 ])
 834
 835 AS_IF([test "x$build_ioutil" = "xyes"], [
 836   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 837   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 838   echo 'release. If you regularly depend on this functionality, please report to the'
 839   echo 'OpenOCD Mailing List.'
 840   echo
 841 ])