git.gag.com Git - debian/gnuradio/blob - config/grc_usrp.m4

   1 dnl Copyright 2001,2002,2003,2004,2005,2006 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 2, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18 dnl Boston, MA 02111-1307, USA.
  19
  20 AC_DEFUN([GRC_USRP],[
  21     AC_CONFIG_SRCDIR([usrp/host/lib/usrp_prims.h])
  22
  23     AC_CONFIG_FILES([ \
  24         usrp/Makefile                           \
  25         usrp/usrp.pc                            \
  26         usrp/usrp.iss                           \
  27         usrp/doc/Doxyfile                       \
  28         usrp/doc/Makefile                       \
  29         usrp/doc/other/Makefile                 \
  30         usrp/host/Makefile                      \
  31         usrp/host/misc/Makefile                 \
  32         usrp/host/lib/Makefile                  \
  33         usrp/host/lib/std_paths.h               \
  34         usrp/host/swig/Makefile                 \
  35         usrp/host/apps/Makefile                 \
  36         usrp/firmware/Makefile                  \
  37         usrp/firmware/include/Makefile          \
  38         usrp/firmware/lib/Makefile              \
  39         usrp/firmware/src/Makefile              \
  40         usrp/firmware/src/common/Makefile       \
  41         usrp/firmware/src/usrp2/Makefile        \
  42         usrp/fpga/Makefile                      \
  43         usrp/fpga/rbf/Makefile                  \
  44     ])
  45
  46     AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  47     AM_CONDITIONAL(HAS_XMLTO, test x$XMLTO = xyes)
  48
  49     # gnulib.
  50     # FIXME: this needs to fail gracefully and continue, not implemented yet
  51     UTILS_FUNC_MKSTEMP
  52
  53     succeeded=yes
  54     dnl Checks for library functions.
  55     USRP_LIBUSB([],[succeeded=no])
  56     USRP_SET_FUSB_TECHNIQUE([],[succeeded=no])
  57
  58     dnl check for firmware cross compilation tools
  59     dnl check for SDCC 2.4.0
  60     USRP_SDCC([2.4.0],[],[succeeded=no])
  61
  62     AC_CHECK_FUNCS([getrusage sched_setscheduler],[],[succeeded=no])
  63     AC_CHECK_FUNCS([sigaction snprintf],[],[succeeded=no])
  64
  65     dnl we use these to handle possible byteswapping to and from the USRP.
  66     AC_CHECK_HEADERS([byteswap.h],[],[succeeeded=no])
  67     AC_C_BIGENDIAN
  68
  69     if test $succeeded = yes; then
  70         dnl Define where to look for USRP includes
  71         USRP_INCLUDES='-I$(top_srcdir)/usrp/host/lib -I$(top_srcdir)/usrp/firmware/include'
  72         AC_SUBST(USRP_INCLUDES)
  73
  74         USRP_DEFINES=''
  75         AC_SUBST(USRP_DEFINES)
  76
  77         dnl Define where to find USRP library
  78         USRP_LIBS='-L$(top_builddir)/usrp/host/lib -lusrp'
  79         AC_SUBST(USRP_LIBS)
  80
  81         dnl FIXME this looked very suspicious
  82         dnl DEFINES="$USRP_DEFINES"
  83         dnl AC_SUBST(DEFINES)
  84
  85         subdirs="$subdirs usrp"
  86     else
  87         failed="$failed usrp"
  88     fi
  89 ])