git.gag.com Git - fw/sdcc/blob - sim/ucsim/configure.in

   1 #!/bin/sh
   2
   3 AC_INIT(.version)
   4 AC_CONFIG_HEADER(ddconfig.h:ddconfig_in.h)
   5
   6 AC_PROG_AWK
   7
   8 AC_MSG_CHECKING(version of the package)
   9 if test -f .version; then
  10   VERSION=`cat .version`
  11   AC_MSG_RESULT($VERSION)
  12 else
  13   VERSION="0.0.0"
  14   AC_MSG_RESULT(unknown using 0.0.0)
  15 fi
  16 VERSIONHI=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $1}'`
  17 VERSIONLO=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $2}'`
  18 VERSIONP=`echo $VERSION|$AWK 'BEGIN {FS="."} {print $3}'`
  19 AC_SUBST(VERSION)
  20 AC_SUBST(VERSIONHI)
  21 AC_SUBST(VERSIONLO)
  22 AC_SUBST(VERSIONP)
  23 AC_DEFINE_UNQUOTED(VERSIONSTR, "${VERSION}")
  24 AC_DEFINE_UNQUOTED(VERSIONHI, $VERSIONHI)
  25 AC_DEFINE_UNQUOTED(VERSIONLO, $VERSIONLO)
  26 AC_DEFINE_UNQUOTED(VERSIONP, $VERSIONP)
  27
  28
  29 # Required programs
  30 #-------------------
  31 AC_PROG_CXX
  32 AC_PROG_CXXCPP
  33 AC_PROG_INSTALL
  34 AC_PROG_RANLIB
  35 AC_LANG_CPLUSPLUS
  36
  37
  38 # Checking for header files.
  39 # ===========================================================================
  40
  41 if test -d /stuff/include; then
  42   CPPFLAGS="$CPPFLAGS -I/stuff/include"
  43 fi
  44
  45 AC_HEADER_STDC
  46 AC_CHECK_HEADERS(getopt.h)
  47 AC_CHECK_HEADERS(unistd.h)
  48 AC_CHECK_HEADER(sys/socket.h,
  49     AC_DEFINE(SOCKET_AVAIL)
  50     AC_DEFINE(HAVE_SYS_SOCKET_H)
  51     AC_EGREP_HEADER(socklen_t,
  52                     sys/socket.h,
  53                     AC_DEFINE_UNQUOTED(SOCKLEN_T, socklen_t),
  54                     AC_DEFINE_UNQUOTED(SOCKLEN_T, uint))
  55 )
  56 AC_HEADER_DIRENT
  57
  58 # This must be after CXXCPP
  59
  60 AC_CACHE_CHECK(which header file defines FD_ macros, s51_cv_fd,
  61 [s51_cv_fd="unknown"
  62 AC_EGREP_CPP(yes, [
  63 #include <sys/time.h>
  64 #ifdef FD_ZERO
  65 yes
  66 #endif], s51_cv_fd="<sys/time.h>")
  67 AC_EGREP_CPP(yes, [
  68 #include <sys/types.h>
  69 #ifdef FD_ZERO
  70 yes
  71 #endif], s51_cv_fd="<sys/types.h>")
  72 AC_EGREP_CPP(yes, [
  73 #include <sys/select.h>
  74 #ifdef FD_ZERO
  75 yes
  76 #endif], s51_cv_fd="<sys/types.h>")])
  77
  78 AC_DEFINE(FD_HEADER_OK, 0)
  79 if echo $s51_cv_fd|grep time >/dev/null 2>&1; then
  80 AC_DEFINE(FD_NEED_TIME_H, 1)
  81 AC_DEFINE(FD_HEADER_OK, 1)
  82 else
  83 AC_DEFINE(FD_NEED_TIME_H, 0)
  84 fi
  85 if echo $s51_cv_fd|grep types >/dev/null 2>&1; then
  86 AC_DEFINE(FD_NEED_TYPES_H, 1)
  87 AC_DEFINE(FD_HEADER_OK, 1)
  88 else
  89 AC_DEFINE(FD_NEED_TYPES_H, 0)
  90 fi
  91 if echo $s51_cv_fd|grep select >/dev/null 2>&1; then
  92 AC_DEFINE(FD_NEED_SELECT_H, 1)
  93 AC_DEFINE(FD_HEADER_OK, 1)
  94 else
  95 AC_DEFINE(FD_NEED_SELECT_H, 0)
  96 fi
  97
  98 AC_DEFINE_UNQUOTED(HEADER_FD, ${s51_cv_fd})
  99
 100
 101 # Checking for functions/libs
 102 # ===========================================================================
 103 AC_CHECK_LIB(socket,socket)
 104 AC_CHECK_LIB(nsl,xdr_short)
 105 AC_CHECK_LIB(panel,panel_above,
 106 panel_ok="yes"
 107 curses_ok="yes"
 108 CURSES_LIBS="-lpanel -lcurses"
 109 ,
 110 panel_ok="no"
 111 AC_CHECK_LIB(curses,nl,
 112 curses_ok="yes"
 113 CURSES_LIBS="-lcurses"
 114 ,
 115 ncurses_ok="no")
 116 ,
 117 -lcurses)
 118 AC_SUBST(panel_ok)
 119 AC_SUBST(curses_ok)
 120 AC_SUBST(CURSES_LIBS)
 121
 122 AC_FUNC_VPRINTF
 123 AC_CHECK_FUNCS(vsnprintf vasprintf)
 124 AC_CHECK_FUNCS(strlen strcpy strcat strstr strcmp strerror strtok strdup)
 125 AC_CHECK_FUNCS(strchr memcpy)
 126 dnl AC_CHECK_FUNCS(getline)
 127 dnl AC_CHECK_FUNCS(getdelim)
 128 AC_CHECK_FUNCS(fgets)
 129 AC_CHECK_FUNCS(yylex)
 130
 131 AC_CACHE_CHECK(whether scanf knows %a, s51_cv_scanf_a,
 132 [echo "a b" >conftest.data
 133 AC_TRY_RUN([
 134 #include <stdio.h>
 135 void main(void)
 136 {
 137   FILE *f;
 138   char *a;
 139   int  i;
 140   if ((f= fopen("conftest.data", "r")) == NULL)
 141     exit(1);
 142   i= fscanf(f, " %a[a-z] ", &a);
 143   fclose(f);
 144   if (i == 0)
 145     exit(2);
 146   if (i == 1)
 147     exit(0);
 148   exit(3);
 149 }],
 150 s51_cv_scanf_a="yes",
 151 s51_cv_scanf_a="no",
 152 s51_cv_scanf_a="unknown")
 153 ])
 154 if test "$s51_cv_scanf_a" = "yes"; then
 155   AC_DEFINE(SCANF_A)
 156 fi
 157
 158 AC_CACHE_CHECK(whether getcwd is GNUish, s51_cv_getcwd,
 159 [AC_TRY_RUN([
 160 #include <unistd.h>
 161 void main(void)
 162 {
 163   if ((getcwd(NULL, 0)) == NULL)
 164     exit(1);
 165   exit(0);
 166 }],
 167 s51_cv_getcwd="yes",
 168 s51_cv_getcwd="no",
 169 s51_cv_getcwd="unknown")
 170 ])
 171 if test "$s51_cv_getcwd" = "yes"; then
 172   AC_DEFINE(GNU_GETCWD)
 173 fi
 174
 175 AC_DEFUN(dxpc_ACCEPT_LENGTH_T,
 176  [AC_CACHE_CHECK([for type of accept's length pointer parameter],
 177    dxpc_cv_accept_length_type,
 178    [ac_save_CPPFLAGS="$CPPFLAGS"
 179     dxpc_cv_accept_length_type=no
 180     for ac_val in int size_t socklen_t; do
 181       CPPFLAGS="$ac_save_CPPFLAGS -DACCEPT_SOCKLEN_T=$ac_val"
 182       AC_TRY_COMPILE([#include <sys/types.h>
 183 #include <sys/socket.h>],
 184         [struct sockaddr a; $ac_val len; accept (0, &a, &len);],
 185         [dxpc_cv_accept_length_type=$ac_val; break])
 186     done
 187     CPPFLAGS="$ac_save_CPPFLAGS"])
 188
 189   if test $dxpc_cv_accept_length_type != no; then
 190     AC_DEFINE_UNQUOTED(ACCEPT_SOCKLEN_T, $dxpc_cv_accept_length_type,
 191       [Define to be the type of accept's length parameter (without
 192 the \*').])
 193   fi
 194  ]
 195 )
 196
 197 dxpc_ACCEPT_LENGTH_T
 198
 199 # Macro definitions
 200 ###################
 201
 202 # DD_COPT macro checks if the compiler specified as the 1st parameter
 203 # supports option specified as the 2nd parameter
 204 # For example: DD_CPORT(CXX, fPIC)
 205
 206 AC_DEFUN(DD_COPT, [
 207 AC_CACHE_CHECK(whether $$1 accepts -$2,s51_cv_$1$2,
 208 cat >_test_.c <<EOF
 209 #include <stdio.h>
 210 void main(void) {}
 211 EOF
 212 $$1 -v -$2 -c _test_.c 1>&5 2>&5
 213 if test "$?" = "0"; then
 214   s51_cv_$1$2="yes"
 215 else
 216   s51_cv_$1$2="no"
 217 fi
 218 rm -f _test_.* a.out)
 219 ])
 220
 221
 222 # Checking characteristics of compilers and other programs
 223 # --------------------------------------------------------
 224 AC_C_BIGENDIAN
 225 AC_CACHE_CHECK(whether preprocessor accepts -MM or -M,s51_cv_MM,
 226 echo "#include <stdio.h>" >_test_.c
 227 echo "" >>_test_.c
 228 $CXXCPP -v -MM _test_.c 1>&5 2>&5
 229 if test "$?" = "0"; then
 230   s51_cv_MM="-MM"
 231 else
 232   s51_cv_MM="-M"
 233 fi
 234 rm -f _test_.*)
 235 M_OR_MM=$s51_cv_MM
 236 AC_SUBST(M_OR_MM)
 237
 238 # This is the first time when CFLAGS are set/modified!!
 239
 240 DD_COPT(CXX, ggdb)
 241 if test "$s51_cv_CXXggdb" = "yes"; then
 242     if test "$CXXFLAGS"x = x ;then
 243         CXXFLAGS="-ggdb -O"
 244     else
 245         CXXFLAGS="$CXXFLAGS -ggdb"
 246     fi
 247 fi
 248
 249 DD_COPT(CXX, pipe)
 250 if test "$s51_cv_CXXpipe" = "yes"; then
 251   CXXFLAGS="$CXXFLAGS -pipe"
 252 fi
 253
 254
 255 # Checks for typedefs, structures, and compiler characteristics.
 256 # ===========================================================================
 257
 258 AC_TYPE_SIGNAL
 259 AC_CHECK_SIZEOF(char)
 260 AC_CHECK_SIZEOF(short)
 261 AC_CHECK_SIZEOF(int)
 262 AC_CHECK_SIZEOF(long)
 263 AC_CHECK_SIZEOF(long long)
 264
 265 type_name()
 266 {
 267     if expr "$ac_cv_sizeof_char" '>=' "$1" >/dev/null; then
 268         echo "char"
 269         exit
 270     fi
 271     if expr "$ac_cv_sizeof_short" '>=' "$1" >/dev/null; then
 272         echo "short"
 273         exit
 274     fi
 275     if expr "$ac_cv_sizeof_int" '>=' "$1" >/dev/null; then
 276         echo "int"
 277         exit
 278     fi
 279     if expr "$ac_cv_sizeof_long" '>=' "$1" >/dev/null; then
 280         echo "long"
 281         exit
 282     fi
 283     if expr "$ac_cv_sizeof_long_long" '>=' "$1" >/dev/null; then
 284         echo "long long"
 285         exit
 286     fi
 287     echo "long long"
 288 }
 289
 290 AC_MSG_CHECKING(type name for byte)
 291 TYPE_BYTE=`type_name 1`
 292 AC_MSG_RESULT($TYPE_BYTE)
 293 AC_MSG_CHECKING(type name for word)
 294 TYPE_WORD=`type_name 2`
 295 AC_MSG_RESULT($TYPE_WORD)
 296 AC_MSG_CHECKING(type name for dword)
 297 TYPE_DWORD=`type_name 4`
 298 AC_MSG_RESULT($TYPE_DWORD)
 299 AC_DEFINE_UNQUOTED(TYPE_BYTE, $TYPE_BYTE)
 300 AC_DEFINE_UNQUOTED(TYPE_WORD, $TYPE_WORD)
 301 AC_DEFINE_UNQUOTED(TYPE_DWORD, $TYPE_DWORD)
 302
 303 # Generating output files
 304 # ===========================================================================
 305
 306 AC_OUTPUT(main.mk:main_in.mk
 307 sim.src/Makefile
 308 cmd.src/Makefile
 309 s51.src/Makefile
 310 avr.src/Makefile
 311 z80.src/Makefile
 312 gui.src/Makefile
 313 gui.src/serio.src/Makefile
 314 gui.src/portmon.src/Makefile
 315 doc/Makefile
 316 )
 317
 318
 319 # End of configure/configure.in