git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 2, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET([])
  25 AM_INIT_AUTOMAKE(gnuradio,3.0svn)
  26 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  27
  28 DEFINES=""
  29 AC_SUBST(DEFINES)
  30
  31 dnl Remember if the user explicity set CXXFLAGS
  32 if test -n "${CXXFLAGS}"; then
  33   user_set_cxxflags=yes
  34 fi
  35
  36 GR_X86_64               dnl check for lib64 suffix
  37 LF_CONFIGURE_CC
  38 LF_CONFIGURE_CXX
  39
  40 dnl The three macros above are known to override CXXFLAGS if the user
  41 dnl didn't specify them.  Though I'm sure somebody thought this was
  42 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  43 dnl selected files.  Thus we "undo" the damage here...
  44 dnl
  45 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  46 dnl the output of swig use use -O1 if we're using g++.
  47 dnl See Makefile.common for the rest of the magic.
  48 if test "$user_set_cxxflags" != yes; then
  49   autoconf_default_CXXFLAGS="$CXXFLAGS"
  50   CXXFLAGS=""
  51   if test "$GXX" = yes; then
  52     swig_CXXFLAGS="-g1 -O1"
  53   fi
  54 fi
  55 AC_SUBST(autoconf_default_CXXFLAGS)
  56 AC_SUBST(swig_CXXFLAGS)
  57
  58
  59 LF_SET_WARNINGS
  60 GR_SET_GPROF
  61 GR_SET_PROF
  62 AM_PROG_AS
  63 AC_PROG_LN_S
  64 AC_PROG_MAKE_SET
  65 AC_PROG_INSTALL
  66 AC_PATH_PROG([RM_PROG], [rm])
  67
  68 AC_LIBTOOL_WIN32_DLL
  69 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  70 AC_ENABLE_SHARED        dnl do build shared libraries
  71 AC_DISABLE_STATIC       dnl don't build static libraries
  72 AC_PROG_LIBTOOL
  73 GR_FORTRAN
  74
  75 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  76 GR_SCRIPTING
  77
  78 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  79 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
  80
  81 dnl Checks for libraries.
  82 AC_CHECK_LIB(socket,socket)
  83
  84 dnl check for threads (mandatory)
  85 GR_OMNITHREAD
  86 #AC_SUBST(PTHREAD_CFLAGS)
  87 CFLAGS="${CFLAGS} $PTHREAD_CFLAGS"
  88 CXXFLAGS="${CXXFLAGS} $PTHREAD_CFLAGS"
  89
  90 if test "x$CXX_FOR_BUILD" = x
  91 then
  92   CXX_FOR_BUILD=${CXX}
  93 fi
  94 AC_SUBST(CXX_FOR_BUILD)
  95
  96 dnl Check for SysV shm (mandatory)
  97 dnl FIXME this is no longer mandatory.  Check the macro.
  98 GR_SYSV_SHM
  99
 100 dnl Checks for header files.
 101 AC_HEADER_STDC
 102 AC_HEADER_SYS_WAIT
 103 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 104 AC_CHECK_HEADERS(linux/ppdev.h sys/mman.h sys/select.h sys/types.h)
 105 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h)
 106
 107 dnl Checks for typedefs, structures, and compiler characteristics.
 108 AC_C_CONST
 109 AC_C_INLINE
 110 AC_TYPE_SIZE_T
 111 AC_HEADER_TIME
 112 AC_C_BIGENDIAN
 113 AC_STRUCT_TM
 114
 115 dnl Checks for library functions.
 116 AC_FUNC_ALLOCA
 117 AC_FUNC_SETVBUF_REVERSED
 118 AC_FUNC_VPRINTF
 119 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 120 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 121 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask])
 122
 123 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 124 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 125 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 126 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 127 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 128 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 129 #AC_FUNC_MKTIME
 130
 131 AH_BOTTOM([
 132 #ifndef HAVE_TRUNC
 133 #include <math.h>
 134 inline static double trunc(double x)
 135 {
 136   return x >= 0 ? floor(x) : ceil(x);
 137 }
 138 #endif
 139
 140 #ifndef HAVE_EXP10
 141 #include <math.h>
 142 inline static double exp10(double x)
 143 {
 144   return pow(10.0, x);
 145 }
 146 #endif
 147 ])
 148
 149 GR_CHECK_SHM_OPEN
 150 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 151 GR_CHECK_CREATEFILEMAPPING
 152
 153 dnl Check for Mingw support
 154 GR_PWIN32
 155
 156 dnl Do we have "dot", part of the graphviz package from AT&T?
 157 dnl Doxgen will use it to draw pretty diagrams ;-)
 158 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 159
 160 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 161 AC_SUBST(FFTW3F_LIBS)
 162
 163 dnl conditional build stuff
 164 GR_CHECK_DOXYGEN
 165 GR_SET_MD_CPU
 166
 167 dnl Define where to look for cppunit includes and libs
 168 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 169 AM_PATH_CPPUNIT([1.9.14],[],
 170                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])
 171
 172 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 173 AC_SUBST(CPPUNIT_INCLUDES)
 174
 175 dnl Define where to find boost includes
 176 dnl defines BOOST_CFLAGS
 177 GR_REQUIRE_BOOST_INCLUDES
 178
 179 dnl Component specific configuration
 180 dnl The order of the GR_ macros determines the order of compilation
 181 AC_ARG_ENABLE(
 182     [all-components],
 183     [  --enable-all-components Build all components or stop on failed dependencies]
 184 )
 185
 186 build_dirs="config"
 187 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 188 GRC_GNURADIO_CORE
 189 GRC_USRP
 190 GRC_GR_USRP                     dnl this must come after GRC_USRP
 191 GRC_GR_AUDIO_ALSA
 192 GRC_GR_AUDIO_JACK
 193 GRC_GR_AUDIO_OSS
 194 GRC_GR_AUDIO_OSX
 195 GRC_GR_AUDIO_PORTAUDIO
 196 GRC_GR_AUDIO_WINDOWS
 197 GRC_GR_ATSC
 198 GRC_GR_COMEDI
 199 GRC_GR_GSM_FR_VOCODER
 200 GRC_GR_PAGER
 201 GRC_GR_RADIO_ASTRONOMY
 202 GRC_GR_TRELLIS
 203 GRC_GR_VIDEO_SDL
 204 #GRC_GR_QTGUI                   dnl disabled until grc_gr_qtgui.m4 is final
 205 GRC_GR_WXGUI
 206 GRC_PMT
 207 GRC_MBLOCK                      dnl this must come after GRC_PMT
 208 GRC_EZDOP
 209 GRC_GR_EZDOP                    dnl this must come after GRC_EZDOP
 210 GRC_GR_RDF
 211 GRC_GNURADIO_EXAMPLES           dnl must come last
 212
 213 # Each component is now either to be built, was skipped, or failed dependencies
 214 AC_SUBST([build_dirs], [$build_dirs])
 215 AC_SUBST([skipped_dirs], [$skipped_dirs])
 216
 217 AC_CONFIG_FILES([\
 218     Makefile \
 219     run_tests.sh
 220     config/Makefile
 221 ])
 222
 223 dnl run_tests.sh is created from run_tests.in.sh.  Make it executable.
 224 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 225
 226 AC_OUTPUT
 227
 228 echo
 229 echo "*********************************************************************"
 230 echo The following GNU Radio components have been successfully configured:
 231 echo
 232 for dir in $build_dirs
 233 do
 234     echo $dir
 235 done
 236 echo
 237 echo You my now run the 'make' command to build these components.
 238 echo
 239 if test "$skipped_dirs" != ""; then
 240     echo "*********************************************************************"
 241     echo The following components were skipped either because you asked not
 242     echo to build them or they didn\'t pass configuration checks:
 243     echo
 244     for dir in $skipped_dirs
 245     do
 246         echo $dir
 247     done
 248     echo
 249     echo These components will not be built.
 250     echo
 251 fi