git.gag.com Git - fw/sdcc/blob - support/cpp2/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(cppmain.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for additional parameters
  34
  35 # With GNU ld
  36 AC_ARG_WITH(gnu-ld,
  37 [  --with-gnu-ld           arrange to work with GNU ld.],
  38 gnu_ld_flag="$with_gnu_ld",
  39 gnu_ld_flag=no)
  40
  41 # With pre-defined ld
  42 AC_ARG_WITH(ld,
  43 [  --with-ld               arrange to use the specified ld (full pathname)],
  44 DEFAULT_LINKER="$with_ld")
  45 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  46   if test ! -x "$DEFAULT_LINKER"; then
  47     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
  48   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
  49     gnu_ld_flag=yes
  50   fi
  51   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
  52         [Define to enable the use of a default linker.])
  53 fi
  54
  55 # With GNU as
  56 AC_ARG_WITH(gnu-as,
  57 [  --with-gnu-as           arrange to work with GNU as],
  58 gas_flag="$with_gnu_as",
  59 gas_flag=no)
  60
  61 AC_ARG_WITH(as,
  62 [  --with-as               arrange to use the specified as (full pathname)],
  63 DEFAULT_ASSEMBLER="$with_as")
  64 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
  65   if test ! -x "$DEFAULT_ASSEMBLER"; then
  66     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
  67   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
  68     gas_flag=yes
  69   fi
  70   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
  71         [Define to enable the use of a default assembler.])
  72 fi
  73
  74 # With stabs
  75 AC_ARG_WITH(stabs,
  76 [  --with-stabs            arrange to use stabs instead of host debug format],
  77 stabs="$with_stabs",
  78 stabs=no)
  79
  80 # With ELF
  81 AC_ARG_WITH(elf,
  82 [  --with-elf              arrange to use ELF instead of host debug format],
  83 elf="$with_elf",
  84 elf=no)
  85
  86 # Specify the local prefix
  87 local_prefix=
  88 AC_ARG_WITH(local-prefix,
  89 [  --with-local-prefix=DIR specifies directory to put local include],
  90 [case "${withval}" in
  91 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
  92 no)     ;;
  93 *)      local_prefix=$with_local_prefix ;;
  94 esac])
  95
  96 # Default local prefix if it is empty
  97 if test x$local_prefix = x; then
  98         local_prefix=/usr/local
  99 fi
 100
 101 AC_ARG_PROGRAM
 102
 103 # Enable Multibyte Characters for C/C++
 104 AC_ARG_ENABLE(c-mbchar,
 105 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 106 if test x$enable_c_mbchar != xno; then
 107   AC_DEFINE(MULTIBYTE_CHARS, 1,
 108   [Define if you want the C and C++ compilers to support multibyte
 109    character sets for source code.])
 110 fi)
 111
 112 # Find the native compiler
 113 AC_PROG_CC
 114 AC_PROG_CC_C_O
 115 # autoconf is lame and doesn't give us any substitution variable for this.
 116 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 117   NO_MINUS_C_MINUS_O=yes
 118 else
 119   OUTPUT_OPTION='-o $@'
 120 fi
 121 AC_SUBST(NO_MINUS_C_MINUS_O)
 122 AC_SUBST(OUTPUT_OPTION)
 123
 124 AC_PROG_CPP
 125 AC_C_INLINE
 126
 127 # sizeof(char) is 1 by definition.
 128 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 129 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 130 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 131
 132 gcc_AC_C_CHARSET
 133
 134 # If the native compiler is GCC, we can enable warnings even in stage1.
 135 # That's useful for people building cross-compilers, or just running a
 136 # quick `make'.
 137 warn_cflags=
 138 if test "x$GCC" = "xyes"; then
 139   warn_cflags='$(GCC_WARN_CFLAGS)'
 140 fi
 141 AC_SUBST(warn_cflags)
 142
 143 AC_PROG_MAKE_SET
 144
 145 AC_MSG_CHECKING([whether a default assembler was specified])
 146 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 147     if test x"$gas_flag" = x"no"; then
 148         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 149     else
 150         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 151     fi
 152 else
 153     AC_MSG_RESULT(no)
 154 fi
 155
 156 AC_MSG_CHECKING([whether a default linker was specified])
 157 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 158     if test x"$gnu_ld_flag" = x"no"; then
 159         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 160     else
 161         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 162     fi
 163 else
 164     AC_MSG_RESULT(no)
 165 fi
 166
 167 AC_MSG_CHECKING(for GNU C library)
 168 AC_CACHE_VAL(gcc_cv_glibc,
 169 [AC_TRY_COMPILE(
 170   [#include <features.h>],[
 171 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 172 #error Not a GNU C library system
 173 #endif],
 174   [gcc_cv_glibc=yes],
 175   gcc_cv_glibc=no)])
 176 AC_MSG_RESULT($gcc_cv_glibc)
 177 if test $gcc_cv_glibc = yes; then
 178   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 179 fi
 180
 181 # Find some useful tools
 182 gcc_AC_PROG_LN
 183 gcc_AC_PROG_LN_S
 184 AC_PROG_RANLIB
 185 gcc_AC_PROG_INSTALL
 186
 187 AC_HEADER_STDC
 188 AC_HEADER_TIME
 189 gcc_AC_HEADER_STRING
 190 AC_HEADER_SYS_WAIT
 191 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 192                  fcntl.h unistd.h sys/file.h sys/time.h \
 193                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 194                  direct.h malloc.h langinfo.h)
 195
 196 # Check for thread headers.
 197
 198 # These tests can't be done till we know if we have limits.h.
 199 gcc_AC_C_CHAR_BIT
 200 gcc_AC_C_COMPILE_ENDIAN
 201
 202 # See if we have the mktemp command.
 203 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 204
 205 AC_CHECK_PROG(STRIP, strip, strip, :)
 206
 207 # See if the stage1 system preprocessor understands the ANSI C
 208 # preprocessor stringification operator.  (Used by symcat.h.)
 209 AC_C_STRINGIZE
 210
 211 # Use <inttypes.h> only if it exists,
 212 # doesn't clash with <sys/types.h>, and declares intmax_t.
 213 AC_MSG_CHECKING(for inttypes.h)
 214 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 215 [AC_TRY_COMPILE(
 216   [#include <sys/types.h>
 217 #include <inttypes.h>],
 218   [intmax_t i = -1;],
 219   [gcc_cv_header_inttypes_h=yes],
 220   gcc_cv_header_inttypes_h=no)])
 221 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 222 if test $gcc_cv_header_inttypes_h = yes; then
 223   AC_DEFINE(HAVE_INTTYPES_H, 1,
 224         [Define if you have a working <inttypes.h> header file.])
 225 fi
 226
 227 dnl Disabled until we have a complete test for buggy enum bitfields.
 228 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 229
 230 AC_CHECK_FUNCS(times clock strchr strrchr lstat)
 231
 232 AC_CHECK_TYPE(ssize_t, int)
 233
 234 AC_FUNC_MMAP_ANYWHERE
 235 AC_FUNC_MMAP_FILE
 236
 237 # We will need to find libiberty.h and ansidecl.h
 238 saved_CFLAGS="$CFLAGS"
 239 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 240 gcc_AC_CHECK_DECLS(getenv abort errno \
 241         malloc realloc calloc free getopt clock, , ,[
 242 #include "ansidecl.h"
 243 #include "system.h"])
 244
 245 gcc_AC_CHECK_DECLS(times, , ,[
 246 #include "ansidecl.h"
 247 #include "system.h"
 248 #ifdef HAVE_SYS_TIMES_H
 249 #include <sys/times.h>
 250 #endif
 251 ])
 252
 253 # More time-related stuff.
 254 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 255 AC_TRY_COMPILE([
 256 #include "ansidecl.h"
 257 #include "system.h"
 258 #ifdef HAVE_SYS_TIMES_H
 259 #include <sys/times.h>
 260 #endif
 261 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 262 if test $ac_cv_struct_tms = yes; then
 263   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 264   [Define if <sys/times.h> defines struct tms.])
 265 fi
 266
 267 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 268 # revisit after autoconf 2.50.
 269 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 270 AC_TRY_COMPILE([
 271 #include "ansidecl.h"
 272 #include "system.h"
 273 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 274 if test $gcc_cv_type_clock_t = yes; then
 275   AC_DEFINE(HAVE_CLOCK_T, 1,
 276   [Define if <time.h> defines clock_t.])
 277 fi
 278
 279 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 280 CFLAGS="$saved_CFLAGS"
 281
 282 # mkdir takes a single argument on some systems.
 283 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 284
 285 # File extensions
 286 manext='.1'
 287 objext='.o'
 288 AC_SUBST(manext)
 289 AC_SUBST(objext)
 290
 291 build_xm_file=
 292 build_xm_defines=
 293 build_install_headers_dir=install-headers-tar
 294 build_exeext=
 295 host_xm_file=
 296 host_xm_defines=
 297 host_xmake_file=
 298 host_truncate_target=
 299 host_exeext=
 300
 301 # Decode the host machine, then the target machine.
 302 # For the host machine, we save the xm_file variable as host_xm_file;
 303 # then we decode the target machine and forget everything else
 304 # that came from the host machine.
 305 #for machine in $build $host $target; do
 306 #       . ${srcdir}/config.gcc
 307 #done
 308
 309 extra_objs="${host_extra_objs} ${extra_objs}"
 310
 311 # Default the target-machine variables that were not explicitly set.
 312 if test x"$tm_file" = x
 313 then tm_file=$cpu_type/$cpu_type.h; fi
 314
 315 if test x"$extra_headers" = x
 316 then extra_headers=; fi
 317
 318 if test x$md_file = x
 319 then md_file=$cpu_type/$cpu_type.md; fi
 320
 321 if test x$out_file = x
 322 then out_file=$cpu_type/$cpu_type.c; fi
 323
 324 if test x"$tmake_file" = x
 325 then tmake_file=$cpu_type/t-$cpu_type
 326 fi
 327
 328 if test x"$dwarf2" = xyes
 329 then tm_file="$tm_file tm-dwarf2.h"
 330 fi
 331
 332 # Handle cpp installation.
 333 if test x$enable_cpp != xno
 334 then
 335   tmake_file="$tmake_file t-install-cpp"
 336 fi
 337
 338 # auto-host.h is the file containing items generated by autoconf and is
 339 # the first file included by config.h.
 340 # If host=build, it is correct to have hconfig include auto-host.h
 341 # as well.  If host!=build, we are in error and need to do more
 342 # work to find out the build config parameters.
 343 if test x$host = x$build
 344 then
 345         build_auto=auto-host.h
 346 else
 347         # We create a subdir, then run autoconf in the subdir.
 348         # To prevent recursion we set host and build for the new
 349         # invocation of configure to the build for this invocation
 350         # of configure.
 351         tempdir=build.$$
 352         rm -rf $tempdir
 353         mkdir $tempdir
 354         cd $tempdir
 355         case ${srcdir} in
 356         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 357         *) realsrcdir=../${srcdir};;
 358         esac
 359         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 360                 --target=$target --host=$build --build=$build
 361
 362         # We just finished tests for the build machine, so rename
 363         # the file auto-build.h in the gcc directory.
 364         mv auto-host.h ../auto-build.h
 365         cd ..
 366         rm -rf $tempdir
 367         build_auto=auto-build.h
 368 fi
 369
 370 tm_file="${tm_file} defaults.h"
 371 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 372 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 373 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 374
 375 # Truncate the target if necessary
 376 if test x$host_truncate_target != x; then
 377         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 378 fi
 379
 380 # Get the version trigger filename from the toplevel
 381 if test "${with_gcc_version_trigger+set}" = set; then
 382         gcc_version_trigger=$with_gcc_version_trigger
 383 else
 384         gcc_version_trigger=${srcdir}/version.c
 385 fi
 386 changequote(,)dnl
 387 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 388 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 389
 390 # Compile in configure arguments.
 391 if test -f configargs.h ; then
 392         # Being re-configured.
 393         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 394         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 395 else
 396         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 397 fi
 398 cat > configargs.h <<EOF
 399 /* Generated automatically. */
 400 static const char configuration_arguments[] = "$gcc_config_arguments";
 401 static const char thread_model[] = "$thread_file";
 402 EOF
 403 changequote([,])dnl
 404
 405 # Internationalization
 406 PACKAGE=sdcc
 407 VERSION="$gcc_version"
 408 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 409         [Define to the name of the distribution.])
 410 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 411         [Define to the version of the distribution.])
 412 AC_SUBST(PACKAGE)
 413 AC_SUBST(VERSION)
 414
 415 ALL_LINGUAS="sv"
 416
 417 # Get an absolute path to the GCC top-level source directory
 418 holddir=`pwd`
 419 cd $srcdir
 420 topdir=`pwd`
 421 cd $holddir
 422
 423 out_object_file=`basename $out_file .c`.o
 424
 425 # Figure out what assembler we will be using.
 426 AC_MSG_CHECKING(what assembler to use)
 427 gcc_cv_as=
 428 gcc_cv_gas_major_version=
 429 gcc_cv_gas_minor_version=
 430 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
 431 if test -x "$DEFAULT_ASSEMBLER"; then
 432         gcc_cv_as="$DEFAULT_ASSEMBLER"
 433 elif test -x "$AS"; then
 434         gcc_cv_as="$AS"
 435 elif test -x as$host_exeext; then
 436         # Build using assembler in the current directory.
 437         gcc_cv_as=./as$host_exeext
 438 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
 439         # Single tree build which includes gas.
 440         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
 441         do
 442 changequote(,)dnl
 443                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
 444 changequote([,])dnl
 445                 if test x$gcc_cv_gas_version != x; then
 446                         break
 447                 fi
 448         done
 449 changequote(,)dnl
 450         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
 451         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
 452 changequote([,])dnl
 453 fi
 454
 455 if test "x$gcc_cv_as" = x -a x$host = x$target; then
 456         # Native build.
 457         # Search the same directories that the installed compiler will
 458         # search.  Else we may find the wrong assembler and lose.  If we
 459         # do not find a suitable assembler binary, then try the user's
 460         # path.
 461         #
 462         # Also note we have to check MD_EXEC_PREFIX before checking the
 463         # user's path.  Unfortunately, there is no good way to get at the
 464         # value of MD_EXEC_PREFIX here.  So we do a brute force search
 465         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
 466         # to be fixed as part of the make/configure rewrite too.
 467
 468         if test "x$exec_prefix" = xNONE; then
 469                 if test "x$prefix" = xNONE; then
 470                         test_prefix=/usr/local
 471                 else
 472                         test_prefix=$prefix
 473                 fi
 474         else
 475                 test_prefix=$exec_prefix
 476         fi
 477
 478         # If the loop below does not find an assembler, then use whatever
 479         # one we can find in the users's path.
 480         # user's path.
 481         gcc_cv_as=as$host_exeext
 482
 483         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
 484                    $test_prefix/lib/gcc-lib/$target \
 485                    /usr/lib/gcc/$target/$gcc_version \
 486                    /usr/lib/gcc/$target \
 487                    $test_prefix/$target/bin/$target/$gcc_version \
 488                    $test_prefix/$target/bin \
 489                    /usr/libexec \
 490                    /usr/ccs/gcc \
 491                    /usr/ccs/bin \
 492                    /udk/usr/ccs/bin \
 493                    /bsd43/usr/lib/cmplrs/cc \
 494                    /usr/cross64/usr/bin \
 495                    /usr/lib/cmplrs/cc \
 496                    /sysv/usr/lib/cmplrs/cc \
 497                    /svr4/usr/lib/cmplrs/cc \
 498                    /usr/bin"
 499
 500         for dir in $test_dirs; do
 501                 if test -f $dir/as$host_exeext; then
 502                         gcc_cv_as=$dir/as$host_exeext
 503                         break;
 504                 fi
 505         done
 506 fi
 507 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
 508   AC_MSG_RESULT("newly built gas")
 509 else
 510   AC_MSG_RESULT($gcc_cv_as)
 511 fi
 512
 513 # Figure out what nm we will be using.
 514 AC_MSG_CHECKING(what nm to use)
 515 if test -x nm$host_exeext; then
 516         gcc_cv_nm=./nm$host_exeext
 517 elif test x$host = x$target; then
 518         # Native build.
 519         gcc_cv_nm=nm$host_exeext
 520 fi
 521 AC_MSG_RESULT($gcc_cv_nm)
 522
 523 dnl Very limited version of automake's enable-maintainer-mode
 524
 525 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
 526   dnl maintainer-mode is disabled by default
 527   AC_ARG_ENABLE(maintainer-mode,
 528 [  --enable-maintainer-mode
 529                           enable make rules and dependencies not useful
 530                           (and sometimes confusing) to the casual installer],
 531       maintainer_mode=$enableval,
 532       maintainer_mode=no)
 533
 534 AC_MSG_RESULT($maintainer_mode)
 535
 536 if test "$maintainer_mode" = "yes"; then
 537   MAINT=''
 538 else
 539   MAINT='#'
 540 fi
 541 AC_SUBST(MAINT)dnl
 542
 543 # These (without "all_") are set in each config-lang.in.
 544 # `language' must be a single word so is spelled singularly.
 545 all_stagestuff=
 546 all_outputs='Makefile'
 547 # List of language makefile fragments.
 548
 549 # Add the language fragments.
 550 # Languages are added via two mechanisms.  Some information must be
 551 # recorded in makefile variables, these are defined in config-lang.in.
 552 # We accumulate them and plug them into the main Makefile.
 553 # The other mechanism is a set of hooks for each of the main targets
 554 # like `clean', `install', etc.
 555
 556 language_fragments="Make-lang"
 557
 558 # Define variables host_canonical and build_canonical
 559 # because some Cygnus local changes in the Makefile depend on them.
 560 build_canonical=${build}
 561 host_canonical=${host}
 562 target_subdir=
 563 if test "${host}" != "${target}" ; then
 564     target_subdir=${target_alias}/
 565 fi
 566 AC_SUBST(build_canonical)
 567 AC_SUBST(host_canonical)
 568 AC_SUBST(target_subdir)
 569
 570 # Nothing to do for FLOAT_H, float_format already handled.
 571 objdir=`pwd`
 572 AC_SUBST(objdir)
 573
 574 # Substitute configuration variables
 575 AC_SUBST(all_stagestuff)
 576 AC_SUBST(build_exeext)
 577 AC_SUBST(build_install_headers_dir)
 578 AC_SUBST(build_xm_file_list)
 579 AC_SUBST(build_xm_file)
 580 AC_SUBST(build_xm_defines)
 581 AC_SUBST(check_languages)
 582 AC_SUBST(dep_host_xmake_file)
 583 AC_SUBST(dep_tmake_file)
 584 AC_SUBST(extra_c_flags)
 585 AC_SUBST(extra_headers_list)
 586 AC_SUBST(extra_objs)
 587 AC_SUBST(extra_parts)
 588 AC_SUBST(extra_passes)
 589 AC_SUBST(extra_programs)
 590 AC_SUBST(gcc_config_arguments)
 591 AC_SUBST(gcc_version)
 592 AC_SUBST(gcc_version_full)
 593 AC_SUBST(gcc_version_trigger)
 594 AC_SUBST(host_exeext)
 595 AC_SUBST(host_extra_gcc_objs)
 596 AC_SUBST(install)
 597 AC_SUBST(lang_tree_files)
 598 AC_SUBST(local_prefix)
 599 AC_SUBST(md_file)
 600 AC_SUBST(out_file)
 601 AC_SUBST(out_object_file)
 602 AC_SUBST(symbolic_link)
 603 AC_SUBST(thread_file)
 604 AC_SUBST(c_target_objs)
 605
 606 AC_SUBST_FILE(target_overrides)
 607 AC_SUBST_FILE(host_overrides)
 608 AC_SUBST(cross_defines)
 609 AC_SUBST_FILE(cross_overrides)
 610 AC_SUBST_FILE(build_overrides)
 611
 612 # Create the Makefile
 613 # and configure language subdirectories
 614 AC_OUTPUT($all_outputs,
 615 [
 616 case x$CONFIG_HEADERS in
 617 xauto-host.h:config.in)
 618 echo > cstamp-h ;;
 619 esac
 620
 621 # Avoid having to add intl to our include paths.
 622 if test -f intl/libintl.h; then
 623   echo creating libintl.h
 624   echo '#include "intl/libintl.h"' >libintl.h
 625 fi
 626 ],
 627 [
 628 host='${host}'
 629 build='${build}'
 630 target='${target}'
 631 target_alias='${target_alias}'
 632 srcdir='${srcdir}'
 633 symbolic_link='${symbolic_link}'
 634 program_transform_set='${program_transform_set}'
 635 program_transform_name='${program_transform_name}'
 636 dep_host_xmake_file='${dep_host_xmake_file}'
 637 host_xmake_file='${host_xmake_file}'
 638 dep_tmake_file='${dep_tmake_file}'
 639 tmake_file='${tmake_file}'
 640 thread_file='${thread_file}'
 641 gcc_config_arguments='${gcc_config_arguments}'
 642 gcc_version='${gcc_version}'
 643 gcc_version_full='${gcc_version_full}'
 644 gcc_version_trigger='${gcc_version_trigger}'
 645 local_prefix='${local_prefix}'
 646 build_install_headers_dir='${build_install_headers_dir}'
 647 build_exeext='${build_exeext}'
 648 host_exeext='${host_exeext}'
 649 out_file='${out_file}'
 650 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
 651 SET_MAKE='${SET_MAKE}'
 652 target_list='${target_list}'
 653 target_overrides='${target_overrides}'
 654 host_overrides='${host_overrides}'
 655 cross_defines='${cross_defines}'
 656 cross_overrides='${cross_overrides}'
 657 build_overrides='${build_overrides}'
 658 cpp_install_dir='${cpp_install_dir}'
 659 ])