git.gag.com Git - fw/openocd/blob - configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5 AC_CONFIG_AUX_DIR([.])
   6
   7 m4_include([config_subdir.m4])dnl
   8
   9 # check for makeinfo before calling AM_INIT_AUTOMAKE
  10 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  11 AS_IF([test "x$MAKEINFO" = "x"], [
  12   MAKEINFO='echo makeinfo missing; true'
  13   AC_MSG_WARN([Info documentation will not be built.])
  14 ])
  15 AC_SUBST([MAKEINFO])
  16
  17 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20 AH_BOTTOM([
  21 #include <helper/system.h>
  22 #include <helper/types.h>
  23 #include <helper/replacements.h>
  24 ])
  25
  26 AC_LANG([C])
  27 AC_PROG_CC
  28 AC_PROG_CC_C99
  29 AM_PROG_CC_C_O
  30 AC_PROG_RANLIB
  31 PKG_PROG_PKG_CONFIG([0.23])
  32
  33 dnl disable checks for C++, Fortran and GNU Java Compiler
  34 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  36 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  37 AC_DISABLE_SHARED
  38 LT_INIT
  39 AC_SUBST([LIBTOOL_DEPS])
  40
  41 dnl configure checks required for Jim files (these are obsolete w/ C99)
  42 AC_C_CONST
  43 AC_TYPE_LONG_LONG_INT
  44
  45 AC_SEARCH_LIBS([ioperm], [ioperm])
  46 AC_SEARCH_LIBS([dlopen], [dl])
  47 AC_SEARCH_LIBS([openpty], [util])
  48
  49 AC_CHECK_HEADERS([sys/socket.h])
  50 AC_CHECK_HEADERS([elf.h])
  51 AC_CHECK_HEADERS([dirent.h])
  52 AC_CHECK_HEADERS([fcntl.h])
  53 AC_CHECK_HEADERS([malloc.h])
  54 AC_CHECK_HEADERS([netdb.h])
  55 AC_CHECK_HEADERS([poll.h])
  56 AC_CHECK_HEADERS([pthread.h])
  57 AC_CHECK_HEADERS([strings.h])
  58 AC_CHECK_HEADERS([sys/ioctl.h])
  59 AC_CHECK_HEADERS([sys/param.h])
  60 AC_CHECK_HEADERS([sys/select.h])
  61 AC_CHECK_HEADERS([sys/stat.h])
  62 AC_CHECK_HEADERS([sys/sysctl.h])
  63 AC_CHECK_HEADERS([sys/time.h])
  64 AC_CHECK_HEADERS([sys/types.h])
  65 AC_CHECK_HEADERS([unistd.h])
  66 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  67 #include <stdio.h>
  68 #ifdef STDC_HEADERS
  69 # include <stdlib.h>
  70 # include <stddef.h>
  71 #else
  72 # ifdef HAVE_STDLIB_H
  73 #  include <stdlib.h>
  74 # endif
  75 #endif
  76 #ifdef HAVE_SYS_SOCKET_H
  77 # include <sys/socket.h>
  78 #endif
  79 ])
  80
  81 AC_HEADER_ASSERT
  82 AC_HEADER_STDBOOL
  83 AC_HEADER_TIME
  84
  85 AC_C_BIGENDIAN
  86
  87 AC_CHECK_FUNCS([strndup])
  88 AC_CHECK_FUNCS([strnlen])
  89 AC_CHECK_FUNCS([gettimeofday])
  90 AC_CHECK_FUNCS([usleep])
  91 AC_CHECK_FUNCS([vasprintf])
  92 AC_CHECK_FUNCS([realpath])
  93
  94 # guess-rev.sh only exists in the repository, not in the released archives
  95 AC_MSG_CHECKING([whether to build a release])
  96 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  97   build_release=no
  98 ], [
  99   build_release=yes
 100 ])
 101 AC_MSG_RESULT([$build_release])
 102
 103 # Adapter drivers
 104 # 1st column -- configure option
 105 # 2nd column -- description
 106 # 3rd column -- symbol used for both config.h and automake
 107 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 108 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 109 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 110 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 111 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 112
 113 m4_define([USB1_ADAPTERS],
 114         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 115         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 116         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 117         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 118         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 119         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 120         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 121         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 122         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 123         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 124         [[aice], [Andes JTAG Programmer], [AICE]]])
 125
 126 m4_define([USB0_ADAPTERS],
 127         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 128         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 129         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 130
 131 m4_define([HIDAPI_ADAPTERS],
 132         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]],
 133         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 134
 135 m4_define([HIDAPI_USB1_ADAPTERS],
 136         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 137
 138 m4_define([LIBFTDI_ADAPTERS],
 139         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 140         [[presto], [ASIX Presto Adapter], [PRESTO]],
 141         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 142
 143 m4_define([LIBGPIOD_ADAPTERS],
 144         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 145
 146 m4_define([LIBJAYLINK_ADAPTERS],
 147         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 148
 149 m4_define([PCIE_ADAPTERS],
 150         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 151
 152
 153 AC_ARG_ENABLE([doxygen-html],
 154   AS_HELP_STRING([--disable-doxygen-html],
 155     [Disable building Doxygen manual as HTML.]),
 156   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 157 AC_SUBST([doxygen_as_html])
 158 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 159 AC_MSG_RESULT([$doxygen_as_html])
 160
 161 AC_ARG_ENABLE([doxygen-pdf],
 162   AS_HELP_STRING([--enable-doxygen-pdf],
 163     [Enable building Doxygen manual as PDF.]),
 164   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 165 AC_SUBST([doxygen_as_pdf])
 166 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 167 AC_MSG_RESULT([$doxygen_as_pdf])
 168
 169 AC_ARG_ENABLE([gccwarnings],
 170   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 171   [gcc_warnings=$enableval], [gcc_warnings=yes])
 172
 173 AC_ARG_ENABLE([wextra],
 174   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 175   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 176
 177 AC_ARG_ENABLE([werror],
 178   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 179   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 180
 181 # set default verbose options, overridden by following options
 182 debug_usb_io=no
 183 debug_usb_comms=no
 184
 185 AC_ARG_ENABLE([verbose],
 186   AS_HELP_STRING([--enable-verbose],
 187       [Enable verbose JTAG I/O messages (for debugging).]),
 188   [
 189   debug_usb_io=$enableval
 190   debug_usb_comms=$enableval
 191   ], [])
 192
 193 AC_ARG_ENABLE([verbose_usb_io],
 194   AS_HELP_STRING([--enable-verbose-usb-io],
 195       [Enable verbose USB I/O messages (for debugging)]),
 196   [debug_usb_io=$enableval], [])
 197
 198 AC_ARG_ENABLE([verbose_usb_comms],
 199   AS_HELP_STRING([--enable-verbose-usb-comms],
 200       [Enable verbose USB communication messages (for debugging)]),
 201   [debug_usb_comms=$enableval], [])
 202
 203 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 204 AC_MSG_RESULT([$debug_usb_io])
 205 AS_IF([test "x$debug_usb_io" = "xyes"], [
 206   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 207 ])
 208
 209 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 210 AC_MSG_RESULT([$debug_usb_comms])
 211 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 212   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 213 ])
 214
 215 debug_malloc=no
 216 AC_ARG_ENABLE([malloc_logging],
 217   AS_HELP_STRING([--enable-malloc-logging],
 218       [Include free space in logging messages (requires malloc.h).]),
 219   [debug_malloc=$enableval], [])
 220
 221 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 222 AC_MSG_RESULT([$debug_malloc])
 223 AS_IF([test "x$debug_malloc" = "xyes"], [
 224   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 225 ])
 226
 227 AC_ARG_ENABLE([dummy],
 228   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 229   [build_dummy=$enableval], [build_dummy=no])
 230
 231 AC_ARG_ENABLE([rshim],
 232   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 233   [build_rshim=$enableval], [build_rshim=no])
 234
 235 m4_define([AC_ARG_ADAPTERS], [
 236   m4_foreach([adapter], [$1],
 237         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 238                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 239                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 240                 [], [ADAPTER_VAR([adapter])=$2])
 241   ])
 242 ])
 243
 244 AC_ARG_ADAPTERS([
 245   USB1_ADAPTERS,
 246   USB0_ADAPTERS,
 247   HIDAPI_ADAPTERS,
 248   HIDAPI_USB1_ADAPTERS,
 249   LIBFTDI_ADAPTERS,
 250   LIBGPIOD_ADAPTERS,
 251   LIBJAYLINK_ADAPTERS
 252   ],[auto])
 253
 254 AC_ARG_ENABLE([parport],
 255   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 256   [build_parport=$enableval], [build_parport=no])
 257
 258 AC_ARG_ENABLE([parport_ppdev],
 259   AS_HELP_STRING([--disable-parport-ppdev],
 260       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 261     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 262
 263 AC_ARG_ENABLE([parport_giveio],
 264     AS_HELP_STRING([--enable-parport-giveio],
 265       [Enable use of giveio for parport (for CygWin only)]),
 266     [parport_use_giveio=$enableval], [parport_use_giveio=])
 267
 268 AC_ARG_ENABLE([jtag_vpi],
 269   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 270   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 271
 272 AC_ARG_ENABLE([jtag_dpi],
 273   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 274   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 275
 276 AC_ARG_ENABLE([amtjtagaccel],
 277   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 278   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 279
 280 AC_ARG_ENABLE([zy1000_master],
 281   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 282   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 283
 284 AC_ARG_ENABLE([zy1000],
 285   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 286   [build_zy1000=$enableval], [build_zy1000=no])
 287
 288 AC_ARG_ENABLE([ioutil],
 289   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 290   [build_ioutil=$enableval], [build_ioutil=no])
 291
 292 AS_CASE(["${host_cpu}"],
 293   [arm*|aarch64], [
 294     AC_ARG_ENABLE([bcm2835gpio],
 295       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 296       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 297     AC_ARG_ENABLE([imx_gpio],
 298       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 299       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 300   ],
 301   [
 302     build_bcm2835gpio=no
 303     build_imx_gpio=no
 304 ])
 305
 306 AS_CASE(["${host_cpu}"],
 307   [arm*], [
 308     AC_ARG_ENABLE([ep93xx],
 309       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 310       [build_ep93xx=$enableval], [build_ep93xx=no])
 311
 312     AC_ARG_ENABLE([at91rm9200],
 313       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 314       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 315   ],
 316   [
 317     build_ep93xx=no
 318     build_at91rm9200=no
 319 ])
 320
 321 AC_ARG_ENABLE([gw16012],
 322   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 323   [build_gw16012=$enableval], [build_gw16012=no])
 324
 325 AC_ARG_ENABLE([oocd_trace],
 326   AS_HELP_STRING([--enable-oocd_trace],
 327   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 328   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 329
 330 AC_ARG_ENABLE([buspirate],
 331   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 332   [build_buspirate=$enableval], [build_buspirate=no])
 333
 334 AC_ARG_ENABLE([sysfsgpio],
 335   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 336   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 337
 338 AC_ARG_ENABLE([xlnx_pcie_xvc],
 339   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 340   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 341
 342 AS_CASE([$host_os],
 343   [linux*], [],
 344   [
 345     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 346       AC_MSG_ERROR([sysfsgpio is only available on linux])
 347     ])
 348
 349     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 350       AC_MSG_ERROR([linuxgpiod is only available on linux])
 351     ])
 352
 353     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 354       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 355     ])
 356
 357     AS_CASE([$host_os], [freebsd*], [],
 358     [
 359       AS_IF([test "x$build_rshim" = "xyes"], [
 360         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 361       ])
 362     ])
 363 ])
 364
 365 AC_ARG_ENABLE([minidriver_dummy],
 366   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 367   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 368
 369 AC_ARG_ENABLE([internal-jimtcl],
 370   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 371   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 372
 373 AC_ARG_ENABLE([internal-libjaylink],
 374   AS_HELP_STRING([--disable-internal-libjaylink],
 375   [Disable building internal libjaylink]),
 376   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 377
 378 build_minidriver=no
 379 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 380 AS_IF([test "x$build_zy1000" = "xyes"], [
 381   AS_IF([test "x$build_minidriver" = "xyes"], [
 382     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 383   ])
 384   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 385       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 386   build_minidriver=yes
 387 ])
 388 AC_MSG_RESULT([$build_zy1000])
 389
 390 AC_ARG_ENABLE([remote-bitbang],
 391   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 392   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 393
 394 AC_MSG_CHECKING([whether to enable dummy minidriver])
 395 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 396   AS_IF([test "x$build_minidriver" = "xyes"], [
 397     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 398   ])
 399   build_minidriver=yes
 400   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 401   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 402       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 403 ])
 404 AC_MSG_RESULT([$build_minidriver_dummy])
 405
 406 AC_MSG_CHECKING([whether standard drivers can be built])
 407 AS_IF([test "x$build_minidriver" = "xyes"], [
 408   AC_MSG_RESULT([no])
 409   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 410   sleep 2
 411 ], [
 412   AC_MSG_RESULT([yes])
 413 ])
 414
 415 AS_CASE(["${host_cpu}"],
 416   [i?86|x86*], [],
 417   [
 418     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 419       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 420     ])
 421     parport_use_ppdev=yes
 422 ])
 423
 424 AS_CASE([$host],
 425   [*-cygwin*], [
 426     is_win32=yes
 427     parport_use_ppdev=no
 428
 429     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 430       [is_mingw=yes],[is_mingw=no])
 431     AS_IF([test "x$is_mingw" = "xyes"], [
 432       AS_IF([test "x$parport_use_giveio" = "xno"], [
 433         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 434       ])
 435       parport_use_giveio=yes
 436       is_cygwin=no
 437     ], [
 438       is_cygwin=yes
 439       # sys/io.h needed under cygwin for parport access
 440       AS_IF([test "x$build_parport" = "xyes"], [
 441         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 442       ])
 443     ])
 444   ],
 445   [*-mingw* | *-msys*], [
 446     is_mingw=yes
 447     is_win32=yes
 448     parport_use_ppdev=no
 449
 450     AS_IF([test "x$parport_use_giveio" = "xno"], [
 451       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 452     ])
 453     parport_use_giveio=yes
 454
 455     AS_IF([test "x$build_buspirate" = "xyes"], [
 456       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 457     ])
 458
 459     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 460   ],
 461   [*darwin*], [
 462     is_darwin=yes
 463
 464     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 465       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 466     ])
 467     parport_use_giveio=no
 468   ],
 469   [
 470     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 471       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 472     ])
 473     parport_use_giveio=no
 474 ])
 475
 476 AS_IF([test "x$is_cygwin" = "xyes"], [
 477     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 478 ], [
 479     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 480 ])
 481
 482 AS_IF([test "x$is_mingw" = "xyes"], [
 483     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 484 ], [
 485     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 486 ])
 487
 488 AS_IF([test "x$is_win32" = "xyes"], [
 489     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 490 ], [
 491     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 492 ])
 493
 494 AS_IF([test "x$is_darwin" = "xyes"], [
 495     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 496 ], [
 497     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 498 ])
 499
 500 AS_IF([test "x$build_parport" = "xyes"], [
 501   build_bitbang=yes
 502   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 503 ], [
 504   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 505 ])
 506
 507 AS_IF([test "x$build_rshim" = "xyes"], [
 508   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 509 ], [
 510   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 511 ])
 512
 513 AS_IF([test "x$build_dummy" = "xyes"], [
 514   build_bitbang=yes
 515   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 516 ], [
 517   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 518 ])
 519
 520 AS_IF([test "x$build_ep93xx" = "xyes"], [
 521   build_bitbang=yes
 522   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 523 ], [
 524   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 525 ])
 526
 527 AS_IF([test "x$build_zy1000" = "xyes"], [
 528   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 529 ], [
 530   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 531 ])
 532
 533 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 534   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 535 ], [
 536   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 537 ])
 538
 539 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 540   build_bitbang=yes
 541   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 542 ], [
 543   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 544 ])
 545
 546 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 547   build_bitbang=yes
 548   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 549 ], [
 550   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 551 ])
 552
 553 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 554   build_bitbang=yes
 555   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 556 ], [
 557   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 558 ])
 559
 560 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 561   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 562 ], [
 563   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 564 ])
 565
 566 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 567   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 568 ], [
 569   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 570 ])
 571
 572 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 573   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 574 ], [
 575   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 576 ])
 577
 578 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 579   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 580 ], [
 581   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 582 ])
 583
 584
 585 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 586   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 587 ], [
 588   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 589 ])
 590
 591 AS_IF([test "x$build_gw16012" = "xyes"], [
 592   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 593 ], [
 594   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 595 ])
 596
 597 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 598   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 599 ], [
 600   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 601 ])
 602
 603 AS_IF([test "x$build_buspirate" = "xyes"], [
 604   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 605 ], [
 606   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 607 ])
 608
 609 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 610   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 611     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 612   ], [
 613     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 614   ])
 615 ])
 616
 617 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 618   build_bitbang=yes
 619   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 620 ], [
 621   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 622 ])
 623
 624 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 625   build_bitbang=yes
 626   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 627 ], [
 628   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 629 ])
 630
 631 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 632   build_xlnx_pcie_xvc=yes
 633   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 634 ], [
 635   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 636 ])
 637
 638 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 639         use_libusb1=yes
 640         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 641         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 642                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 643                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 644         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 645         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 646         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 647                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 648   ], [
 649         use_libusb1=no
 650         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 651 ])
 652
 653 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 654
 655 PKG_CHECK_MODULES([CAPSTONE], [capstone], [have_capstone=yes],
 656         [have_capstone=no])
 657
 658 AS_IF([test "x$have_capstone" = "xyes"], [
 659   AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have captone disassembly framework.])
 660 ], [
 661   AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have captone disassembly framework.])
 662 ])
 663
 664 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 665         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 666                 use_hidapi=yes
 667                 break
 668         ],[
 669                 use_hidapi=no
 670         ])
 671 done
 672
 673 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 674         use_libftdi=yes
 675         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 676                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 677   ], [
 678         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 679 ])
 680
 681 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 682
 683 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 684         [use_libjaylink=yes], [use_libjaylink=no])
 685
 686 m4_define([PROCESS_ADAPTERS], [
 687   m4_foreach([adapter], [$1], [
 688         AS_IF([test "x$build_zy1000" = "xyes"], [
 689                 ADAPTER_VAR([adapter])=no
 690         ])
 691         AS_IF([test $2], [
 692                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 693                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 694                 ], [
 695                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 696                 ])
 697         ], [
 698                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 699                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 700                 ])
 701                 ADAPTER_VAR([adapter])=no
 702         ])
 703         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 704   ])
 705 ])
 706
 707 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 708 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 709 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 710 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 711 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 712 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 713 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 714
 715 AS_IF([test "x$build_openjtag" = "xyes"], [
 716   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 717     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 718     build_openjtag=no
 719   ])
 720 ])
 721
 722 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 723   build_bitbang=yes
 724 ])
 725
 726 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 727         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 728         AM_CONDITIONAL([HLADAPTER], [true])
 729 ], [
 730         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 731         AM_CONDITIONAL([HLADAPTER], [false])
 732 ])
 733 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 734 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 735 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 736
 737 AS_IF([test "x$enable_jlink" != "xno"], [
 738   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 739     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 740       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 741                 [--enable-subproject-build])
 742     ], [
 743       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 744     ])
 745   ])
 746 ])
 747
 748 # Presto needs the bitq module
 749 AS_IF([test "x$enable_presto" != "xno"], [
 750   build_bitq=yes
 751 ])
 752
 753 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 754 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 755 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 756 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 757 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 758 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 759 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 760 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 761 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 762 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 763 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 764 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 765 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 766 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 767 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 768 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 769 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 770 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 771 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 772 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 773 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 774 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 775 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 776 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 777 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 778 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 779 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 780 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 781 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 782 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 783 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 784 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 785 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 786 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 787 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$have_capstone" = "xyes"])
 788
 789 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 790 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 791
 792 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 793 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 794
 795 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 796 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 797 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 798 #define _GNU_SOURCE
 799 #include <unistd.h>
 800 #include <stdlib.h>
 801   ]], [[char **ep = environ;]]
 802   )], [
 803     AC_MSG_RESULT([yes])
 804     has_environ=yes
 805   ], [
 806     AC_MSG_RESULT([no])
 807
 808     # Possibility #2: can environ be found in an available library?
 809     AC_MSG_CHECKING([for extern environ])
 810     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 811     extern char **environ;
 812     ]], [[char **ep = environ;]]
 813       )], [
 814         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 815         has_environ=yes
 816       ], [
 817         has_environ=no
 818       ])
 819     AC_MSG_RESULT([${has_environ}])
 820   ])
 821
 822 AS_IF([test "x${has_environ}" != "xyes" ], [
 823   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 824 ])
 825
 826 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 827
 828 # set default gcc warnings
 829 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 830 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 831   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 832   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 833   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 834   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 835 ])
 836 AS_IF([test "x${gcc_werror}" = "xyes"], [
 837   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 838 ])
 839
 840 # override default gcc cflags
 841 AS_IF([test "x$gcc_warnings" = "xyes"], [
 842   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 843 ])
 844
 845 AC_CONFIG_FILES([
 846   Makefile
 847 ])
 848 AC_OUTPUT
 849
 850 echo
 851 echo
 852 echo OpenOCD configuration summary
 853 echo --------------------------------------------------
 854 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 855         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 856         LIBGPIOD_ADAPTERS,
 857         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 858         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 859         AS_CASE([$ADAPTER_VAR([adapter])],
 860                 [auto], [
 861                         echo "$s"yes '(auto)'
 862                 ],
 863                 [yes], [
 864                         echo "$s"yes
 865                 ],
 866                 [no], [
 867                         echo "$s"no
 868         ])
 869 ])
 870 echo
 871
 872 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 873   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 874   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 875   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 876   echo
 877 ])
 878
 879 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 880   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 881   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 882   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 883   echo 'Mailing List.'
 884   echo
 885 ])
 886
 887 AS_IF([test "x$build_ioutil" = "xyes"], [
 888   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 889   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 890   echo 'release. If you regularly depend on this functionality, please report to the'
 891   echo 'OpenOCD Mailing List.'
 892   echo
 893 ])