git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.1svn)
  30
  31 dnl add ${prefix}/lib/pkgconfig to the head of the PKG_CONFIG_PATH
  32 if test [x]${PKG_CONFIG_PATH} = x; then
  33     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig
  34 else
  35     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig:${PKG_CONFIG_PATH}
  36 fi
  37 export PKG_CONFIG_PATH
  38
  39 DEFINES=""
  40 AC_SUBST(DEFINES)
  41
  42 dnl Remember if the user explicity set CXXFLAGS
  43 if test -n "${CXXFLAGS}"; then
  44   user_set_cxxflags=yes
  45 fi
  46
  47 GR_X86_64               dnl check for lib64 suffix
  48 LF_CONFIGURE_CC
  49 LF_CONFIGURE_CXX
  50
  51 dnl The three macros above are known to override CXXFLAGS if the user
  52 dnl didn't specify them.  Though I'm sure somebody thought this was
  53 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  54 dnl selected files.  Thus we "undo" the damage here...
  55 dnl
  56 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  57 dnl the output of swig use use -O1 if we're using g++.
  58 dnl See Makefile.common for the rest of the magic.
  59 if test "$user_set_cxxflags" != yes; then
  60   autoconf_default_CXXFLAGS="$CXXFLAGS"
  61   CXXFLAGS=""
  62   if test "$GXX" = yes; then
  63     case "$host_cpu" in
  64         powerpc*)
  65            dnl "-O1" is broken on the PPC for some reason
  66            dnl (at least as of g++ 4.1.1)
  67            swig_CXXFLAGS="-g1 -O2"
  68         ;;
  69         *)
  70         swig_CXXFLAGS="-g -O1"
  71         ;;
  72     esac
  73   fi
  74 fi
  75 AC_SUBST(autoconf_default_CXXFLAGS)
  76 AC_SUBST(swig_CXXFLAGS)
  77
  78 LF_SET_WARNINGS
  79 GR_SET_GPROF
  80 GR_SET_PROF
  81 AM_PROG_AS
  82 AC_PROG_LN_S
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PATH_PROG([RM_PROG], [rm])
  86
  87 AC_LIBTOOL_WIN32_DLL
  88 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  89 AC_ENABLE_SHARED        dnl do build shared libraries
  90 AC_DISABLE_STATIC       dnl don't build static libraries
  91 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
  92 GR_FORTRAN
  93
  94 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  95 GR_SCRIPTING
  96
  97 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  98 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
  99
 100 dnl Checks for libraries.
 101 AC_CHECK_LIB(socket,socket)
 102
 103 dnl check for threads (mandatory)
 104 GR_OMNITHREAD
 105 CFLAGS="${CFLAGS} $PTHREAD_CFLAGS"
 106 CXXFLAGS="${CXXFLAGS} $PTHREAD_CFLAGS"
 107
 108 if test x$CXX_FOR_BUILD = x
 109 then
 110   if test x$cross_compiling = xno; then
 111     CXX_FOR_BUILD=${CXX}
 112   else
 113     CXX_FOR_BUILD=g++
 114   fi
 115 fi
 116
 117 AC_SUBST(CXX_FOR_BUILD)
 118
 119 dnl Check for SysV shm (mandatory)
 120 dnl FIXME this is no longer mandatory.  Check the macro.
 121 GR_SYSV_SHM
 122
 123 dnl Checks for header files.
 124 AC_HEADER_STDC
 125 AC_HEADER_SYS_WAIT
 126 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 127 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 128 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h)
 129 AC_CHECK_HEADERS(netinet/in.h)
 130 AC_CHECK_HEADERS(windows.h)
 131
 132 dnl Allow creating autoconf independent header files for bytesex routines
 133 AC_CHECK_HEADER(arpa/inet.h, [GR_HAVE_ARPA_INET=1],[GR_HAVE_ARPA_INET=0])
 134 AC_CHECK_HEADER(netinet/in.h, [GR_HAVE_NETINET_IN=1],[GR_HAVE_NETINET_IN=0])
 135 AC_CHECK_HEADER(byteswap.h, [GR_HAVE_BYTESWAP=1],[GR_HAVE_BYTESWAP=0])
 136 AC_SUBST(GR_HAVE_ARPA_INET)
 137 AC_SUBST(GR_HAVE_NETINET_IN)
 138 AC_SUBST(GR_HAVE_BYTESWAP)
 139
 140 dnl Checks for typedefs, structures, and compiler characteristics.
 141 AC_C_CONST
 142 AC_C_INLINE
 143 AC_TYPE_SIZE_T
 144 AC_HEADER_TIME
 145 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 146 AC_SUBST(GR_ARCH_BIGENDIAN)
 147 AC_STRUCT_TM
 148
 149 dnl Checks for library functions.
 150 AC_FUNC_ALLOCA
 151 AC_FUNC_SETVBUF_REVERSED
 152 AC_FUNC_VPRINTF
 153 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 154 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 155 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 156 AC_CHECK_FUNCS([sched_setaffinity])
 157
 158 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 159 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 160 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 161 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 162 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 163 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 164 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 165 #AC_FUNC_MKTIME
 166
 167 AH_BOTTOM([
 168 #ifndef HAVE_TRUNC
 169 #include <math.h>
 170 inline static double trunc(double x)
 171 {
 172   return x >= 0 ? floor(x) : ceil(x);
 173 }
 174 #endif
 175
 176 #ifndef HAVE_EXP10
 177 #include <math.h>
 178 inline static double exp10(double x)
 179 {
 180   return pow(10.0, x);
 181 }
 182 #endif
 183
 184 #ifdef HAVE_WINDOWS_H
 185 #define NOMINMAX
 186 #endif
 187 ])
 188
 189 GR_CHECK_SHM_OPEN
 190 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 191 GR_CHECK_CREATEFILEMAPPING
 192
 193 dnl Check for Mingw support
 194 GR_PWIN32
 195
 196 dnl Do we have "dot", part of the graphviz package from AT&T?
 197 dnl Doxgen will use it to draw pretty diagrams ;-)
 198 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 199
 200 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 201 AC_SUBST(FFTW3F_LIBS)
 202
 203 dnl conditional build stuff
 204 GR_CHECK_DOXYGEN
 205 GR_SET_MD_CPU
 206
 207 dnl Define where to look for cppunit includes and libs
 208 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 209 dnl Try using pkg-config first, then fall back to cppunit-config.
 210 PKG_CHECK_EXISTS(cppunit,
 211   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 212   [AM_PATH_CPPUNIT([1.9.14],[],
 213                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 214
 215 dnl see if GUILE is installed
 216 AC_PATH_PROG(GUILE,guile)
 217
 218 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 219 AC_SUBST(CPPUNIT_INCLUDES)
 220
 221 dnl Define where to find boost includes
 222 dnl defines BOOST_CFLAGS
 223 GR_REQUIRE_BOOST_INCLUDES
 224
 225 dnl If this is being done from a subversion tree, create variables
 226 GR_SUBVERSION
 227
 228 dnl Component specific configuration
 229 dnl The order of the GR_ macros determines the order of compilation
 230 dnl For -any- checks on $enable_all_components
 231 dnl use the following guildlines:
 232 dnl   yes : --enable-all-components was specified, so error out if any
 233 dnl         components do not pass configuration checks.
 234 dnl   no  : --disable-all-components was specified, so try to build the
 235 dnl         --enable'd components, and error out if any do not pass
 236 dnl         configuration checks.
 237 dnl   ""  : this option was not specified on the command line; try to
 238 dnl         build all components that are not --with'd, but don't
 239 dnl         error out if any component does not pass configuration checks.
 240 dnl
 241 dnl For each --enable-foo component, if that flag is not specified on
 242 dnl the command line, the related variable $enable_foo will be set to
 243 dnl $enable_all_components .
 244
 245 AC_ARG_ENABLE(
 246     [all-components],
 247     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 248 )
 249
 250 build_dirs="config"
 251 GRC_GRUEL                       dnl must come first
 252 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 253 GRC_GCELL
 254 GRC_GNURADIO_CORE
 255 GRC_PMT
 256 GRC_MBLOCK                      dnl this must come after GRC_PMT
 257 GRC_USRP
 258 GRC_GR_USRP                     dnl this must come after GRC_USRP
 259 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 260 # GRC_GR_MSDD6000               dnl disabled until component is fixed
 261 GRC_GR_AUDIO_ALSA
 262 GRC_GR_AUDIO_JACK
 263 GRC_GR_AUDIO_OSS
 264 GRC_GR_AUDIO_OSX
 265 GRC_GR_AUDIO_PORTAUDIO
 266 GRC_GR_AUDIO_WINDOWS
 267 GRC_GR_ATSC
 268 GRC_GR_COMEDI
 269 GRC_GR_CVSD_VOCODER
 270 GRC_GR_GPIO
 271 GRC_GR_GSM_FR_VOCODER
 272 GRC_GR_PAGER
 273 GRC_GR_RADAR_MONO
 274 GRC_GR_RADIO_ASTRONOMY
 275 GRC_GR_TRELLIS
 276 GRC_GR_VIDEO_SDL
 277 GRC_GR_WXGUI
 278 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 279 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 280 GRC_GNURADIO_EXAMPLES           dnl must come last
 281
 282 # Each component is now either to be built, was skipped, will be
 283 # included from pre-installed libraries and includes, or failed
 284 # dependencies.
 285 AC_SUBST([build_dirs], [$build_dirs])
 286 AC_SUBST([skipped_dirs], [$skipped_dirs])
 287 AC_SUBST([with_dirs], [$with_dirs])
 288
 289 # fix for older autotools that don't define "abs_top_YYY" by default
 290 AC_SUBST(abs_top_srcdir)
 291 AC_SUBST(abs_top_builddir)
 292
 293 # 'with' variables - the pre-installed libraries, includes, and paths
 294 # - must always come last in the lists, so they require special
 295 # treatment.
 296 AC_SUBST(with_INCLUDES)
 297 AC_SUBST(with_SWIG_INCLUDES)
 298 AC_SUBST(with_PYDIRPATH)
 299 AC_SUBST(with_SWIGDIRPATH)
 300 AC_SUBST(with_LIBDIRPATH)
 301
 302 # Local files tweaked by AC
 303 AC_CONFIG_FILES([\
 304     Makefile \
 305     run_tests.sh \
 306     config/Makefile \
 307 ])
 308
 309 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 310 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 311
 312 AC_OUTPUT
 313
 314 echo
 315 echo "*********************************************************************"
 316 echo The following GNU Radio components have been successfully configured:
 317 echo
 318 for dir in $build_dirs
 319 do
 320     echo $dir
 321 done
 322 echo
 323 echo You my now run the 'make' command to build these components.
 324 echo
 325 if test "$skipped_dirs" != ""; then
 326     echo "*********************************************************************"
 327     echo The following components were skipped either because you asked not
 328     echo to build them or they didn\'t pass configuration checks:
 329     echo
 330     for dir in $skipped_dirs
 331     do
 332         echo $dir
 333     done
 334     echo
 335     echo These components will not be built.
 336     echo
 337 fi
 338 if test "$with_dirs" != ""; then
 339     echo "*********************************************************************"
 340     echo The following components will be included from pre-installed
 341     echo libraries and includes:
 342     echo
 343     for dir in $with_dirs
 344     do
 345         echo $dir
 346     done
 347     echo
 348     echo These components will not be built.
 349     echo
 350 fi