git.gag.com Git - debian/gnuradio/blob - config/grc_usrp2.m4

   1 dnl Copyright 2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_DEFUN([GRC_USRP2],[
  21     GRC_ENABLE(usrp2)
  22
  23     dnl Don't do usrp if omnithread or gruel is skipped
  24     GRC_CHECK_DEPENDENCY(usrp2, gruel)
  25     GRC_CHECK_DEPENDENCY(usrp2, omnithread)
  26
  27     dnl USRP2 host code only works on Linux at the moment
  28     AC_MSG_CHECKING([whether host_os is linux*])
  29     case "$host_os" in
  30       linux*)
  31         AC_MSG_RESULT([yes])
  32         ;;
  33       *)
  34         AC_MSG_RESULT([no])
  35         AC_MSG_NOTICE([USRP2 currently requires Linux host OS, not found])
  36         passed="no"
  37         ;;
  38     esac
  39
  40     dnl If execution gets to here, $passed will be:
  41     dnl   with : if the --with code didn't error out
  42     dnl   yes  : if the --enable code passed muster and all dependencies are met
  43     dnl   no   : otherwise
  44     if test $passed = yes; then
  45         dnl Only do firmware if mb-gcc can be found
  46         AC_CHECK_PROG([MB_GCC],[mb-gcc],[yes],[no])
  47         if test $MB_GCC = yes; then
  48             dnl Adds usrp2/firmware to $(subdirs), hierarchical build
  49             AC_CONFIG_SUBDIRS([usrp2/firmware])
  50         else
  51             AC_MSG_WARN([usrp2/firmware is not being built])
  52         fi
  53         AM_CONDITIONAL([BUILDING_USRP2_FIRMWARE],[test $MB_GCC = yes])
  54
  55         dnl Needed for usrp2_socket_opener
  56         AC_CHECK_HEADERS(arpa/inet.h byteswap.h linux/if_packet.h sys/socket.h sys/un.h)
  57         AC_CHECK_MEMBERS([struct msghdr.msg_control,
  58                           struct msghdr.msg_accrights,
  59                           struct cmsgcred.cmcred_uid,
  60                           struct ucred.uid],
  61                          [],[],
  62                          [#define __USE_GNU 1
  63                           #include <sys/types.h>
  64                           #include <sys/socket.h>
  65                           #include <sys/un.h>])
  66     fi
  67     if test $passed != with; then
  68         dnl how and where to find INCLUDES and LA
  69         USRP2_INCLUDES="-I\${abs_top_srcdir}/usrp2/host/include \
  70                 -I\${abs_top_srcdir}/usrp2/firmware/include"
  71         USRP2_LA="\${abs_top_builddir}/usrp2/host/lib/libusrp2.la"
  72     fi
  73
  74     dnl Include the usrp2 INCLUDES and LA
  75     AC_SUBST(USRP2_INCLUDES)
  76     AC_SUBST(USRP2_LA)
  77
  78     AC_CONFIG_FILES([ \
  79         usrp2/Makefile
  80         usrp2/host/Makefile \
  81         usrp2/host/usrp2.pc \
  82         usrp2/host/include/Makefile
  83         usrp2/host/include/usrp2/Makefile
  84         usrp2/host/lib/Makefile
  85         usrp2/host/apps/Makefile
  86     ])
  87
  88     GRC_BUILD_CONDITIONAL(usrp2)
  89 ])