git.gag.com Git - debian/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.13.94], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([config])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_PROG_YACC
  33 AC_SYS_LARGEFILE
  34 AC_ISC_POSIX
  35 AC_C_INLINE
  36
  37 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  38   sgtty.h string.h \
  39   sys/buf.h sys/device.h sys/gentape.h \
  40   sys/inet.h sys/io/trioctl.h \
  41   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  42   unistd.h)
  43
  44 AC_HEADER_SYS_WAIT
  45 AM_STDBOOL_H
  46
  47 if test $ac_cv_header_sys_mtio_h = yes; then
  48   AC_CACHE_CHECK(for remote tape header files, tar_cv_header_rmt,
  49     [AC_TRY_CPP([
  50 #if HAVE_SGTTY_H
  51 # include <sgtty.h>
  52 #endif
  53 #include <sys/socket.h>],
  54     tar_cv_header_rmt=yes, tar_cv_header_rmt=no)])
  55   test $tar_cv_header_rmt = yes && RMT='rmt$(EXEEXT)'
  56   AC_SUBST(RMT)
  57 fi
  58
  59 AC_CACHE_CHECK(which ioctl field to test for reversed bytes,
  60   tar_cv_header_mtio_check_field,
  61   [AC_EGREP_HEADER(mt_model, sys/mtio.h,
  62   tar_cv_header_mtio_check_field=mt_model,
  63   tar_cv_header_mtio_check_field=mt_type)])
  64 AC_DEFINE_UNQUOTED(MTIO_CHECK_FIELD, $tar_cv_header_mtio_check_field,
  65   [Define to mt_model (v.g., for DG/UX), else to mt_type.])
  66
  67 AC_HEADER_DIRENT
  68 AC_HEADER_MAJOR
  69 AC_HEADER_STAT
  70 AC_HEADER_STDC
  71 AC_STRUCT_ST_BLKSIZE
  72 AC_STRUCT_ST_BLOCKS
  73 AC_MSG_CHECKING([for st_fstype string in struct stat])
  74 AC_CACHE_VAL(diff_cv_st_fstype_string,
  75   [AC_TRY_COMPILE([#include <sys/types.h>
  76 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  77    diff_cv_st_fstype_string=yes,
  78    diff_cv_st_fstype_string=no)])
  79 AC_MSG_RESULT($diff_cv_st_fstype_string)
  80 if test $diff_cv_st_fstype_string = yes; then
  81   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  82     [Define if struct stat has a char st_fstype[] member.])
  83 fi
  84
  85 AC_TYPE_SIGNAL
  86 AC_TYPE_MODE_T
  87 AC_TYPE_PID_T
  88 AC_TYPE_OFF_T
  89 AC_TYPE_SIZE_T
  90 AC_TYPE_UID_T
  91 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  92                                    [Type of major device numbers.]))
  93 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  94                                    [Type of minor device numbers.]))
  95 AC_CHECK_TYPE(dev_t, unsigned)
  96 AC_CHECK_TYPE(ino_t, unsigned)
  97
  98 gt_TYPE_SSIZE_T
  99 gl_AC_TYPE_INTMAX_T
 100 jm_AC_TYPE_UINTMAX_T
 101
 102 # gnulib modules
 103 tar_GNULIB
 104
 105
 106 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
 107                  [
 108 #include <sys/types.h>
 109 #include <sys/stat.h>])
 110
 111 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
 112 # programs in the package would end up linked with that potentially-shared
 113 # library, inducing unnecessary run-time overhead.
 114
 115 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 116 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 117 tar_save_LIBS=$LIBS
 118   LIB_CLOCK_GETTIME=
 119   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 120   case "$ac_cv_search_clock_gettime" in
 121     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 122   esac
 123   AC_SUBST(LIB_CLOCK_GETTIME)
 124   AC_CHECK_FUNCS(clock_gettime)
 125 LIBS=$tar_save_LIBS
 126
 127 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 128 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 129 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 130 AC_CHECK_DECLS([valloc])
 131 AC_CHECK_DECLS([time],,, [#include <time.h>])
 132
 133 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 134 tar_save_LIBS=$LIBS
 135   LIB_SETSOCKOPT=
 136   AC_SEARCH_LIBS(setsockopt, [socket], ,
 137     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 138   AC_SEARCH_LIBS(setsockopt, [nsl])
 139
 140   case "$ac_cv_search_setsockopt" in
 141     -l*) LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 142   esac
 143   AC_SUBST(LIB_SETSOCKOPT)
 144 LIBS=$tar_save_LIBS
 145
 146 AC_REPLACE_FUNCS(waitpid)
 147
 148 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 149   [if test -n "$RSH"; then
 150     tar_cv_path_RSH=$RSH
 151   else
 152     tar_cv_path_RSH=no
 153     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 154         /usr/bin/nsh /usr/bin/rcmd
 155     do
 156       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 157       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 158       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 159       if test -f $ac_file; then
 160         if (test -h $ac_file) 2>/dev/null; then
 161           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 162         else
 163           tar_cv_path_RSH=$ac_file
 164           break
 165         fi
 166       fi
 167     done
 168   fi])
 169 if test $tar_cv_path_RSH = no; then
 170   AC_CHECK_HEADERS(netdb.h)
 171 else
 172   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 173     [Define to the full path of your rsh, if any.])
 174 fi
 175
 176 AC_MSG_CHECKING(for default archive format)
 177
 178 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 179            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 180
 181 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 182   DEFAULT_ARCHIVE_FORMAT="GNU"
 183 fi
 184 case $DEFAULT_ARCHIVE_FORMAT in
 185   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 186   *) AC_MSG_ERROR(Invalid format name);;
 187 esac
 188 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 189   [By default produce archives of this format])
 190 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 191
 192 AC_MSG_CHECKING(for default archive)
 193
 194 AC_ARG_VAR([DEFAULT_ARCHIVE],
 195            [Set the name of the default archive (default: -)])
 196 if test -z "$DEFAULT_ARCHIVE"; then
 197   DEFAULT_ARCHIVE=-
 198 else
 199   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 200     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 201   fi
 202   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 203   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 204   # FIXME: Rearrange, here.
 205   case $DEFAULT_ARCHIVE in
 206     *[[0-7][lmh]])
 207       AC_DEFINE(DENSITY_LETTER, 1,
 208         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 209       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 210       ;;
 211     *[[0-7]])
 212       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 213       ;;
 214     *)
 215       device_prefix=
 216       ;;
 217   esac
 218   case "$device_prefix" in
 219     ?*)
 220       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 221         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 222       ;;
 223   esac
 224 fi
 225 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 226   [Define to a string giving the full name of the default archive file.])
 227 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 228
 229 AC_ARG_VAR([DEFAULT_BLOCKING],
 230            [Define default blocking factor (default: 20)])
 231 AC_MSG_CHECKING(for default blocking)
 232 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 233 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 234   [Define to a number giving the default blocking size for archives.])
 235 AC_MSG_RESULT($DEFAULT_BLOCKING)
 236
 237 AC_ARG_VAR([DEFAULT_RMT_COMMAND],
 238            [Define full pathname of rmt program.])
 239 if test "x$DEFAULT_RMT_COMMAND" != x; then
 240   AC_DEFINE_UNQUOTED(DEFAULT_RMT_COMMAND, "$DEFAULT_RMT_COMMAND",
 241                      [Define full pathname of rmt program.])
 242 fi
 243
 244 # Gettext.
 245 AM_GNU_GETTEXT([external], [need-ngettext])
 246 AM_GNU_GETTEXT_VERSION(0.12.1)
 247
 248 # Iconv
 249 AM_ICONV
 250 AC_CHECK_HEADERS(iconv.h)
 251 AC_CHECK_TYPE(iconv_t,:,
 252               AC_DEFINE(iconv_t, int,
 253                         [Conversion descriptor type]),
 254               [
 255 #ifdef HAVE_ICONV_H
 256 # include <iconv.h>
 257 #endif
 258 ])
 259
 260 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 261 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 262 AC_ARG_ENABLE(backup-scripts,
 263               AC_HELP_STRING([--enable-backup-scripts],
 264                              [Create and install backup and restore scripts]),
 265               [case $enableval in
 266                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 267                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 268                     ;;
 269                esac])
 270
 271 AC_SUBST(BACKUP_SED_COND)
 272 if date +%Y-%m-%d 2>/dev/null >&2; then
 273         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 274 else
 275         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 276 fi
 277
 278
 279 AC_OUTPUT([Makefile\
 280            doc/Makefile\
 281            lib/Makefile\
 282            po/Makefile.in\
 283            scripts/Makefile\
 284            src/Makefile\
 285            tests/Makefile\
 286            tests/preset])