git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.1svn)
  30
  31 DEFINES=""
  32 AC_SUBST(DEFINES)
  33
  34 dnl Remember if the user explicity set CXXFLAGS
  35 if test -n "${CXXFLAGS}"; then
  36   user_set_cxxflags=yes
  37 fi
  38
  39 LF_CONFIGURE_CC
  40 LF_CONFIGURE_CXX
  41 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  42
  43 dnl The three macros above are known to override CXXFLAGS if the user
  44 dnl didn't specify them.  Though I'm sure somebody thought this was
  45 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  46 dnl selected files.  Thus we "undo" the damage here...
  47 dnl
  48 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  49 dnl the output of swig use use -O1 if we're using g++.
  50 dnl See Makefile.common for the rest of the magic.
  51 if test "$user_set_cxxflags" != yes; then
  52   autoconf_default_CXXFLAGS="$CXXFLAGS"
  53   CXXFLAGS=""
  54   if test "$GXX" = yes; then
  55     case "$host_cpu" in
  56         powerpc*)
  57            dnl "-O1" is broken on the PPC for some reason
  58            dnl (at least as of g++ 4.1.1)
  59            swig_CXXFLAGS="-g1 -O2"
  60         ;;
  61         *)
  62         swig_CXXFLAGS="-g -O1"
  63         ;;
  64     esac
  65   fi
  66 fi
  67 AC_SUBST(autoconf_default_CXXFLAGS)
  68 AC_SUBST(swig_CXXFLAGS)
  69
  70
  71 dnl add ${prefix}/lib${gr_libdir_suffix}/pkgconfig to the head of the PKG_CONFIG_PATH
  72 if test x${PKG_CONFIG_PATH} = x; then
  73     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig
  74 else
  75     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig:${PKG_CONFIG_PATH}
  76 fi
  77 export PKG_CONFIG_PATH
  78
  79
  80 LF_SET_WARNINGS
  81 GR_SET_GPROF
  82 GR_SET_PROF
  83 AM_PROG_AS
  84 AC_PROG_LN_S
  85 AC_PROG_MAKE_SET
  86 AC_PROG_INSTALL
  87 AC_PATH_PROG([RM_PROG], [rm])
  88
  89 AC_LIBTOOL_WIN32_DLL
  90 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  91 AC_ENABLE_SHARED        dnl do build shared libraries
  92 AC_DISABLE_STATIC       dnl don't build static libraries
  93 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
  94 GR_FORTRAN
  95
  96 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  97 GR_SCRIPTING
  98
  99 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
 100 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
 101
 102 dnl Checks for libraries.
 103 AC_CHECK_LIB(socket,socket)
 104
 105 dnl check for omnithreads (will soon be removed)
 106 GR_OMNITHREAD
 107 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 108 CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
 109
 110 dnl Set the c++ compiler that we use for the build system when cross compiling
 111 if test x$CXX_FOR_BUILD = x
 112 then
 113   if test x$cross_compiling = xno; then
 114     CXX_FOR_BUILD=${CXX}
 115   else
 116     CXX_FOR_BUILD=g++
 117   fi
 118 fi
 119 AC_SUBST(CXX_FOR_BUILD)
 120
 121 dnl Check for SysV shm (mandatory)
 122 dnl FIXME this is no longer mandatory.  Check the macro.
 123 GR_SYSV_SHM
 124
 125 dnl Checks for header files.
 126 AC_HEADER_STDC
 127 AC_HEADER_SYS_WAIT
 128 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 129 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 130 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h)
 131 AC_CHECK_HEADERS(netinet/in.h)
 132 AC_CHECK_HEADERS(windows.h)
 133
 134 dnl Checks for typedefs, structures, and compiler characteristics.
 135 AC_C_CONST
 136 AC_C_INLINE
 137 AC_TYPE_SIZE_T
 138 AC_HEADER_TIME
 139 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 140 AC_SUBST(GR_ARCH_BIGENDIAN)
 141 AC_STRUCT_TM
 142
 143 dnl Checks for library functions.
 144 AC_FUNC_ALLOCA
 145 AC_FUNC_SETVBUF_REVERSED
 146 AC_FUNC_VPRINTF
 147 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 148 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 149 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 150 AC_CHECK_FUNCS([sched_setaffinity])
 151
 152 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 153 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 154 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 155 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 156 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 157 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 158 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 159 #AC_FUNC_MKTIME
 160
 161 AH_BOTTOM([
 162 #ifndef HAVE_TRUNC
 163 #include <math.h>
 164 inline static double trunc(double x)
 165 {
 166   return x >= 0 ? floor(x) : ceil(x);
 167 }
 168 #endif
 169
 170 #ifndef HAVE_EXP10
 171 #include <math.h>
 172 inline static double exp10(double x)
 173 {
 174   return pow(10.0, x);
 175 }
 176 #endif
 177
 178 #ifdef HAVE_WINDOWS_H
 179 #define NOMINMAX
 180 #endif
 181 ])
 182
 183 GR_CHECK_SHM_OPEN
 184 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 185 GR_CHECK_CREATEFILEMAPPING
 186
 187 dnl Check for Mingw support
 188 GR_PWIN32
 189
 190 dnl Do we have "dot", part of the graphviz package from AT&T?
 191 dnl Doxgen will use it to draw pretty diagrams ;-)
 192 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 193
 194 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 195 AC_SUBST(FFTW3F_LIBS)
 196
 197 dnl conditional build stuff
 198 GR_CHECK_DOXYGEN
 199 GR_SET_MD_CPU
 200
 201 dnl Define where to look for cppunit includes and libs
 202 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 203 dnl Try using pkg-config first, then fall back to cppunit-config.
 204 PKG_CHECK_EXISTS(cppunit,
 205   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 206   [AM_PATH_CPPUNIT([1.9.14],[],
 207                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 208
 209 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 210 AC_SUBST(CPPUNIT_INCLUDES)
 211
 212 dnl see if GUILE is installed
 213 AC_PATH_PROG(GUILE,guile)
 214
 215 dnl
 216 dnl We require the boost headers, thread lib and date_time lib.
 217 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 218 dnl
 219 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 220 AX_BOOST_BASE([1.35])
 221
 222 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 223 AX_BOOST_THREAD
 224 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 225 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 226
 227 dnl
 228 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 229 dnl
 230 AX_BOOST_DATE_TIME
 231 dnl AX_BOOST_FILESYSTEM
 232 dnl AX_BOOST_IOSTREAMS
 233 dnl AX_BOOST_PROGRAM_OPTIONS
 234 dnl AX_BOOST_REGEX
 235 dnl AX_BOOST_SERIALIZATION
 236 dnl AX_BOOST_SIGNALS
 237 dnl AX_BOOST_SYSTEM
 238 dnl AX_BOOST_TEST_EXEC_MONITOR
 239 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 240 dnl AX_BOOST_WSERIALIZATION
 241
 242
 243 dnl If this is being done from a subversion tree, create variables
 244 GR_SUBVERSION
 245
 246 dnl Component specific configuration
 247 dnl The order of the GR_ macros determines the order of compilation
 248 dnl For -any- checks on $enable_all_components
 249 dnl use the following guildlines:
 250 dnl   yes : --enable-all-components was specified, so error out if any
 251 dnl         components do not pass configuration checks.
 252 dnl   no  : --disable-all-components was specified, so try to build the
 253 dnl         --enable'd components, and error out if any do not pass
 254 dnl         configuration checks.
 255 dnl   ""  : this option was not specified on the command line; try to
 256 dnl         build all components that are not --with'd, but don't
 257 dnl         error out if any component does not pass configuration checks.
 258 dnl
 259 dnl For each --enable-foo component, if that flag is not specified on
 260 dnl the command line, the related variable $enable_foo will be set to
 261 dnl $enable_all_components .
 262
 263 AC_ARG_ENABLE(
 264     [all-components],
 265     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 266 )
 267
 268 build_dirs="config"
 269 GRC_GRUEL                       dnl must come first
 270 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 271 GRC_GCELL
 272 GRC_GNURADIO_CORE
 273 GRC_PMT
 274 GRC_MBLOCK                      dnl this must come after GRC_PMT
 275 GRC_USRP
 276 GRC_GR_USRP                     dnl this must come after GRC_USRP
 277 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 278 GRC_GR_MSDD6000
 279 GRC_GR_AUDIO_ALSA
 280 GRC_GR_AUDIO_JACK
 281 GRC_GR_AUDIO_OSS
 282 GRC_GR_AUDIO_OSX
 283 GRC_GR_AUDIO_PORTAUDIO
 284 GRC_GR_AUDIO_WINDOWS
 285 GRC_GR_ATSC
 286 GRC_GR_COMEDI
 287 GRC_GR_CVSD_VOCODER
 288 GRC_GR_GPIO
 289 GRC_GR_GSM_FR_VOCODER
 290 GRC_GR_PAGER
 291 GRC_GR_RADAR_MONO
 292 GRC_GR_RADIO_ASTRONOMY
 293 GRC_GR_TRELLIS
 294 GRC_GR_VIDEO_SDL
 295 GRC_GR_WXGUI
 296 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 297 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 298 GRC_GNURADIO_EXAMPLES           dnl must come after all GRC_GR_*
 299 GRC_GRC
 300
 301 # Each component is now either to be built, was skipped, will be
 302 # included from pre-installed libraries and includes, or failed
 303 # dependencies.
 304 AC_SUBST([build_dirs], [$build_dirs])
 305 AC_SUBST([skipped_dirs], [$skipped_dirs])
 306 AC_SUBST([with_dirs], [$with_dirs])
 307
 308 # fix for older autotools that don't define "abs_top_YYY" by default
 309 AC_SUBST(abs_top_srcdir)
 310 AC_SUBST(abs_top_builddir)
 311
 312 # 'with' variables - the pre-installed libraries, includes, and paths
 313 # - must always come last in the lists, so they require special
 314 # treatment.
 315 AC_SUBST(with_INCLUDES)
 316 AC_SUBST(with_SWIG_INCLUDES)
 317 AC_SUBST(with_PYDIRPATH)
 318 AC_SUBST(with_SWIGDIRPATH)
 319 AC_SUBST(with_LIBDIRPATH)
 320
 321 # Local files tweaked by AC
 322 AC_CONFIG_FILES([\
 323     Makefile \
 324     run_tests.sh \
 325     config/Makefile \
 326 ])
 327
 328 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 329 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 330
 331 AC_OUTPUT
 332
 333 echo
 334 echo "*********************************************************************"
 335 echo The following GNU Radio components have been successfully configured:
 336 echo
 337 for dir in $build_dirs
 338 do
 339     echo $dir
 340 done
 341 echo
 342 echo You my now run the 'make' command to build these components.
 343 echo
 344 if test "$skipped_dirs" != ""; then
 345     echo "*********************************************************************"
 346     echo The following components were skipped either because you asked not
 347     echo to build them or they didn\'t pass configuration checks:
 348     echo
 349     for dir in $skipped_dirs
 350     do
 351         echo $dir
 352     done
 353     echo
 354     echo These components will not be built.
 355     echo
 356 fi
 357 if test "$with_dirs" != ""; then
 358     echo "*********************************************************************"
 359     echo The following components will be included from pre-installed
 360     echo libraries and includes:
 361     echo
 362     for dir in $with_dirs
 363     do
 364         echo $dir
 365     done
 366     echo
 367     echo These components will not be built.
 368     echo
 369 fi