git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.1svn)
  30
  31 dnl add ${prefix}/lib/pkgconfig to the head of the PKG_CONFIG_PATH
  32 if test [x]${PKG_CONFIG_PATH} = x; then
  33     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig
  34 else
  35     PKG_CONFIG_PATH=${prefix}/lib/pkgconfig:${PKG_CONFIG_PATH}
  36 fi
  37 export PKG_CONFIG_PATH
  38
  39 DEFINES=""
  40 AC_SUBST(DEFINES)
  41
  42 dnl Remember if the user explicity set CXXFLAGS
  43 if test -n "${CXXFLAGS}"; then
  44   user_set_cxxflags=yes
  45 fi
  46
  47 GR_X86_64               dnl check for lib64 suffix
  48 LF_CONFIGURE_CC
  49 LF_CONFIGURE_CXX
  50
  51 dnl The three macros above are known to override CXXFLAGS if the user
  52 dnl didn't specify them.  Though I'm sure somebody thought this was
  53 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  54 dnl selected files.  Thus we "undo" the damage here...
  55 dnl
  56 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  57 dnl the output of swig use use -O1 if we're using g++.
  58 dnl See Makefile.common for the rest of the magic.
  59 if test "$user_set_cxxflags" != yes; then
  60   autoconf_default_CXXFLAGS="$CXXFLAGS"
  61   CXXFLAGS=""
  62   if test "$GXX" = yes; then
  63     case "$host_cpu" in
  64         powerpc*)
  65            dnl "-O1" is broken on the PPC for some reason
  66            dnl (at least as of g++ 4.1.1)
  67            swig_CXXFLAGS="-g1 -O2"
  68         ;;
  69         *)
  70         swig_CXXFLAGS="-g -O1"
  71         ;;
  72     esac
  73   fi
  74 fi
  75 AC_SUBST(autoconf_default_CXXFLAGS)
  76 AC_SUBST(swig_CXXFLAGS)
  77
  78 LF_SET_WARNINGS
  79 GR_SET_GPROF
  80 GR_SET_PROF
  81 AM_PROG_AS
  82 AC_PROG_LN_S
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PATH_PROG([RM_PROG], [rm])
  86
  87 AC_LIBTOOL_WIN32_DLL
  88 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  89 AC_ENABLE_SHARED        dnl do build shared libraries
  90 AC_DISABLE_STATIC       dnl don't build static libraries
  91 AC_PROG_LIBTOOL
  92 GR_FORTRAN
  93
  94 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  95 GR_SCRIPTING
  96
  97 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  98 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
  99
 100 dnl Checks for libraries.
 101 AC_CHECK_LIB(socket,socket)
 102
 103 dnl check for threads (mandatory)
 104 GR_OMNITHREAD
 105 CFLAGS="${CFLAGS} $PTHREAD_CFLAGS"
 106 CXXFLAGS="${CXXFLAGS} $PTHREAD_CFLAGS"
 107
 108 if test x$CXX_FOR_BUILD = x
 109 then
 110   if test x$cross_compiling = xno; then
 111     CXX_FOR_BUILD=${CXX}
 112   else
 113     CXX_FOR_BUILD=g++
 114   fi
 115 fi
 116
 117 AC_SUBST(CXX_FOR_BUILD)
 118
 119 dnl Check for SysV shm (mandatory)
 120 dnl FIXME this is no longer mandatory.  Check the macro.
 121 GR_SYSV_SHM
 122
 123 dnl Checks for header files.
 124 AC_HEADER_STDC
 125 AC_HEADER_SYS_WAIT
 126 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 127 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 128 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h)
 129 AC_CHECK_HEADERS(netinet/in.h)
 130 AC_CHECK_HEADERS(windows.h)
 131
 132 dnl Checks for typedefs, structures, and compiler characteristics.
 133 AC_C_CONST
 134 AC_C_INLINE
 135 AC_TYPE_SIZE_T
 136 AC_HEADER_TIME
 137 AC_C_BIGENDIAN
 138 AC_STRUCT_TM
 139
 140 dnl Checks for library functions.
 141 AC_FUNC_ALLOCA
 142 AC_FUNC_SETVBUF_REVERSED
 143 AC_FUNC_VPRINTF
 144 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 145 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 146 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 147 AC_CHECK_FUNCS([sched_setaffinity])
 148
 149 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 150 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 151 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 152 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 153 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 154 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 155 #AC_FUNC_MKTIME
 156
 157 AH_BOTTOM([
 158 #ifndef HAVE_TRUNC
 159 #include <math.h>
 160 inline static double trunc(double x)
 161 {
 162   return x >= 0 ? floor(x) : ceil(x);
 163 }
 164 #endif
 165
 166 #ifndef HAVE_EXP10
 167 #include <math.h>
 168 inline static double exp10(double x)
 169 {
 170   return pow(10.0, x);
 171 }
 172 #endif
 173
 174 #ifdef HAVE_WINDOWS_H
 175 #define NOMINMAX
 176 #endif
 177 ])
 178
 179 GR_CHECK_SHM_OPEN
 180 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 181 GR_CHECK_CREATEFILEMAPPING
 182
 183 dnl Check for Mingw support
 184 GR_PWIN32
 185
 186 dnl Do we have "dot", part of the graphviz package from AT&T?
 187 dnl Doxgen will use it to draw pretty diagrams ;-)
 188 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 189
 190 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 191 AC_SUBST(FFTW3F_LIBS)
 192
 193 dnl conditional build stuff
 194 GR_CHECK_DOXYGEN
 195 GR_SET_MD_CPU
 196
 197 dnl Define where to look for cppunit includes and libs
 198 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 199 dnl Try using pkg-config first, then fall back to cppunit-config.
 200 PKG_CHECK_EXISTS(cppunit,
 201   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 202   [AM_PATH_CPPUNIT([1.9.14],[],
 203                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 204
 205 dnl see if GUILE is installed
 206 AC_PATH_PROG(GUILE,guile)
 207
 208 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 209 AC_SUBST(CPPUNIT_INCLUDES)
 210
 211 dnl Define where to find boost includes
 212 dnl defines BOOST_CFLAGS
 213 GR_REQUIRE_BOOST_INCLUDES
 214
 215 dnl If this is being done from a subversion tree, create variables
 216 GR_SUBVERSION
 217
 218 dnl Component specific configuration
 219 dnl The order of the GR_ macros determines the order of compilation
 220 dnl For -any- checks on $enable_all_components
 221 dnl use the following guildlines:
 222 dnl   yes : --enable-all-components was specified, so error out if any
 223 dnl         components do not pass configuration checks.
 224 dnl   no  : --disable-all-components was specified, so try to build the
 225 dnl         --enable'd components, and error out if any do not pass
 226 dnl         configuration checks.
 227 dnl   ""  : this option was not specified on the command line; try to
 228 dnl         build all components that are not --with'd, but don't
 229 dnl         error out if any component does not pass configuration checks.
 230 dnl
 231 dnl For each --enable-foo component, if that flag is not specified on
 232 dnl the command line, the related variable $enable_foo will be set to
 233 dnl $enable_all_components .
 234
 235 AC_ARG_ENABLE(
 236     [all-components],
 237     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 238 )
 239
 240 build_dirs="config"
 241 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 242 GRC_PMT
 243 GRC_MBLOCK                      dnl this must come after GRC_PMT
 244 GRC_GCELL
 245 GRC_GNURADIO_CORE
 246 GRC_USRP
 247 GRC_GR_USRP                     dnl this must come after GRC_USRP
 248 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 249 GRC_GR_MSDD6000
 250 GRC_GR_AUDIO_ALSA
 251 GRC_GR_AUDIO_JACK
 252 GRC_GR_AUDIO_OSS
 253 GRC_GR_AUDIO_OSX
 254 GRC_GR_AUDIO_PORTAUDIO
 255 GRC_GR_AUDIO_WINDOWS
 256 GRC_GR_ATSC
 257 GRC_GR_COMEDI
 258 GRC_GR_CVSD_VOCODER
 259 GRC_GR_GPIO
 260 GRC_GR_GSM_FR_VOCODER
 261 GRC_GR_PAGER
 262 GRC_GR_RADAR_MONO
 263 GRC_GR_RADIO_ASTRONOMY
 264 GRC_GR_TRELLIS
 265 GRC_GR_VIDEO_SDL
 266 GRC_GR_WXGUI
 267 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 268 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 269 GRC_GNURADIO_EXAMPLES           dnl must come last
 270
 271 # Each component is now either to be built, was skipped, will be
 272 # included from pre-installed libraries and includes, or failed
 273 # dependencies.
 274 AC_SUBST([build_dirs], [$build_dirs])
 275 AC_SUBST([skipped_dirs], [$skipped_dirs])
 276 AC_SUBST([with_dirs], [$with_dirs])
 277
 278 # fix for older autotools that don't define "abs_top_YYY" by default
 279 AC_SUBST(abs_top_srcdir)
 280 AC_SUBST(abs_top_builddir)
 281
 282 # 'with' variables - the pre-installed libraries, includes, and paths
 283 # - must always come last in the lists, so they require special
 284 # treatment.
 285 AC_SUBST(with_INCLUDES)
 286 AC_SUBST(with_SWIG_INCLUDES)
 287 AC_SUBST(with_PYDIRPATH)
 288 AC_SUBST(with_SWIGDIRPATH)
 289 AC_SUBST(with_LIBDIRPATH)
 290
 291 # Local files tweaked by AC
 292 AC_CONFIG_FILES([\
 293     Makefile \
 294     run_tests.sh \
 295     config/Makefile \
 296 ])
 297
 298 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 299 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 300
 301 AC_OUTPUT
 302
 303 echo
 304 echo "*********************************************************************"
 305 echo The following GNU Radio components have been successfully configured:
 306 echo
 307 for dir in $build_dirs
 308 do
 309     echo $dir
 310 done
 311 echo
 312 echo You my now run the 'make' command to build these components.
 313 echo
 314 if test "$skipped_dirs" != ""; then
 315     echo "*********************************************************************"
 316     echo The following components were skipped either because you asked not
 317     echo to build them or they didn\'t pass configuration checks:
 318     echo
 319     for dir in $skipped_dirs
 320     do
 321         echo $dir
 322     done
 323     echo
 324     echo These components will not be built.
 325     echo
 326 fi
 327 if test "$with_dirs" != ""; then
 328     echo "*********************************************************************"
 329     echo The following components will be included from pre-installed
 330     echo libraries and includes:
 331     echo
 332     for dir in $with_dirs
 333     do
 334         echo $dir
 335     done
 336     echo
 337     echo These components will not be built.
 338     echo
 339 fi