git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.8.7.1)
  22 ANDROID_VERSION=18
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2018-10-08
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=13
  38 ALTOSLIB_VERSION=13
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  68         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  69         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  70
  71 if test "x$JVM_INCLUDE" = "xauto"; then
  72         AC_MSG_CHECKING([JVM include files])
  73         for jvm in default-java java-6-openjdk java-6-sun; do
  74                 if test "x$JVM_INCLUDE" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM_INCLUDE="$INCLUDE"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM_INCLUDE" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM include files found])
  83         fi
  84         AC_MSG_RESULT([$JVM_INCLUDE])
  85 fi
  86
  87 AC_SUBST(JVM_INCLUDE)
  88
  89 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  90         [Set android SDK path (default searches in a variety of places)]),
  91         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  92
  93 if test "x$ANDROID_SDK" = "xauto"; then
  94         AC_MSG_CHECKING([Android SDK])
  95         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  96                 if test "x$ANDROID_SDK" = "xauto"; then
  97                         SDK="$sdk"
  98                         if test -f "$SDK/SDK Readme.txt"; then
  99                                 ANDROID_SDK=`readlink -m "$SDK"`
 100                         fi
 101                 fi
 102         done
 103         if test "x$ANDROID_SDK" = "xauto"; then
 104                 AC_MSG_NOTICE([no Android SDK found])
 105                 ANDROID_SDK=no
 106         fi
 107         AC_MSG_RESULT([$ANDROID_SDK])
 108 fi
 109 if test "x$ANDROID_SDK" != "xno"; then
 110         AC_MSG_CHECKING([Android SDK version])
 111         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 112         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 113         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 114                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 115                 ANDROID_SDK=no
 116         else
 117                 AC_MSG_RESULT([$SDK_VERSION])
 118         fi
 119 fi
 120 if test "x$ANDROID_SDK" != "xno"; then
 121         AC_MSG_CHECKING([Android SDK API Level])
 122         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 123                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 124                 if test "$API_LEVEL" = "10"; then
 125                         AC_MSG_RESULT([$API_LEVEL])
 126                 else
 127                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 128                         ANDROID_SDK=no
 129                 fi
 130         else
 131                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 132                 ANDROID_SDK=no
 133         fi
 134 fi
 135 if test "x$ANDROID_SDK" != "xno"; then
 136         AC_MSG_CHECKING([Android SDK required extras])
 137         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 138                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 139                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 140                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 141                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 142                 else
 143                         AC_MSG_NOTICE([Google Play Services library not installed.])
 144                         ANDROID_SDK=no
 145                 fi
 146         else
 147                 AC_MSG_NOTICE([Android Support Library not installed.])
 148                 ANDROID_SDK=no
 149         fi
 150 fi
 151
 152 ANDROID_RELEASE=no
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         HAVE_ANDROID_SDK="yes"
 155         if test -f "$HOME/altusmetrumllc/google-play-release.keystore" -a -f "$HOME/altusmetrumllc/google-play-passphrase"; then
 156                 ANDROID_RELEASE=yes
 157         fi
 158 else
 159         HAVE_ANDROID_SDK="no"
 160 fi
 161
 162 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 163 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 164
 165 AC_SUBST(ANDROID_SDK)
 166
 167 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 168             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 169             [FATDIR=$withval], [FATDIR=none])
 170
 171 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 172
 173 AC_SUBST(FATDIR)
 174
 175 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 176             [Set the file to read the AltosDroid maps API key from (defaults to ~/altusmetrumllc/google-altosdroid-maps-api-key)]),
 177             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-altosdroid-maps-api-key])
 178
 179 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 180         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 181         HAVE_GOOGLE_KEY="yes"
 182 else
 183         GOOGLEKEY='null'
 184         HAVE_GOOGLE_KEY="no"
 185 fi
 186
 187 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 188               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 189               [FAKETIME=$enableval], [FAKETIME=no])
 190
 191 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 192
 193 AC_SUBST(GOOGLEKEY)
 194
 195 AC_PROG_CC
 196 AC_PROG_INSTALL
 197 AC_PROG_LN_S
 198 AC_PROG_LIBTOOL
 199 PKG_PROG_PKG_CONFIG
 200
 201 WARN_CFLAGS=""
 202 if test "x$GCC" = "xyes"; then
 203         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 204         -Wmissing-prototypes -Wmissing-declarations \
 205         -Wnested-externs -fno-strict-aliasing"
 206         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 207         [Can use #warning in C files])
 208 fi
 209 AC_SUBST(WARN_CFLAGS)
 210
 211 #
 212 # Configure ARM compiler for STM32L and LPC11U14
 213 #
 214
 215 AC_ARG_WITH([arm-cc],
 216             [AS_HELP_STRING([--with-arm-cc],
 217                             [Name of ARM C compiler])],
 218             [],
 219             [with_arm_cc=auto])
 220
 221 if test "x$with_arm_cc" != "xno"; then
 222         if test "x$with_arm_cc" = "xauto"; then
 223                 with_arm_cc="arm-none-eabi-gcc"
 224                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 225         else
 226                 HAVE_ARM_CC=yes
 227         fi
 228 else
 229         HAVE_ARM_CC=no
 230 fi
 231
 232 if test "x$HAVE_ARM_CC" = "xno"; then
 233         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 234 else
 235         ARM_CC=$with_arm_cc
 236 fi
 237 AC_SUBST(HAVE_ARM_CC)
 238 AC_SUBST(ARM_CC)
 239
 240 if test "x$HAVE_ARM_CC" = "xyes"; then
 241         save_CC="$CC"
 242         save_CFLAGS="$CFLAGS"
 243         save_LIBS="$LIBS"
 244         CC="$ARM_CC"
 245         CFLAGS="-mthumb -mcpu=cortex-m0"
 246         LIBS="-ffreestanding -nostdlib"
 247         AC_LANG_PUSH([C])
 248
 249         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 250         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 251                           [HAVE_ARM_M0_CC=yes],
 252                           [HAVE_ARM_M0_CC=no])
 253         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 254
 255         CFLAGS="-mthumb -mcpu=cortex-m3"
 256         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 257         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 258                           [HAVE_ARM_M3_CC=yes],
 259                           [HAVE_ARM_M3_CC=no])
 260         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 261
 262         AC_LANG_POP([C])
 263         LIBS="$save_LIBS"
 264         CFLAGS="$save_CFLAGS"
 265         CC="$save_CC"
 266 else
 267         HAVE_ARM_M3_CC=no
 268         HAVE_ARM_M0_CC=no
 269 fi
 270 AC_SUBST(HAVE_ARM_M3_CC)
 271 AC_SUBST(HAVE_ARM_M0_CC)
 272
 273 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 274         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 275 fi
 276
 277 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 278         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 279 fi
 280
 281 AC_ARG_WITH([newlib-nano],
 282             [AS_HELP_STRING([--with-newlib-nano],
 283                             [Root of newlib nano install])],
 284             [],
 285             [with_newlib_nano=auto])
 286
 287 HAVE_NEWLIB_NANO=no
 288 if test "x$with_newlib_nano" != "xno"; then
 289         if test "x$with_newlib_nano" = "xauto"; then
 290                 for d in /usr/local/lib/newlib-nano /usr/lib/newlib-nano; do
 291                         if test "x$with_newlib_nano" = "xauto" -a -d "$d"; then
 292                                 with_newlib_nano="$d"
 293                                 HAVE_NEWLIB_NANO=yes
 294                         fi
 295                 done
 296         else
 297                 HAVE_NEWLIB_NANO=yes
 298         fi
 299 fi
 300
 301 if test "x$HAVE_NEWLIB_NANO" = "xno"; then
 302         AC_MSG_WARN([No newlib-nano library found, ARM binaries will not be built])
 303         HAVE_ARM_M3_CC=no
 304         HAVE_ARM_M0_CC=no
 305 else
 306         NEWLIB_NANO="$with_newlib_nano"
 307 fi
 308
 309 AC_SUBST(HAVE_NEWLIB_NANO)
 310 AC_SUBST(NEWLIB_NANO)
 311
 312 #
 313 # Configure AVR compiler
 314 #
 315
 316 AC_ARG_WITH([avr-cc],
 317             [AS_HELP_STRING([--with-avr-cc],
 318                             [Name of AVR C compiler])],
 319             [],
 320             [with_avr_cc=auto])
 321
 322 if test "x$with_avr_cc" != "xno"; then
 323         if test "x$with_avr_cc" = "xauto"; then
 324                 with_avr_cc="avr-gcc"
 325                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 326         else
 327                 HAVE_AVR_CC=yes
 328         fi
 329 else
 330         HAVE_AVR_CC=no
 331 fi
 332
 333 AC_ARG_WITH([avr-objcopy],
 334             [AS_HELP_STRING([--with-avr-objcopy],
 335                             [Name of AVR objcopy])],
 336             [],
 337             [with_avr_objcopy=auto])
 338
 339 if test "x$with_avr_objcopy" != "xno"; then
 340         if test "x$with_avr_objcopy" = "xauto"; then
 341                 with_avr_objcopy="avr-objcopy"
 342                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 343         else
 344                 HAVE_AVR_OBJCOPY=yes
 345         fi
 346 else
 347         HAVE_AVR_OBJCOPY=no
 348 fi
 349
 350 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 351         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 352         HAVE_AVR_CC=no
 353 else
 354         save_CC="$CC"
 355         save_CFLAGS="$CFLAGS"
 356         save_LIBS="$LIBS"
 357
 358         CC="$with_avr_cc"
 359         CFLAGS="-mmcu=attiny85"
 360         AC_LANG_PUSH([C])
 361         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 362         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 363                           [AVR_LINK=yes],
 364                           [AVR_LINK=no])
 365         AC_MSG_RESULT([$AVR_LINK])
 366         AC_LANG_POP([C])
 367
 368         LIBS="$save_LIBS"
 369         CFLAGS="$save_CFLAGS"
 370         CC="$save_CC"
 371
 372         if test "x$AVR_LINK" = xyes; then
 373                 AVR_CC=$with_avr_cc
 374                 AVR_OBJCOPY=$with_avr_objcopy
 375         else
 376                 HAVE_AVR_CC=no;
 377         fi
 378 fi
 379
 380 AC_SUBST(AVR_CC)
 381 AC_SUBST(AVR_OBJCOPY)
 382 AC_SUBST(HAVE_AVR_CC)
 383
 384 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 385 if test "x$HAVE_NICKLE" = "xno"; then
 386         AC_MSG_ERROR([Please install nickle to build AltOs])
 387 fi
 388
 389 PKG_CHECK_MODULES([JANSSON], [jansson])
 390
 391 AC_ARG_WITH([readline],
 392             [AS_HELP_STRING([--with-readline],
 393                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 394               [],
 395               [with_readline=auto])
 396
 397 LIBREADLINE_LIBS=
 398
 399 if test x"$with_readline" != "xno"; then
 400         AC_CHECK_LIB([readline], [main],
 401                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 402                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 403                          [Define if you have libreadline])],
 404                       [if test "x$with_readline" != xauto; then
 405                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 406                        fi],
 407                        -lncurses)
 408 fi
 409
 410 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 411
 412 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 413 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 414
 415 AC_ARG_WITH([stlink],
 416             [AS_HELP_STRING([--with-stlink],
 417                             [Build tools that use the stlink library (default: auto)])],
 418             [],
 419             [with_stlink=auto])
 420
 421 if test x"$with_stlink" != "xno"; then
 422         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 423         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 424                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 425         fi
 426 else
 427         HAVE_STLINK=no
 428 fi
 429
 430 if test x"$HAVE_STLINK" = "xyes"; then
 431         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 432 fi
 433
 434 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 435
 436 AC_ARG_ENABLE([multi-arch],
 437               [AS_HELP_STRING([--enable-multi-arch],
 438                               [enable building both i386 and amd64 libraries (default=auto)])],
 439               [MULTI_ARCH=$enableval],
 440               [MULTI_ARCH=auto])
 441
 442 case x"$MULTI_ARCH" in
 443 xauto)
 444         arch=`uname -m`
 445         case x"$arch" in
 446         xx86_64|xi*86)
 447                 save_CFLAGS="$CFLAGS"
 448                 save_LIBS="$LIBS"
 449                 LIBS="-ldl"
 450                 CFLAGS="-m64"
 451                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 452                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 453                                 [M64_LINK=yes],
 454                                 [M64_LINK=no])
 455                 AC_MSG_RESULT([$M64_LINK])
 456                 CFLAGS="-m32"
 457                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 458                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 459                                 [M32_LINK=yes],
 460                                 [M32_LINK=no])
 461                 AC_MSG_RESULT([$M32_LINK])
 462                 CFLAGS="$save_CFLAGS"
 463                 LIBS="$save_LIBS"
 464                 case x"$M64_LINK"x"$M32_LINK" in
 465                 xyesxyes)
 466                         MULTI_ARCH=yes
 467                         ;;
 468                 *)
 469                         MULTI_ARCH=no
 470                         ;;
 471                 esac
 472                 ;;
 473         *)
 474                 MULTI_ARCH=no
 475                 ;;
 476         esac
 477         ;;
 478 xyes|xno)
 479         ;;
 480 *)
 481         MULTI_ARCH="no"
 482         ;;
 483 esac
 484
 485 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 486
 487 AC_ARG_ENABLE([install-shared-mime-info],
 488               [AS_HELP_STRING([--disable-install-shared-mime-info],
 489                               [disable installing shared mime info files (default=yes)])],
 490               [INSTALL_SHARED_MIME_INFO=$enableval],
 491               [INSTALL_SHARED_MIME_INFO=yes])
 492
 493 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 494
 495 AC_OUTPUT([
 496 Makefile
 497 src/Makedefs
 498 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 499 doc/Makefile
 500 altoslib/Makefile
 501 altoslib/AltosVersion.java
 502 icon/Makefile
 503 altosuilib/Makefile
 504 altosui/Makefile
 505 altosui/Info.plist
 506 altosui/altos-windows.nsi
 507 libaltos/Makefile
 508 micropeak/Makefile
 509 micropeak/Info.plist
 510 micropeak/micropeak-windows.nsi
 511 telegps/Makefile
 512 telegps/Info.plist
 513 telegps/telegps-windows.nsi
 514 altosdroid/Makefile
 515 altosdroid/local.properties
 516 altosdroid/AndroidManifest.xml
 517 ao-tools/Makefile
 518 ao-tools/lib/Makefile
 519 ao-tools/ao-rawload/Makefile
 520 ao-tools/ao-dbg/Makefile
 521 ao-tools/ao-bitbang/Makefile
 522 ao-tools/ao-eeprom/Makefile
 523 ao-tools/ao-list/Makefile
 524 ao-tools/ao-load/Makefile
 525 ao-tools/ao-telem/Makefile
 526 ao-tools/ao-stmload/Makefile
 527 ao-tools/ao-send-telem/Makefile
 528 ao-tools/ao-sky-flash/Makefile
 529 ao-tools/ao-dumpflash/Makefile
 530 ao-tools/ao-edit-telem/Makefile
 531 ao-tools/ao-dump-up/Makefile
 532 ao-tools/ao-elftohex/Makefile
 533 ao-tools/ao-usbload/Makefile
 534 ao-tools/ao-flash/Makefile
 535 ao-tools/ao-test-igniter/Makefile
 536 ao-tools/ao-test-baro/Makefile
 537 ao-tools/ao-test-flash/Makefile
 538 ao-tools/ao-cal-accel/Makefile
 539 ao-tools/ao-cal-freq/Makefile
 540 ao-tools/ao-test-gps/Makefile
 541 ao-tools/ao-usbtrng/Makefile
 542 ao-tools/ao-chaosread/Makefile
 543 ao-tools/ao-makebin/Makefile
 544 ao-utils/Makefile
 545 map-server/Makefile
 546 map-server/altos-mapd/Makefile
 547 map-server/altos-map/Makefile
 548 map-server/altos-mapj/Makefile
 549 src/Version
 550 ])
 551
 552 echo ""
 553 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 554 echo ""
 555 echo "  Configuration"
 556 echo "    Arm compiler................: ${ARM_CC}"
 557 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 558 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 559 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 560 echo "    AVR support.................: ${HAVE_AVR_CC}"
 561 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 562 echo "    Android release support.....: ${ANDROID_RELEASE}"
 563 echo "    STlink support..............: ${HAVE_STLINK}"
 564 echo "    Newlib-nano support.........: ${NEWLIB_NANO}"
 565 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 566 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 567 echo ""
 568 echo "  Java"
 569 echo "    freetts.....................: ${FREETTS}"
 570 echo "    jfreechart..................: ${JFREECHART}"
 571 echo "    jcommon.....................: ${JCOMMON}"
 572 echo "    JVM include.................: ${JVM_INCLUDE}"
 573 echo "    AltosDroid maps API key.....: ${HAVE_GOOGLE_KEY}"
 574 if test x${ANDROID_SDK} != "xno"; then
 575 echo ""
 576 echo "  Android path"
 577 echo "    Android SDK.................: ${ANDROID_SDK}"
 578 fi
 579 echo ""