git.gag.com Git - debian/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 AC_INIT([GNU tar], [1.15.2], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_PROG_YACC
  33 AC_SYS_LARGEFILE
  34 AC_ISC_POSIX
  35 AC_C_INLINE
  36
  37 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  38   sgtty.h string.h \
  39   sys/param.h sys/device.h sys/gentape.h \
  40   sys/inet.h sys/io/trioctl.h \
  41   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  42   unistd.h locale.h)
  43
  44 AC_CHECK_HEADERS([sys/buf.h], [], [],
  45 [#if HAVE_SYS_PARAM_H
  46 #include <sys/param.h>
  47 #endif])
  48
  49 AC_HEADER_SYS_WAIT
  50 AM_STDBOOL_H
  51
  52 AC_HEADER_DIRENT
  53 AC_HEADER_MAJOR
  54 AC_HEADER_STAT
  55 AC_HEADER_STDC
  56
  57 AC_MSG_CHECKING([for st_fstype string in struct stat])
  58 AC_CACHE_VAL(diff_cv_st_fstype_string,
  59   [AC_TRY_COMPILE([#include <sys/types.h>
  60 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  61    diff_cv_st_fstype_string=yes,
  62    diff_cv_st_fstype_string=no)])
  63 AC_MSG_RESULT($diff_cv_st_fstype_string)
  64 if test $diff_cv_st_fstype_string = yes; then
  65   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  66     [Define if struct stat has a char st_fstype[] member.])
  67 fi
  68
  69 AC_TYPE_SIGNAL
  70 AC_TYPE_MODE_T
  71 AC_TYPE_PID_T
  72 AC_TYPE_OFF_T
  73 AC_TYPE_SIZE_T
  74 AC_TYPE_UID_T
  75 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  76                                    [Type of major device numbers.]))
  77 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  78                                    [Type of minor device numbers.]))
  79 AC_CHECK_TYPE(dev_t, unsigned)
  80 AC_CHECK_TYPE(ino_t, unsigned)
  81
  82 gt_TYPE_SSIZE_T
  83 gl_AC_TYPE_INTMAX_T
  84 jm_AC_TYPE_UINTMAX_T
  85
  86 # gnulib modules
  87 tar_GNULIB
  88 # paxutils modules
  89 tar_PAXUTILS
  90
  91 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
  92                  [
  93 #include <sys/types.h>
  94 #include <sys/stat.h>])
  95
  96 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
  97 # programs in the package would end up linked with that potentially-shared
  98 # library, inducing unnecessary run-time overhead.
  99
 100 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 101 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 102 tar_save_LIBS=$LIBS
 103   LIB_CLOCK_GETTIME=
 104   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 105   case "$ac_cv_search_clock_gettime" in
 106     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 107   esac
 108   AC_SUBST(LIB_CLOCK_GETTIME)
 109   AC_CHECK_FUNCS(clock_gettime)
 110 LIBS=$tar_save_LIBS
 111
 112 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 113 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 114 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 115 AC_CHECK_DECLS([time],,, [#include <time.h>])
 116
 117 AC_REPLACE_FUNCS(waitpid)
 118
 119 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 120   [if test -n "$RSH"; then
 121     tar_cv_path_RSH=$RSH
 122   else
 123     tar_cv_path_RSH=no
 124     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 125         /usr/bin/nsh /usr/bin/rcmd
 126     do
 127       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 128       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 129       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 130       if test -f $ac_file; then
 131         if (test -h $ac_file) 2>/dev/null; then
 132           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 133         else
 134           tar_cv_path_RSH=$ac_file
 135           break
 136         fi
 137       fi
 138     done
 139   fi])
 140 if test $tar_cv_path_RSH = no; then
 141   AC_CHECK_HEADERS(netdb.h)
 142 else
 143   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 144     [Define to the full path of your rsh, if any.])
 145 fi
 146
 147 AC_MSG_CHECKING(for default archive format)
 148
 149 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 150            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 151
 152 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 153   DEFAULT_ARCHIVE_FORMAT="GNU"
 154 fi
 155 case $DEFAULT_ARCHIVE_FORMAT in
 156   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 157   *) AC_MSG_ERROR(Invalid format name);;
 158 esac
 159 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 160   [By default produce archives of this format])
 161 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 162
 163 AC_MSG_CHECKING(for default archive)
 164
 165 AC_ARG_VAR([DEFAULT_ARCHIVE],
 166            [Set the name of the default archive (default: -)])
 167 if test -z "$DEFAULT_ARCHIVE"; then
 168   DEFAULT_ARCHIVE=-
 169 else
 170   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 171     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 172   fi
 173   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 174   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 175   # FIXME: Rearrange, here.
 176   case $DEFAULT_ARCHIVE in
 177     *[[0-7][lmh]])
 178       AC_DEFINE(DENSITY_LETTER, 1,
 179         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 180       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 181       ;;
 182     *[[0-7]])
 183       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 184       ;;
 185     *)
 186       device_prefix=
 187       ;;
 188   esac
 189   case "$device_prefix" in
 190     ?*)
 191       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 192         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 193       ;;
 194   esac
 195 fi
 196 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 197   [Define to a string giving the full name of the default archive file.])
 198 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 199
 200 AC_ARG_VAR([DEFAULT_BLOCKING],
 201            [Define default blocking factor (default: 20)])
 202 AC_MSG_CHECKING(for default blocking)
 203 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 204 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 205   [Define to a number giving the default blocking size for archives.])
 206 AC_MSG_RESULT($DEFAULT_BLOCKING)
 207
 208 # Iconv
 209 AM_ICONV
 210 AC_CHECK_HEADERS(iconv.h)
 211 AC_CHECK_TYPE(iconv_t,:,
 212               AC_DEFINE(iconv_t, int,
 213                         [Conversion descriptor type]),
 214               [
 215 #ifdef HAVE_ICONV_H
 216 # include <iconv.h>
 217 #endif
 218 ])
 219
 220 # Gettext.
 221 AM_GNU_GETTEXT([external], [need-ngettext])
 222 AM_GNU_GETTEXT_VERSION(0.12.1)
 223
 224 # Initialize the test suite.
 225 AC_CONFIG_TESTDIR(tests)
 226 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 227 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 228
 229 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 230 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 231 AC_ARG_ENABLE(backup-scripts,
 232               AC_HELP_STRING([--enable-backup-scripts],
 233                              [Create and install backup and restore scripts]),
 234               [case $enableval in
 235                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 236                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 237                     ;;
 238                esac])
 239
 240 AC_SUBST(BACKUP_SED_COND)
 241 if date +%Y-%m-%d 2>/dev/null >&2; then
 242         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 243 else
 244         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 245 fi
 246
 247
 248 AC_OUTPUT([Makefile\
 249            doc/Makefile\
 250            lib/Makefile\
 251            po/Makefile.in\
 252            scripts/Makefile\
 253            rmt/Makefile\
 254            src/Makefile])