git.gag.com Git - debian/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.15.2], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_PROG_YACC
  33 AC_SYS_LARGEFILE
  34 AC_ISC_POSIX
  35 AC_C_INLINE
  36
  37 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  38   sgtty.h string.h \
  39   sys/param.h sys/device.h sys/gentape.h \
  40   sys/inet.h sys/io/trioctl.h \
  41   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  42   unistd.h locale.h)
  43
  44 AC_CHECK_HEADERS([sys/buf.h], [], [],
  45 [#if HAVE_SYS_PARAM_H
  46 #include <sys/param.h>
  47 #endif])
  48
  49 AC_HEADER_SYS_WAIT
  50 AM_STDBOOL_H
  51
  52 AC_HEADER_DIRENT
  53 AC_HEADER_MAJOR
  54 AC_HEADER_STAT
  55 AC_HEADER_STDC
  56 AC_STRUCT_ST_BLKSIZE
  57 AC_STRUCT_ST_BLOCKS
  58 AC_MSG_CHECKING([for st_fstype string in struct stat])
  59 AC_CACHE_VAL(diff_cv_st_fstype_string,
  60   [AC_TRY_COMPILE([#include <sys/types.h>
  61 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  62    diff_cv_st_fstype_string=yes,
  63    diff_cv_st_fstype_string=no)])
  64 AC_MSG_RESULT($diff_cv_st_fstype_string)
  65 if test $diff_cv_st_fstype_string = yes; then
  66   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  67     [Define if struct stat has a char st_fstype[] member.])
  68 fi
  69
  70 AC_TYPE_SIGNAL
  71 AC_TYPE_MODE_T
  72 AC_TYPE_PID_T
  73 AC_TYPE_OFF_T
  74 AC_TYPE_SIZE_T
  75 AC_TYPE_UID_T
  76 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  77                                    [Type of major device numbers.]))
  78 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  79                                    [Type of minor device numbers.]))
  80 AC_CHECK_TYPE(dev_t, unsigned)
  81 AC_CHECK_TYPE(ino_t, unsigned)
  82
  83 gt_TYPE_SSIZE_T
  84 gl_AC_TYPE_INTMAX_T
  85 jm_AC_TYPE_UINTMAX_T
  86
  87 # gnulib modules
  88 tar_GNULIB
  89 # paxutils modules
  90 tar_PAXUTILS
  91
  92 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
  93                  [
  94 #include <sys/types.h>
  95 #include <sys/stat.h>])
  96
  97 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
  98 # programs in the package would end up linked with that potentially-shared
  99 # library, inducing unnecessary run-time overhead.
 100
 101 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 102 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 103 tar_save_LIBS=$LIBS
 104   LIB_CLOCK_GETTIME=
 105   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 106   case "$ac_cv_search_clock_gettime" in
 107     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 108   esac
 109   AC_SUBST(LIB_CLOCK_GETTIME)
 110   AC_CHECK_FUNCS(clock_gettime)
 111 LIBS=$tar_save_LIBS
 112
 113 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 114 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 115 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 116 AC_CHECK_DECLS([time],,, [#include <time.h>])
 117
 118 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 119 tar_save_LIBS=$LIBS
 120   LIB_SETSOCKOPT=
 121   AC_SEARCH_LIBS(setsockopt, [socket], ,
 122     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 123   AC_SEARCH_LIBS(setsockopt, [nsl])
 124
 125   case "$ac_cv_search_setsockopt" in
 126     -l*) LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 127   esac
 128   AC_SUBST(LIB_SETSOCKOPT)
 129 LIBS=$tar_save_LIBS
 130
 131 AC_REPLACE_FUNCS(waitpid)
 132
 133 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 134   [if test -n "$RSH"; then
 135     tar_cv_path_RSH=$RSH
 136   else
 137     tar_cv_path_RSH=no
 138     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 139         /usr/bin/nsh /usr/bin/rcmd
 140     do
 141       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 142       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 143       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 144       if test -f $ac_file; then
 145         if (test -h $ac_file) 2>/dev/null; then
 146           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 147         else
 148           tar_cv_path_RSH=$ac_file
 149           break
 150         fi
 151       fi
 152     done
 153   fi])
 154 if test $tar_cv_path_RSH = no; then
 155   AC_CHECK_HEADERS(netdb.h)
 156 else
 157   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 158     [Define to the full path of your rsh, if any.])
 159 fi
 160
 161 AC_MSG_CHECKING(for default archive format)
 162
 163 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 164            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 165
 166 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 167   DEFAULT_ARCHIVE_FORMAT="GNU"
 168 fi
 169 case $DEFAULT_ARCHIVE_FORMAT in
 170   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 171   *) AC_MSG_ERROR(Invalid format name);;
 172 esac
 173 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 174   [By default produce archives of this format])
 175 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 176
 177 AC_MSG_CHECKING(for default archive)
 178
 179 AC_ARG_VAR([DEFAULT_ARCHIVE],
 180            [Set the name of the default archive (default: -)])
 181 if test -z "$DEFAULT_ARCHIVE"; then
 182   DEFAULT_ARCHIVE=-
 183 else
 184   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 185     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 186   fi
 187   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 188   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 189   # FIXME: Rearrange, here.
 190   case $DEFAULT_ARCHIVE in
 191     *[[0-7][lmh]])
 192       AC_DEFINE(DENSITY_LETTER, 1,
 193         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 194       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 195       ;;
 196     *[[0-7]])
 197       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 198       ;;
 199     *)
 200       device_prefix=
 201       ;;
 202   esac
 203   case "$device_prefix" in
 204     ?*)
 205       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 206         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 207       ;;
 208   esac
 209 fi
 210 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 211   [Define to a string giving the full name of the default archive file.])
 212 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 213
 214 AC_ARG_VAR([DEFAULT_BLOCKING],
 215            [Define default blocking factor (default: 20)])
 216 AC_MSG_CHECKING(for default blocking)
 217 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 218 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 219   [Define to a number giving the default blocking size for archives.])
 220 AC_MSG_RESULT($DEFAULT_BLOCKING)
 221
 222 # Iconv
 223 AM_ICONV
 224 AC_CHECK_HEADERS(iconv.h)
 225 AC_CHECK_TYPE(iconv_t,:,
 226               AC_DEFINE(iconv_t, int,
 227                         [Conversion descriptor type]),
 228               [
 229 #ifdef HAVE_ICONV_H
 230 # include <iconv.h>
 231 #endif
 232 ])
 233
 234 # Gettext.
 235 AM_GNU_GETTEXT([external], [need-ngettext])
 236 AM_GNU_GETTEXT_VERSION(0.12.1)
 237
 238 # Initialize the test suite.
 239 AC_CONFIG_TESTDIR(tests)
 240 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 241 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 242
 243 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 244 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 245 AC_ARG_ENABLE(backup-scripts,
 246               AC_HELP_STRING([--enable-backup-scripts],
 247                              [Create and install backup and restore scripts]),
 248               [case $enableval in
 249                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 250                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 251                     ;;
 252                esac])
 253
 254 AC_SUBST(BACKUP_SED_COND)
 255 if date +%Y-%m-%d 2>/dev/null >&2; then
 256         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 257 else
 258         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 259 fi
 260
 261
 262 AC_OUTPUT([Makefile\
 263            doc/Makefile\
 264            lib/Makefile\
 265            po/Makefile.in\
 266            scripts/Makefile\
 267            rmt/Makefile\
 268            src/Makefile])