git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.1svn)
  30
  31 DEFINES=""
  32 AC_SUBST(DEFINES)
  33
  34 dnl Remember if the user explicity set CXXFLAGS
  35 if test -n "${CXXFLAGS}"; then
  36   user_set_cxxflags=yes
  37 fi
  38
  39 LF_CONFIGURE_CC
  40 LF_CONFIGURE_CXX
  41 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  42
  43 dnl The three macros above are known to override CXXFLAGS if the user
  44 dnl didn't specify them.  Though I'm sure somebody thought this was
  45 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  46 dnl selected files.  Thus we "undo" the damage here...
  47 dnl
  48 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  49 dnl the output of swig use use -O1 if we're using g++.
  50 dnl See Makefile.common for the rest of the magic.
  51 if test "$user_set_cxxflags" != yes; then
  52   autoconf_default_CXXFLAGS="$CXXFLAGS"
  53   if test "$GXX" = yes; then
  54     case "$host_cpu" in
  55         powerpc*)
  56            dnl "-O1" is broken on the PPC for some reason
  57            dnl (at least as of g++ 4.1.1)
  58            swig_CXXFLAGS="-g1 -O2 -Wno-strict-aliasing -Wno-parentheses"
  59         ;;
  60         *)
  61         swig_CXXFLAGS="-g -O1 -Wno-strict-aliasing -Wno-parentheses"
  62         ;;
  63     esac
  64   fi
  65 fi
  66 AC_SUBST(autoconf_default_CXXFLAGS)
  67 AC_SUBST(swig_CXXFLAGS)
  68
  69
  70 dnl add ${prefix}/lib${gr_libdir_suffix}/pkgconfig to the head of the PKG_CONFIG_PATH
  71 if test x${PKG_CONFIG_PATH} = x; then
  72     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig
  73 else
  74     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig:${PKG_CONFIG_PATH}
  75 fi
  76 export PKG_CONFIG_PATH
  77
  78
  79 GR_SET_GPROF
  80 GR_SET_PROF
  81 AM_PROG_AS
  82 AC_PROG_LN_S
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PATH_PROG([RM_PROG], [rm])
  86
  87 AC_LIBTOOL_WIN32_DLL
  88 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  89 AC_ENABLE_SHARED        dnl do build shared libraries
  90 AC_DISABLE_STATIC       dnl don't build static libraries
  91 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
  92 GR_FORTRAN
  93
  94 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  95 GR_SCRIPTING
  96
  97 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  98 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
  99
 100 dnl Checks for libraries.
 101 AC_CHECK_LIB(socket,socket)
 102
 103 dnl check for omnithreads (will soon be removed)
 104 GR_OMNITHREAD
 105 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 106 CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
 107
 108 dnl Set the c++ compiler that we use for the build system when cross compiling
 109 if test x$CXX_FOR_BUILD = x
 110 then
 111   if test x$cross_compiling = xno; then
 112     CXX_FOR_BUILD=${CXX}
 113   else
 114     CXX_FOR_BUILD=g++
 115   fi
 116 fi
 117 AC_SUBST(CXX_FOR_BUILD)
 118
 119 dnl Check for SysV shm (mandatory)
 120 dnl FIXME this is no longer mandatory.  Check the macro.
 121 GR_SYSV_SHM
 122
 123 dnl Checks for header files.
 124 AC_HEADER_STDC
 125 AC_HEADER_SYS_WAIT
 126 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 127 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 128 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h)
 129 AC_CHECK_HEADERS(netinet/in.h)
 130 AC_CHECK_HEADERS(windows.h)
 131 AC_CHECK_HEADERS(vec_types.h)
 132
 133 dnl Checks for typedefs, structures, and compiler characteristics.
 134 AC_C_CONST
 135 AC_C_INLINE
 136 AC_TYPE_SIZE_T
 137 AC_HEADER_TIME
 138 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 139 AC_SUBST(GR_ARCH_BIGENDIAN)
 140 AC_STRUCT_TM
 141
 142 dnl Checks for library functions.
 143 AC_FUNC_ALLOCA
 144 AC_FUNC_SETVBUF_REVERSED
 145 AC_FUNC_VPRINTF
 146 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 147 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 148 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 149 AC_CHECK_FUNCS([sched_setaffinity])
 150
 151 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 152 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 153 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 154 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 155 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 156 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 157 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 158 #AC_FUNC_MKTIME
 159
 160 AH_BOTTOM([
 161 #ifndef HAVE_TRUNC
 162 #include <math.h>
 163 inline static double trunc(double x)
 164 {
 165   return x >= 0 ? floor(x) : ceil(x);
 166 }
 167 #endif
 168
 169 #ifndef HAVE_EXP10
 170 #include <math.h>
 171 inline static double exp10(double x)
 172 {
 173   return pow(10.0, x);
 174 }
 175 #endif
 176
 177 #ifdef HAVE_WINDOWS_H
 178 #define NOMINMAX
 179 #endif
 180 ])
 181
 182 GR_CHECK_SHM_OPEN
 183 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 184 GR_CHECK_CREATEFILEMAPPING
 185
 186 dnl Check for Mingw support
 187 GR_PWIN32
 188
 189 dnl Do we have "dot", part of the graphviz package from AT&T?
 190 dnl Doxgen will use it to draw pretty diagrams ;-)
 191 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 192
 193 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 194 AC_SUBST(FFTW3F_LIBS)
 195
 196 dnl conditional build stuff
 197 GR_CHECK_DOXYGEN
 198 GR_SET_MD_CPU
 199
 200 dnl Define where to look for cppunit includes and libs
 201 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 202 dnl Try using pkg-config first, then fall back to cppunit-config.
 203 PKG_CHECK_EXISTS(cppunit,
 204   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 205   [AM_PATH_CPPUNIT([1.9.14],[],
 206                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 207
 208 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 209 AC_SUBST(CPPUNIT_INCLUDES)
 210
 211 dnl see if GUILE is installed
 212 AC_PATH_PROG(GUILE,guile)
 213
 214 dnl
 215 dnl We require the boost headers, thread lib and date_time lib.
 216 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 217 dnl
 218 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 219 AX_BOOST_BASE([1.35])
 220
 221 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 222 AX_BOOST_THREAD
 223 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 224 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 225
 226 dnl
 227 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 228 dnl
 229 AX_BOOST_DATE_TIME
 230 dnl AX_BOOST_FILESYSTEM
 231 dnl AX_BOOST_IOSTREAMS
 232 dnl AX_BOOST_PROGRAM_OPTIONS
 233 dnl AX_BOOST_REGEX
 234 dnl AX_BOOST_SERIALIZATION
 235 dnl AX_BOOST_SIGNALS
 236 dnl AX_BOOST_SYSTEM
 237 dnl AX_BOOST_TEST_EXEC_MONITOR
 238 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 239 dnl AX_BOOST_WSERIALIZATION
 240
 241
 242 dnl If this is being done from a subversion tree, create variables
 243 GR_SUBVERSION
 244
 245 dnl Component specific configuration
 246 dnl The order of the GR_ macros determines the order of compilation
 247 dnl For -any- checks on $enable_all_components
 248 dnl use the following guidelines:
 249 dnl   yes : --enable-all-components was specified, so error out if any
 250 dnl         components do not pass configuration checks.
 251 dnl   no  : --disable-all-components was specified, so try to build the
 252 dnl         --enable'd components, and error out if any do not pass
 253 dnl         configuration checks.
 254 dnl   ""  : this option was not specified on the command line; try to
 255 dnl         build all components that are not --with'd, but don't
 256 dnl         error out if any component does not pass configuration checks.
 257 dnl
 258 dnl For each --enable-foo component, if that flag is not specified on
 259 dnl the command line, the related variable $enable_foo will be set to
 260 dnl $enable_all_components .
 261
 262 AC_ARG_ENABLE(
 263     [all-components],
 264     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 265 )
 266
 267 build_dirs="config"
 268 GRC_GRUEL                       dnl must come first
 269 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 270 GRC_GCELL
 271 GRC_GNURADIO_CORE
 272 GRC_PMT
 273 GRC_MBLOCK                      dnl this must come after GRC_PMT
 274 GRC_USRP
 275 GRC_USRP2
 276 GRC_GR_USRP                     dnl this must come after GRC_USRP
 277 GRC_GR_USRP2
 278 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 279 GRC_GR_MSDD6000
 280 GRC_GR_AUDIO_ALSA
 281 GRC_GR_AUDIO_JACK
 282 GRC_GR_AUDIO_OSS
 283 GRC_GR_AUDIO_OSX
 284 GRC_GR_AUDIO_PORTAUDIO
 285 GRC_GR_AUDIO_WINDOWS
 286 GRC_GR_ATSC
 287 GRC_GR_COMEDI
 288 GRC_GR_CVSD_VOCODER
 289 GRC_GR_GPIO
 290 GRC_GR_GSM_FR_VOCODER
 291 GRC_GR_PAGER
 292 GRC_GR_RADAR_MONO
 293 GRC_GR_RADIO_ASTRONOMY
 294 GRC_GR_TRELLIS
 295 GRC_GR_VIDEO_SDL
 296 GRC_GR_WXGUI
 297 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 298 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 299 GRC_GNURADIO_EXAMPLES           dnl must come after all GRC_GR_*
 300 GRC_GRC
 301
 302 # Each component is now either to be built, was skipped, will be
 303 # included from pre-installed libraries and includes, or failed
 304 # dependencies.
 305 AC_SUBST([build_dirs], [$build_dirs])
 306 AC_SUBST([skipped_dirs], [$skipped_dirs])
 307 AC_SUBST([with_dirs], [$with_dirs])
 308
 309 # fix for older autotools that don't define "abs_top_YYY" by default
 310 AC_SUBST(abs_top_srcdir)
 311 AC_SUBST(abs_top_builddir)
 312
 313 # 'with' variables - the pre-installed libraries, includes, and paths
 314 # - must always come last in the lists, so they require special
 315 # treatment.
 316 AC_SUBST(with_INCLUDES)
 317 AC_SUBST(with_SWIG_INCLUDES)
 318 AC_SUBST(with_PYDIRPATH)
 319 AC_SUBST(with_SWIGDIRPATH)
 320 AC_SUBST(with_LIBDIRPATH)
 321
 322 # Local files tweaked by AC
 323 AC_CONFIG_FILES([\
 324     Makefile \
 325     run_tests.sh \
 326     config/Makefile \
 327 ])
 328
 329 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 330 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 331
 332 dnl Enable warnings as the last thing before generating output, since
 333 dnl this may add -Werror to CFLAGS which can cause various configure
 334 dnl checks to fail.
 335 LF_SET_WARNINGS
 336
 337 AC_OUTPUT
 338
 339 echo
 340 echo "*********************************************************************"
 341 echo The following GNU Radio components have been successfully configured:
 342 echo
 343 for dir in $build_dirs
 344 do
 345     echo $dir
 346 done
 347 echo
 348 echo You my now run the 'make' command to build these components.
 349 echo
 350 if test "$skipped_dirs" != ""; then
 351     echo "*********************************************************************"
 352     echo The following components were skipped either because you asked not
 353     echo to build them or they didn\'t pass configuration checks:
 354     echo
 355     for dir in $skipped_dirs
 356     do
 357         echo $dir
 358     done
 359     echo
 360     echo These components will not be built.
 361     echo
 362 fi
 363 if test "$with_dirs" != ""; then
 364     echo "*********************************************************************"
 365     echo The following components will be included from pre-installed
 366     echo libraries and includes:
 367     echo
 368     for dir in $with_dirs
 369     do
 370         echo $dir
 371     done
 372     echo
 373     echo These components will not be built.
 374     echo
 375 fi