git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.1svn)
  30
  31 dnl add ${prefix}/lib/pkgconfig to the head of the PKG_CONFIG_PATH
  32 if test x${PKG_CONFIG_PATH} = x; then
  33     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig
  34 else
  35     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig:${PKG_CONFIG_PATH}
  36 fi
  37 export PKG_CONFIG_PATH
  38
  39 DEFINES=""
  40 AC_SUBST(DEFINES)
  41
  42 dnl Remember if the user explicity set CXXFLAGS
  43 if test -n "${CXXFLAGS}"; then
  44   user_set_cxxflags=yes
  45 fi
  46
  47 LF_CONFIGURE_CC
  48 LF_CONFIGURE_CXX
  49 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  50
  51 dnl The three macros above are known to override CXXFLAGS if the user
  52 dnl didn't specify them.  Though I'm sure somebody thought this was
  53 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  54 dnl selected files.  Thus we "undo" the damage here...
  55 dnl
  56 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  57 dnl the output of swig use use -O1 if we're using g++.
  58 dnl See Makefile.common for the rest of the magic.
  59 if test "$user_set_cxxflags" != yes; then
  60   autoconf_default_CXXFLAGS="$CXXFLAGS"
  61   CXXFLAGS=""
  62   if test "$GXX" = yes; then
  63     case "$host_cpu" in
  64         powerpc*)
  65            dnl "-O1" is broken on the PPC for some reason
  66            dnl (at least as of g++ 4.1.1)
  67            swig_CXXFLAGS="-g1 -O2"
  68         ;;
  69         *)
  70         swig_CXXFLAGS="-g -O1"
  71         ;;
  72     esac
  73   fi
  74 fi
  75 AC_SUBST(autoconf_default_CXXFLAGS)
  76 AC_SUBST(swig_CXXFLAGS)
  77
  78 LF_SET_WARNINGS
  79 GR_SET_GPROF
  80 GR_SET_PROF
  81 AM_PROG_AS
  82 AC_PROG_LN_S
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PATH_PROG([RM_PROG], [rm])
  86
  87 AC_LIBTOOL_WIN32_DLL
  88 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  89 AC_ENABLE_SHARED        dnl do build shared libraries
  90 AC_DISABLE_STATIC       dnl don't build static libraries
  91 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
  92 GR_FORTRAN
  93
  94 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  95 GR_SCRIPTING
  96
  97 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  98 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
  99
 100 dnl Checks for libraries.
 101 AC_CHECK_LIB(socket,socket)
 102
 103 dnl check for omnithreads (will soon be removed)
 104 GR_OMNITHREAD
 105 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 106 CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
 107
 108 if test x$CXX_FOR_BUILD = x
 109 then
 110   if test x$cross_compiling = xno; then
 111     CXX_FOR_BUILD=${CXX}
 112   else
 113     CXX_FOR_BUILD=g++
 114   fi
 115 fi
 116
 117 AC_SUBST(CXX_FOR_BUILD)
 118
 119 dnl Check for SysV shm (mandatory)
 120 dnl FIXME this is no longer mandatory.  Check the macro.
 121 GR_SYSV_SHM
 122
 123 dnl Checks for header files.
 124 AC_HEADER_STDC
 125 AC_HEADER_SYS_WAIT
 126 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 127 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 128 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h)
 129 AC_CHECK_HEADERS(netinet/in.h)
 130 AC_CHECK_HEADERS(windows.h)
 131
 132 dnl Checks for typedefs, structures, and compiler characteristics.
 133 AC_C_CONST
 134 AC_C_INLINE
 135 AC_TYPE_SIZE_T
 136 AC_HEADER_TIME
 137 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 138 AC_SUBST(GR_ARCH_BIGENDIAN)
 139 AC_STRUCT_TM
 140
 141 dnl Checks for library functions.
 142 AC_FUNC_ALLOCA
 143 AC_FUNC_SETVBUF_REVERSED
 144 AC_FUNC_VPRINTF
 145 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 146 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 147 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 148 AC_CHECK_FUNCS([sched_setaffinity])
 149
 150 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 151 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 152 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 153 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 154 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 155 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 156 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 157 #AC_FUNC_MKTIME
 158
 159 AH_BOTTOM([
 160 #ifndef HAVE_TRUNC
 161 #include <math.h>
 162 inline static double trunc(double x)
 163 {
 164   return x >= 0 ? floor(x) : ceil(x);
 165 }
 166 #endif
 167
 168 #ifndef HAVE_EXP10
 169 #include <math.h>
 170 inline static double exp10(double x)
 171 {
 172   return pow(10.0, x);
 173 }
 174 #endif
 175
 176 #ifdef HAVE_WINDOWS_H
 177 #define NOMINMAX
 178 #endif
 179 ])
 180
 181 GR_CHECK_SHM_OPEN
 182 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 183 GR_CHECK_CREATEFILEMAPPING
 184
 185 dnl Check for Mingw support
 186 GR_PWIN32
 187
 188 dnl Do we have "dot", part of the graphviz package from AT&T?
 189 dnl Doxgen will use it to draw pretty diagrams ;-)
 190 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 191
 192 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 193 AC_SUBST(FFTW3F_LIBS)
 194
 195 dnl conditional build stuff
 196 GR_CHECK_DOXYGEN
 197 GR_SET_MD_CPU
 198
 199 dnl Define where to look for cppunit includes and libs
 200 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 201 dnl Try using pkg-config first, then fall back to cppunit-config.
 202 PKG_CHECK_EXISTS(cppunit,
 203   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 204   [AM_PATH_CPPUNIT([1.9.14],[],
 205                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 206
 207 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 208 AC_SUBST(CPPUNIT_INCLUDES)
 209
 210 dnl see if GUILE is installed
 211 AC_PATH_PROG(GUILE,guile)
 212
 213 dnl
 214 dnl We require the boost headers, thread lib and date_time lib.
 215 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 216 dnl
 217 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 218 AX_BOOST_BASE([1.35])
 219
 220 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 221 AX_BOOST_THREAD
 222 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 223 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 224
 225 dnl
 226 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 227 dnl
 228 AX_BOOST_DATE_TIME
 229 dnl AX_BOOST_FILESYSTEM
 230 dnl AX_BOOST_IOSTREAMS
 231 dnl AX_BOOST_PROGRAM_OPTIONS
 232 dnl AX_BOOST_REGEX
 233 dnl AX_BOOST_SERIALIZATION
 234 dnl AX_BOOST_SIGNALS
 235 dnl AX_BOOST_SYSTEM
 236 dnl AX_BOOST_TEST_EXEC_MONITOR
 237 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 238 dnl AX_BOOST_WSERIALIZATION
 239
 240
 241 dnl If this is being done from a subversion tree, create variables
 242 GR_SUBVERSION
 243
 244 dnl Component specific configuration
 245 dnl The order of the GR_ macros determines the order of compilation
 246 dnl For -any- checks on $enable_all_components
 247 dnl use the following guildlines:
 248 dnl   yes : --enable-all-components was specified, so error out if any
 249 dnl         components do not pass configuration checks.
 250 dnl   no  : --disable-all-components was specified, so try to build the
 251 dnl         --enable'd components, and error out if any do not pass
 252 dnl         configuration checks.
 253 dnl   ""  : this option was not specified on the command line; try to
 254 dnl         build all components that are not --with'd, but don't
 255 dnl         error out if any component does not pass configuration checks.
 256 dnl
 257 dnl For each --enable-foo component, if that flag is not specified on
 258 dnl the command line, the related variable $enable_foo will be set to
 259 dnl $enable_all_components .
 260
 261 AC_ARG_ENABLE(
 262     [all-components],
 263     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 264 )
 265
 266 build_dirs="config"
 267 GRC_GRUEL                       dnl must come first
 268 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 269 GRC_GCELL
 270 GRC_GNURADIO_CORE
 271 GRC_PMT
 272 GRC_MBLOCK                      dnl this must come after GRC_PMT
 273 GRC_USRP
 274 GRC_GR_USRP                     dnl this must come after GRC_USRP
 275 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 276 GRC_GR_MSDD6000
 277 GRC_GR_AUDIO_ALSA
 278 GRC_GR_AUDIO_JACK
 279 GRC_GR_AUDIO_OSS
 280 GRC_GR_AUDIO_OSX
 281 GRC_GR_AUDIO_PORTAUDIO
 282 GRC_GR_AUDIO_WINDOWS
 283 GRC_GR_ATSC
 284 GRC_GR_COMEDI
 285 GRC_GR_CVSD_VOCODER
 286 GRC_GR_GPIO
 287 GRC_GR_GSM_FR_VOCODER
 288 GRC_GR_PAGER
 289 GRC_GR_RADAR_MONO
 290 GRC_GR_RADIO_ASTRONOMY
 291 GRC_GR_TRELLIS
 292 GRC_GR_VIDEO_SDL
 293 GRC_GR_WXGUI
 294 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 295 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 296 GRC_GNURADIO_EXAMPLES           dnl must come last
 297
 298 # Each component is now either to be built, was skipped, will be
 299 # included from pre-installed libraries and includes, or failed
 300 # dependencies.
 301 AC_SUBST([build_dirs], [$build_dirs])
 302 AC_SUBST([skipped_dirs], [$skipped_dirs])
 303 AC_SUBST([with_dirs], [$with_dirs])
 304
 305 # fix for older autotools that don't define "abs_top_YYY" by default
 306 AC_SUBST(abs_top_srcdir)
 307 AC_SUBST(abs_top_builddir)
 308
 309 # 'with' variables - the pre-installed libraries, includes, and paths
 310 # - must always come last in the lists, so they require special
 311 # treatment.
 312 AC_SUBST(with_INCLUDES)
 313 AC_SUBST(with_SWIG_INCLUDES)
 314 AC_SUBST(with_PYDIRPATH)
 315 AC_SUBST(with_SWIGDIRPATH)
 316 AC_SUBST(with_LIBDIRPATH)
 317
 318 # Local files tweaked by AC
 319 AC_CONFIG_FILES([\
 320     Makefile \
 321     run_tests.sh \
 322     config/Makefile \
 323 ])
 324
 325 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 326 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 327
 328 AC_OUTPUT
 329
 330 echo
 331 echo "*********************************************************************"
 332 echo The following GNU Radio components have been successfully configured:
 333 echo
 334 for dir in $build_dirs
 335 do
 336     echo $dir
 337 done
 338 echo
 339 echo You my now run the 'make' command to build these components.
 340 echo
 341 if test "$skipped_dirs" != ""; then
 342     echo "*********************************************************************"
 343     echo The following components were skipped either because you asked not
 344     echo to build them or they didn\'t pass configuration checks:
 345     echo
 346     for dir in $skipped_dirs
 347     do
 348         echo $dir
 349     done
 350     echo
 351     echo These components will not be built.
 352     echo
 353 fi
 354 if test "$with_dirs" != ""; then
 355     echo "*********************************************************************"
 356     echo The following components will be included from pre-installed
 357     echo libraries and includes:
 358     echo
 359     for dir in $with_dirs
 360     do
 361         echo $dir
 362     done
 363     echo
 364     echo These components will not be built.
 365     echo
 366 fi