git.gag.com Git - debian/gnuradio/blob - config/grc_gr_audio_oss.m4

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_DEFUN([GRC_GR_AUDIO_OSS],[
  21     GRC_ENABLE([gr-audio-oss])
  22
  23     AC_CONFIG_FILES([ \
  24         gr-audio-oss/Makefile \
  25         gr-audio-oss/src/Makefile \
  26         gr-audio-oss/src/run_tests \
  27     ])
  28
  29     passed=yes
  30     # Don't do gr-audio-oss if gnuradio-core skipped
  31     if test x$gnuradio_core_skipped = xyes; then
  32         AC_MSG_RESULT([Component gr-audio-oss requires gnuradio-core, which is not being built or specified via pre-installed files.])
  33         passed=no
  34     fi
  35     # Make sure the correct library and/or headers are available.
  36     case $host in
  37         *-*-netbsd*)
  38             AC_HAVE_LIBRARY(ossaudio,[],
  39                 [passed=no;AC_MSG_RESULT([gr-audio-oss requires library ossaudio, not found.])])
  40             if test x$passed != xno; then
  41                 OSS_LIBS=-lossaudio
  42                 AC_MSG_RESULT([Using OSS library $OSS_LIBS])
  43             fi
  44             ;;
  45         *)
  46             AC_CHECK_HEADER(sys/soundcard.h,[],
  47                 [passed=no;AC_MSG_RESULT([gr-audio-oss requires sys/soundcard.h, not found.])])
  48     esac
  49
  50     GRC_BUILD_CONDITIONAL([gr-audio-oss],[
  51         AC_SUBST(OSS_LIBS)
  52         dnl run_tests is created from run_tests.in.  Make it executable.
  53         AC_CONFIG_COMMANDS([run_tests_oss], [chmod +x gr-audio-oss/src/run_tests])
  54     ])
  55 ])