X-Git-Url: https://git.gag.com/?p=fw%2Faltos;a=blobdiff_plain;f=src%2Flambdakey-v1.0%2Flambda.ld;fp=src%2Flambdakey-v1.0%2Flambda.ld;h=0000000000000000000000000000000000000000;hp=b09fdb4ae16115f8b00b46e626534f4258cdb3e1;hb=0686a7b8aec524d81bda4c572549a3a068ce0eed;hpb=6aa451ce81bfdfe679e3f9902043a5f0d235c745

diff --git a/src/lambdakey-v1.0/lambda.ld b/src/lambdakey-v1.0/lambda.ld
deleted file mode 100644
index b09fdb4a..00000000
--- a/src/lambdakey-v1.0/lambda.ld
+++ /dev/null
@@ -1,114 +0,0 @@
-/*
- * Copyright © 2012 Keith Packard <keithp@keithp.com>
- *
- * This program is free software; you can redistribute it and/or modify
- * it under the terms of the GNU General Public License as published by
- * the Free Software Foundation; either version 2 of the License, or
- * (at your option) any later version.
- *
- * This program is distributed in the hope that it will be useful, but
- * WITHOUT ANY WARRANTY; without even the implied warranty of
- * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
- * General Public License for more details.
- *
- * You should have received a copy of the GNU General Public License along
- * with this program; if not, write to the Free Software Foundation, Inc.,
- * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
- */
-
-MEMORY {
-	rom (rx) :   ORIGIN = 0x08001000, LENGTH = 28K
-	ram (!w) :   ORIGIN = 0x20000000, LENGTH = 6k - 1k
-	stack (!w) : ORIGIN = 0x20000000 + 6k - 1k, LENGTH = 1k
-}
-
-INCLUDE registers.ld
-
-EXTERN (stm_interrupt_vector)
-
-SECTIONS {
-	/*
-	 * Rom contents
-	 */
-
-	.interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
-		__interrupt_start__ = .;
-		__interrupt_rom__ = ORIGIN(rom);
-		*(.interrupt)	/* Interrupt vectors */
-		__interrupt_end__ = .;
-	} > ram
-
-	.text ORIGIN(rom) + 0x100 : {
-		__text_start__ = .;
-
-		/* Ick. What I want is to specify the
-		 * addresses of some global constants so
-		 * that I can find them across versions
-		 * of the application. I can't figure out
-		 * how to make gnu ld do that, so instead
-		 * we just load the two files that include
-		 * these defines in the right order here and
-		 * expect things to 'just work'. Don't change
-		 * the contents of those files, ok?
-		 */
-		ao_romconfig.o(.romconfig*)
-		ao_product.o(.romconfig*)
-
-		*(.text*)	/* Executable code */
-		*(.ARM.exidx* .gnu.linkonce.armexidx.*)
-		*(.rodata*)	/* Constants */
-
-	} > rom
-	__text_end__ = .;
-	
-
-	/* Boot data which must live at the start of ram so that
-	 * the application and bootloader share the same addresses.
-	 * This must be all uninitialized data
-	 */
-	.boot (NOLOAD) : {
-		__boot_start__ = .;
-		*(.boot)
-		. = ALIGN(4);
-		__boot_end__ = .;
-	} >ram
-
-	/* Functions placed in RAM (required for flashing)
-	 *
-	 * Align to 8 bytes as that's what the ARM likes text
-	 * segment alignments to be, and if we don't, then
-	 * we end up with a mismatch between the location in
-	 * ROM and the desired location in RAM. I don't
-	 * entirely understand this, but at least this appears
-	 * to work...
-	 */
-
-	.textram BLOCK(8): {
-		__data_start__ = .;
-		__text_ram_start__ = .;
-		*(.ramtext)
-		__text_ram_end = .;
-	} >ram AT>rom
-
-	/* Data -- relocated to RAM, but written to ROM
-	 */
-	.data BLOCK(8): {
-		*(.data)	/* initialized data */
-		. = ALIGN(8);
-		__data_end__ = .;
-	} >ram AT>rom
-
-	.bss : {
-		__bss_start__ = .;
-		*(.bss)
-		*(COMMON)
-		. = ALIGN(4);
-		__bss_end__ = .;
-	} >ram
-
-	PROVIDE(end = .);
-
-	PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
-}
-
-ENTRY(start);