git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 2, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET([])
  25 AM_INIT_AUTOMAKE(gnuradio,3.0svn)
  26 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  27
  28 dnl Remember if the user explicity set CXXFLAGS
  29 if test -n "${CXXFLAGS}"; then
  30   user_set_cxxflags=yes
  31 fi
  32
  33 GR_X86_64               dnl check for lib64 suffix
  34 LF_CONFIGURE_CC
  35 LF_CONFIGURE_CXX
  36
  37 dnl The three macros above are known to override CXXFLAGS if the user
  38 dnl didn't specify them.  Though I'm sure somebody thought this was
  39 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  40 dnl selected files.  Thus we "undo" the damage here...
  41 dnl
  42 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  43 dnl the output of swig use use -O1 if we're using g++.
  44 dnl See Makefile.common for the rest of the magic.
  45 if test "$user_set_cxxflags" != yes; then
  46   autoconf_default_CXXFLAGS="$CXXFLAGS"
  47   CXXFLAGS=""
  48   if test "$GXX" = yes; then
  49     swig_CXXFLAGS="-g1 -O1"
  50   fi
  51 fi
  52 AC_SUBST(autoconf_default_CXXFLAGS)
  53 AC_SUBST(swig_CXXFLAGS)
  54
  55
  56 LF_SET_WARNINGS
  57 GR_SET_GPROF
  58 GR_SET_PROF
  59 AM_PROG_AS
  60 AC_PROG_LN_S
  61 AC_PROG_MAKE_SET
  62 AC_PROG_INSTALL
  63 AC_PATH_PROG([RM_PROG], [rm])
  64
  65 AC_LIBTOOL_WIN32_DLL
  66 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  67 AC_ENABLE_SHARED        dnl do build shared libraries
  68 AC_DISABLE_STATIC       dnl don't build static libraries
  69 AC_PROG_LIBTOOL
  70 GR_FORTRAN
  71
  72 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  73 GR_SCRIPTING
  74
  75 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  76 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
  77
  78 dnl Checks for libraries.
  79 AC_CHECK_LIB(socket,socket)
  80
  81 dnl check for threads (mandatory)
  82 GR_OMNITHREAD
  83 #AC_SUBST(PTHREAD_CFLAGS)
  84 CFLAGS="${CFLAGS} $PTHREAD_CFLAGS"
  85 CXXFLAGS="${CXXFLAGS} $PTHREAD_CFLAGS"
  86
  87 if test "x$CXX_FOR_BUILD" = x
  88 then
  89   CXX_FOR_BUILD=${CXX}
  90 fi
  91 AC_SUBST(CXX_FOR_BUILD)
  92
  93 dnl Check for SysV shm (mandatory)
  94 dnl FIXME this is no longer mandatory.  Check the macro.
  95 GR_SYSV_SHM
  96
  97 dnl Checks for header files.
  98 AC_HEADER_STDC
  99 AC_HEADER_SYS_WAIT
 100 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 101 AC_CHECK_HEADERS(linux/ppdev.h sys/mman.h sys/select.h sys/types.h)
 102 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h)
 103
 104 dnl Checks for typedefs, structures, and compiler characteristics.
 105 AC_C_CONST
 106 AC_C_INLINE
 107 AC_TYPE_SIZE_T
 108 AC_HEADER_TIME
 109 AC_C_BIGENDIAN
 110 AC_STRUCT_TM
 111
 112 dnl Checks for library functions.
 113 AC_FUNC_ALLOCA
 114 AC_FUNC_SETVBUF_REVERSED
 115 AC_FUNC_VPRINTF
 116 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 117 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 118 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask])
 119
 120 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 121 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 122 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 123 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 124 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 125 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 126 #AC_FUNC_MKTIME
 127
 128 AH_BOTTOM([
 129 #ifndef HAVE_TRUNC
 130 #include <math.h>
 131 inline static double trunc(double x)
 132 {
 133   return x >= 0 ? floor(x) : ceil(x);
 134 }
 135 #endif
 136
 137 #ifndef HAVE_EXP10
 138 #include <math.h>
 139 inline static double exp10(double x)
 140 {
 141   return pow(10.0, x);
 142 }
 143 #endif
 144 ])
 145
 146 GR_CHECK_SHM_OPEN
 147 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 148 GR_CHECK_CREATEFILEMAPPING
 149
 150 dnl Check for Mingw support
 151 GR_PWIN32
 152
 153 dnl Do we have "dot", part of the graphviz package from AT&T?
 154 dnl Doxgen will use it to draw pretty diagrams ;-)
 155 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 156
 157 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 158 AC_SUBST(FFTW3F_LIBS)
 159
 160 dnl conditional build stuff
 161 GR_CHECK_DOXYGEN
 162 GR_SET_MD_CPU
 163
 164 dnl Define where to look for cppunit includes and libs
 165 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 166 AM_PATH_CPPUNIT([1.9.14],[],
 167                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])
 168
 169 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 170 AC_SUBST(CPPUNIT_INCLUDES)
 171
 172 dnl Define where to find boost includes
 173 dnl defines BOOST_CFLAGS
 174 GR_REQUIRE_BOOST_INCLUDES
 175
 176 DEFINES=""
 177 AC_SUBST(DEFINES)
 178
 179 dnl Component specific configuration
 180 dnl The order of the GR_ macros determines the order of compilation
 181 AC_ARG_ENABLE(
 182     [all-components],
 183     [  --enable-all-components Build all components or stop on failed dependencies]
 184 )
 185
 186 build_dirs="config"
 187 GRC_GNURADIO_CORE
 188 GRC_USRP
 189 GRC_GR_USRP                     dnl this must come after GRC_USRP
 190 GRC_GR_AUDIO_ALSA
 191 GRC_GR_AUDIO_JACK
 192 GRC_GR_AUDIO_OSS
 193 GRC_GR_AUDIO_OSX
 194 GRC_GR_AUDIO_PORTAUDIO
 195 GRC_GR_AUDIO_WINDOWS
 196 GRC_GR_ATSC
 197 GRC_GR_COMEDI
 198 GRC_GR_GSM_FR_VOCODER
 199 GRC_GR_PAGER
 200 GRC_GR_RADIO_ASTRONOMY
 201 GRC_GR_TRELLIS
 202 GRC_GR_VIDEO_SDL
 203 GRC_GR_WXGUI
 204 GRC_PMT
 205 GRC_MBLOCK                      dnl this must come after GRC_PMT
 206 GRC_EZDOP
 207 GRC_GR_EZDOP                    dnl this must come after GRC_EZDOP
 208 GRC_GR_RDF
 209 GRC_GNURADIO_EXAMPLES           dnl must come last
 210
 211 # Each component is now either to be built, was skipped, or failed dependencies
 212 AC_SUBST([build_dirs], [$build_dirs])
 213 AC_SUBST([skipped_dirs], [$skipped_dirs])
 214
 215 AC_CONFIG_FILES([\
 216     Makefile \
 217     run_tests.sh
 218     config/Makefile
 219 ])
 220
 221 dnl run_tests.sh is created from run_tests.in.sh.  Make it executable.
 222 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 223
 224 AC_OUTPUT
 225
 226 echo
 227 echo "*********************************************************************"
 228 echo The following GNU Radio components have been successfully configured:
 229 echo
 230 for dir in $build_dirs
 231 do
 232     echo $dir
 233 done
 234 echo
 235 echo You my now run the 'make' command to build these components.
 236 echo
 237 if test "$skipped_dirs" != ""; then
 238     echo "*********************************************************************"
 239     echo The following components were skipped either because you asked not
 240     echo to build them or they didn\'t pass configuration checks:
 241     echo
 242     for dir in $skipped_dirs
 243     do
 244         echo $dir
 245     done
 246     echo
 247     echo These components will not be built.
 248     echo
 249 fi