X-Git-Url: https://git.gag.com/?p=fw%2Faltos;a=blobdiff_plain;f=src%2Fmicropeak-v2.0%2Fmicropeak.ld;fp=src%2Fmicropeak-v2.0%2Fmicropeak.ld;h=77717e168e7eead5f15dda1fc291cb33a12853ce;hp=0000000000000000000000000000000000000000;hb=217d77dadbef4192d2f32e290a5c5f50159f2e0d;hpb=65bb93f69b2f420281b67d62a9ee3cf30874fb7c

diff --git a/src/micropeak-v2.0/micropeak.ld b/src/micropeak-v2.0/micropeak.ld
new file mode 100644
index 00000000..77717e16
--- /dev/null
+++ b/src/micropeak-v2.0/micropeak.ld
@@ -0,0 +1,123 @@
+/*
+ * Copyright © 2012 Keith Packard <keithp@keithp.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful, but
+ * WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License along
+ * with this program; if not, write to the Free Software Foundation, Inc.,
+ * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
+ */
+
+MEMORY {
+	rom (rx) :   ORIGIN = 0x08001000, LENGTH = 20K
+	flash(rx) :  ORIGIN = 0x08006000, LENGTH = 8K
+	ram (!w) :   ORIGIN = 0x20000000, LENGTH = 6k - 128
+	stack (!w) : ORIGIN = 0x20000000 + 6k - 128, LENGTH = 128
+}
+
+INCLUDE registers.ld
+
+EXTERN (stm_interrupt_vector)
+
+SECTIONS {
+	/*
+	 * Rom contents
+	 */
+
+	.interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
+		__interrupt_start__ = .;
+		__interrupt_rom__ = ORIGIN(rom);
+		*(.interrupt)	/* Interrupt vectors */
+		__interrupt_end__ = .;
+	} > ram
+
+	.text ORIGIN(rom) + 0x100 : {
+		__text_start__ = .;
+
+		/* Ick. What I want is to specify the
+		 * addresses of some global constants so
+		 * that I can find them across versions
+		 * of the application. I can't figure out
+		 * how to make gnu ld do that, so instead
+		 * we just load the two files that include
+		 * these defines in the right order here and
+		 * expect things to 'just work'. Don't change
+		 * the contents of those files, ok?
+		 */
+		ao_romconfig.o(.romconfig*)
+		ao_product.o(.romconfig*)
+
+		*(.text*)	/* Executable code */
+	} > rom
+
+	.ARM.exidx : {
+		*(.ARM.exidx* .gnu.linkonce.armexidx.*)
+	} > rom
+
+	.rodata : {
+		*(.rodata*)	/* Constants */
+	} > rom
+
+	__text_end__ = .;
+
+	/* Boot data which must live at the start of ram so that
+	 * the application and bootloader share the same addresses.
+	 * This must be all uninitialized data
+	 */
+	.boot (NOLOAD) : {
+		__boot_start__ = .;
+		*(.boot)
+		. = ALIGN(4);
+		__boot_end__ = .;
+	} >ram
+
+	/* Functions placed in RAM (required for flashing)
+	 *
+	 * Align to 8 bytes as that's what the ARM likes text
+	 * segment alignments to be, and if we don't, then
+	 * we end up with a mismatch between the location in
+	 * ROM and the desired location in RAM. I don't
+	 * entirely understand this, but at least this appears
+	 * to work...
+	 */
+
+	.textram BLOCK(8): {
+		__data_start__ = .;
+		*(.ramtext)
+	} >ram AT>rom
+
+	/* Data -- relocated to RAM, but written to ROM
+	 */
+	.data : {
+		*(.data)	/* initialized data */
+		. = ALIGN(4);
+		__data_end__ = .;
+	} >ram AT>rom
+
+	.bss : {
+		__bss_start__ = .;
+		*(.bss)
+		*(COMMON)
+		. = ALIGN(4);
+		__bss_end__ = .;
+	} >ram
+
+	PROVIDE(end = .);
+
+	PROVIDE(__flash__ = ORIGIN(flash));
+	PROVIDE(__flash_end__ = ORIGIN(flash) + LENGTH(flash));
+
+	PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
+}
+
+ENTRY(start);
+
+