git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.2svn)
  30
  31 DEFINES=""
  32 AC_SUBST(DEFINES)
  33
  34 dnl Remember if the user explicity set CXXFLAGS
  35 if test -n "${CXXFLAGS}"; then
  36   user_set_cxxflags=yes
  37 fi
  38
  39 LF_CONFIGURE_CC
  40 LF_CONFIGURE_CXX
  41 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  42
  43 dnl The three macros above are known to override CXXFLAGS if the user
  44 dnl didn't specify them.  Though I'm sure somebody thought this was
  45 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  46 dnl selected files.  Thus we "undo" the damage here...
  47 dnl
  48 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  49 dnl the output of swig use use -O1 if we're using g++.
  50 dnl See Makefile.common for the rest of the magic.
  51 if test "$user_set_cxxflags" != yes; then
  52   autoconf_default_CXXFLAGS="$CXXFLAGS"
  53   if test "$GXX" = yes; then
  54     case "$host_cpu" in
  55         powerpc*)
  56            dnl "-O1" is broken on the PPC for some reason
  57            dnl (at least as of g++ 4.1.1)
  58            swig_CXXFLAGS="-g1 -O2 -Wno-strict-aliasing -Wno-parentheses"
  59         ;;
  60         *)
  61         swig_CXXFLAGS="-g -O1 -Wno-strict-aliasing -Wno-parentheses"
  62         ;;
  63     esac
  64   fi
  65 fi
  66 AC_SUBST(autoconf_default_CXXFLAGS)
  67 AC_SUBST(swig_CXXFLAGS)
  68
  69
  70 dnl add ${prefix}/lib${gr_libdir_suffix}/pkgconfig to the head of the PKG_CONFIG_PATH
  71 if test x${PKG_CONFIG_PATH} = x; then
  72     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig
  73 else
  74     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig:${PKG_CONFIG_PATH}
  75 fi
  76 export PKG_CONFIG_PATH
  77
  78
  79 GR_SET_GPROF
  80 GR_SET_PROF
  81 AM_PROG_AS
  82 AC_PROG_LN_S
  83 AC_PROG_MAKE_SET
  84 AC_PROG_INSTALL
  85 AC_PATH_PROG([RM_PROG], [rm])
  86
  87 AC_LIBTOOL_WIN32_DLL
  88 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  89 AC_ENABLE_SHARED        dnl do build shared libraries
  90 AC_DISABLE_STATIC       dnl don't build static libraries
  91 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
  92 GR_FORTRAN
  93
  94 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
  95 GR_SCRIPTING
  96
  97 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
  98 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
  99
 100 dnl Checks for libraries.
 101 AC_CHECK_LIB(socket,socket)
 102
 103 dnl check for omnithreads (will soon be removed)
 104 GR_OMNITHREAD
 105 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 106 CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
 107
 108 dnl Set the c++ compiler that we use for the build system when cross compiling
 109 if test x$CXX_FOR_BUILD = x
 110 then
 111   if test x$cross_compiling = xno; then
 112     CXX_FOR_BUILD=${CXX}
 113   else
 114     CXX_FOR_BUILD=g++
 115   fi
 116 fi
 117 AC_SUBST(CXX_FOR_BUILD)
 118
 119 dnl Check for SysV shm (mandatory)
 120 dnl FIXME this is no longer mandatory.  Check the macro.
 121 GR_SYSV_SHM
 122
 123 dnl Checks for header files.
 124 AC_HEADER_STDC
 125 AC_HEADER_SYS_WAIT
 126 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 127 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 128 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h malloc.h)
 129 AC_CHECK_HEADERS(netinet/in.h)
 130 AC_CHECK_HEADERS(windows.h)
 131 AC_CHECK_HEADERS(vec_types.h)
 132
 133 dnl Checks for typedefs, structures, and compiler characteristics.
 134 AC_C_CONST
 135 AC_C_INLINE
 136 AC_TYPE_SIZE_T
 137 AC_HEADER_TIME
 138 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 139 AC_SUBST(GR_ARCH_BIGENDIAN)
 140 AC_STRUCT_TM
 141
 142 dnl Checks for library functions.
 143 AC_FUNC_ALLOCA
 144 GR_CHECK_MEMALIGN
 145 AC_FUNC_SETVBUF_REVERSED
 146 AC_FUNC_VPRINTF
 147 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 148 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 149 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 150 AC_CHECK_FUNCS([sched_setaffinity])
 151
 152 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 153 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 154 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 155 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 156 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 157 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 158 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 159 #AC_FUNC_MKTIME
 160
 161 AH_BOTTOM([
 162 #ifndef HAVE_TRUNC
 163 #include <math.h>
 164 inline static double trunc(double x)
 165 {
 166   return x >= 0 ? floor(x) : ceil(x);
 167 }
 168 #endif
 169
 170 #ifndef HAVE_EXP10
 171 #include <math.h>
 172 inline static double exp10(double x)
 173 {
 174   return pow(10.0, x);
 175 }
 176 #endif
 177
 178 #ifdef HAVE_WINDOWS_H
 179 #define NOMINMAX
 180 #endif
 181 ])
 182
 183 GR_CHECK_SHM_OPEN
 184 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 185 GR_CHECK_CREATEFILEMAPPING
 186
 187 dnl Check for Mingw support
 188 GR_PWIN32
 189
 190 dnl Do we have "dot", part of the graphviz package from AT&T?
 191 dnl Doxgen will use it to draw pretty diagrams ;-)
 192 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 193
 194 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 195 AC_SUBST(FFTW3F_LIBS)
 196
 197 dnl conditional build stuff
 198 GR_CHECK_DOXYGEN
 199 GR_SET_MD_CPU
 200
 201 dnl Define where to look for cppunit includes and libs
 202 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 203 dnl Try using pkg-config first, then fall back to cppunit-config.
 204 PKG_CHECK_EXISTS(cppunit,
 205   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 206   [AM_PATH_CPPUNIT([1.9.14],[],
 207                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 208
 209 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 210 AC_SUBST(CPPUNIT_INCLUDES)
 211
 212 dnl see if GUILE is installed
 213 AC_PATH_PROG(GUILE,guile)
 214
 215 dnl
 216 dnl We require the boost headers, thread lib and date_time lib.
 217 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 218 dnl
 219 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 220 AX_BOOST_BASE([1.35])
 221
 222 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 223 AX_BOOST_THREAD
 224 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 225 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 226
 227 dnl
 228 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 229 dnl
 230 AX_BOOST_DATE_TIME
 231 dnl AX_BOOST_FILESYSTEM
 232 dnl AX_BOOST_IOSTREAMS
 233 AX_BOOST_PROGRAM_OPTIONS
 234 dnl AX_BOOST_REGEX
 235 dnl AX_BOOST_SERIALIZATION
 236 dnl AX_BOOST_SIGNALS
 237 dnl AX_BOOST_SYSTEM
 238 dnl AX_BOOST_TEST_EXEC_MONITOR
 239 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 240 dnl AX_BOOST_WSERIALIZATION
 241
 242
 243 dnl If this is being done from a subversion tree, create variables
 244 GR_SUBVERSION
 245
 246 dnl Component specific configuration
 247 dnl The order of the GR_ macros determines the order of compilation
 248 dnl For -any- checks on $enable_all_components
 249 dnl use the following guidelines:
 250 dnl   yes : --enable-all-components was specified, so error out if any
 251 dnl         components do not pass configuration checks.
 252 dnl   no  : --disable-all-components was specified, so try to build the
 253 dnl         --enable'd components, and error out if any do not pass
 254 dnl         configuration checks.
 255 dnl   ""  : this option was not specified on the command line; try to
 256 dnl         build all components that are not --with'd, but don't
 257 dnl         error out if any component does not pass configuration checks.
 258 dnl
 259 dnl For each --enable-foo component, if that flag is not specified on
 260 dnl the command line, the related variable $enable_foo will be set to
 261 dnl $enable_all_components .
 262
 263 AC_ARG_ENABLE(
 264     [all-components],
 265     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 266 )
 267
 268 build_dirs="config"
 269 GRC_GRUEL                       dnl must come first
 270 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 271 GRC_GCELL
 272 GRC_GNURADIO_CORE
 273 GRC_PMT
 274 GRC_MBLOCK                      dnl this must come after GRC_PMT
 275 GRC_USRP
 276 GRC_USRP2
 277 GRC_GR_USRP                     dnl this must come after GRC_USRP
 278 GRC_GR_USRP2
 279 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 280 GRC_GR_MSDD6000
 281 GRC_GR_AUDIO_ALSA
 282 GRC_GR_AUDIO_JACK
 283 GRC_GR_AUDIO_OSS
 284 GRC_GR_AUDIO_OSX
 285 GRC_GR_AUDIO_PORTAUDIO
 286 GRC_GR_AUDIO_WINDOWS
 287 GRC_GR_ATSC
 288 GRC_GR_COMEDI
 289 GRC_GR_CVSD_VOCODER
 290 GRC_GR_GPIO
 291 GRC_GR_GSM_FR_VOCODER
 292 GRC_GR_PAGER
 293 GRC_GR_RADAR_MONO
 294 GRC_GR_RADIO_ASTRONOMY
 295 GRC_GR_TRELLIS
 296 GRC_GR_VIDEO_SDL
 297 GRC_GR_WXGUI
 298 GRC_GR_QTGUI
 299 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 300 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 301 GRC_GNURADIO_EXAMPLES           dnl must come after all GRC_GR_*
 302 GRC_GRC
 303
 304 # Each component is now either to be built, was skipped, will be
 305 # included from pre-installed libraries and includes, or failed
 306 # dependencies.
 307 AC_SUBST([build_dirs], [$build_dirs])
 308 AC_SUBST([skipped_dirs], [$skipped_dirs])
 309 AC_SUBST([with_dirs], [$with_dirs])
 310
 311 # fix for older autotools that don't define "abs_top_YYY" by default
 312 AC_SUBST(abs_top_srcdir)
 313 AC_SUBST(abs_top_builddir)
 314
 315 # 'with' variables - the pre-installed libraries, includes, and paths
 316 # - must always come last in the lists, so they require special
 317 # treatment.
 318 AC_SUBST(with_INCLUDES)
 319 AC_SUBST(with_SWIG_INCLUDES)
 320 AC_SUBST(with_PYDIRPATH)
 321 AC_SUBST(with_SWIGDIRPATH)
 322 AC_SUBST(with_LIBDIRPATH)
 323
 324 # Local files tweaked by AC
 325 AC_CONFIG_FILES([\
 326     Makefile \
 327     run_tests.sh \
 328     config/Makefile \
 329 ])
 330
 331 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 332 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 333
 334 dnl Enable warnings as the last thing before generating output, since
 335 dnl this may add -Werror to CFLAGS which can cause various configure
 336 dnl checks to fail.
 337 LF_SET_WARNINGS
 338
 339 AC_OUTPUT
 340
 341 echo
 342 echo "*********************************************************************"
 343 echo The following GNU Radio components have been successfully configured:
 344 echo
 345 for dir in $build_dirs
 346 do
 347     echo $dir
 348 done
 349 echo
 350 echo You my now run the 'make' command to build these components.
 351 echo
 352 if test "$skipped_dirs" != ""; then
 353     echo "*********************************************************************"
 354     echo The following components were skipped either because you asked not
 355     echo to build them or they didn\'t pass configuration checks:
 356     echo
 357     for dir in $skipped_dirs
 358     do
 359         echo $dir
 360     done
 361     echo
 362     echo These components will not be built.
 363     echo
 364 fi
 365 if test "$with_dirs" != ""; then
 366     echo "*********************************************************************"
 367     echo The following components will be included from pre-installed
 368     echo libraries and includes:
 369     echo
 370     for dir in $with_dirs
 371     do
 372         echo $dir
 373     done
 374     echo
 375     echo These components will not be built.
 376     echo
 377 fi