git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.1svn)
  30
  31 DEFINES=""
  32 AC_SUBST(DEFINES)
  33
  34 dnl Remember if the user explicity set CXXFLAGS
  35 if test -n "${CXXFLAGS}"; then
  36   user_set_cxxflags=yes
  37 fi
  38
  39 LF_CONFIGURE_CC
  40 LF_CONFIGURE_CXX
  41 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  42
  43 cxx_warnings_as_errors=""
  44 AC_ARG_ENABLE(
  45     [warnings-as-errors],
  46     [--enable-warnings-as-errors Treat compiler warnings as errors],
  47     [cxx_warnings_as_errors="-Werror"]
  48 )
  49
  50 dnl The three macros above are known to override CXXFLAGS if the user
  51 dnl didn't specify them.  Though I'm sure somebody thought this was
  52 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  53 dnl selected files.  Thus we "undo" the damage here...
  54 dnl
  55 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  56 dnl the output of swig use use -O1 if we're using g++.
  57 dnl See Makefile.common for the rest of the magic.
  58 if test "$user_set_cxxflags" != yes; then
  59   autoconf_default_CXXFLAGS="$CXXFLAGS"
  60   CXXFLAGS=$cxx_warnings_as_errors
  61   if test "$GXX" = yes; then
  62     case "$host_cpu" in
  63         powerpc*)
  64            dnl "-O1" is broken on the PPC for some reason
  65            dnl (at least as of g++ 4.1.1)
  66            swig_CXXFLAGS="-g1 -O2 -fno-strict-aliasing"
  67         ;;
  68         *)
  69         swig_CXXFLAGS="-g -O1 -fno-strict-aliasing"
  70         ;;
  71     esac
  72   fi
  73 fi
  74 AC_SUBST(autoconf_default_CXXFLAGS)
  75 AC_SUBST(swig_CXXFLAGS)
  76
  77
  78 dnl add ${prefix}/lib${gr_libdir_suffix}/pkgconfig to the head of the PKG_CONFIG_PATH
  79 if test x${PKG_CONFIG_PATH} = x; then
  80     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig
  81 else
  82     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig:${PKG_CONFIG_PATH}
  83 fi
  84 export PKG_CONFIG_PATH
  85
  86
  87 LF_SET_WARNINGS
  88 GR_SET_GPROF
  89 GR_SET_PROF
  90 AM_PROG_AS
  91 AC_PROG_LN_S
  92 AC_PROG_MAKE_SET
  93 AC_PROG_INSTALL
  94 AC_PATH_PROG([RM_PROG], [rm])
  95
  96 AC_LIBTOOL_WIN32_DLL
  97 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
  98 AC_ENABLE_SHARED        dnl do build shared libraries
  99 AC_DISABLE_STATIC       dnl don't build static libraries
 100 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
 101 GR_FORTRAN
 102
 103 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
 104 GR_SCRIPTING
 105
 106 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
 107 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
 108
 109 dnl Checks for libraries.
 110 AC_CHECK_LIB(socket,socket)
 111
 112 dnl check for omnithreads (will soon be removed)
 113 GR_OMNITHREAD
 114 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 115 CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
 116
 117 dnl Set the c++ compiler that we use for the build system when cross compiling
 118 if test x$CXX_FOR_BUILD = x
 119 then
 120   if test x$cross_compiling = xno; then
 121     CXX_FOR_BUILD=${CXX}
 122   else
 123     CXX_FOR_BUILD=g++
 124   fi
 125 fi
 126 AC_SUBST(CXX_FOR_BUILD)
 127
 128 dnl Check for SysV shm (mandatory)
 129 dnl FIXME this is no longer mandatory.  Check the macro.
 130 GR_SYSV_SHM
 131
 132 dnl Checks for header files.
 133 AC_HEADER_STDC
 134 AC_HEADER_SYS_WAIT
 135 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 136 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 137 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h)
 138 AC_CHECK_HEADERS(netinet/in.h)
 139 AC_CHECK_HEADERS(windows.h)
 140
 141 dnl Checks for typedefs, structures, and compiler characteristics.
 142 AC_C_CONST
 143 AC_C_INLINE
 144 AC_TYPE_SIZE_T
 145 AC_HEADER_TIME
 146 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 147 AC_SUBST(GR_ARCH_BIGENDIAN)
 148 AC_STRUCT_TM
 149
 150 dnl Checks for library functions.
 151 AC_FUNC_ALLOCA
 152 AC_FUNC_SETVBUF_REVERSED
 153 AC_FUNC_VPRINTF
 154 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 155 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 156 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 157 AC_CHECK_FUNCS([sched_setaffinity])
 158
 159 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 160 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 161 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 162 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 163 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 164 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 165 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 166 #AC_FUNC_MKTIME
 167
 168 AH_BOTTOM([
 169 #ifndef HAVE_TRUNC
 170 #include <math.h>
 171 inline static double trunc(double x)
 172 {
 173   return x >= 0 ? floor(x) : ceil(x);
 174 }
 175 #endif
 176
 177 #ifndef HAVE_EXP10
 178 #include <math.h>
 179 inline static double exp10(double x)
 180 {
 181   return pow(10.0, x);
 182 }
 183 #endif
 184
 185 #ifdef HAVE_WINDOWS_H
 186 #define NOMINMAX
 187 #endif
 188 ])
 189
 190 GR_CHECK_SHM_OPEN
 191 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 192 GR_CHECK_CREATEFILEMAPPING
 193
 194 dnl Check for Mingw support
 195 GR_PWIN32
 196
 197 dnl Do we have "dot", part of the graphviz package from AT&T?
 198 dnl Doxgen will use it to draw pretty diagrams ;-)
 199 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 200
 201 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 202 AC_SUBST(FFTW3F_LIBS)
 203
 204 dnl conditional build stuff
 205 GR_CHECK_DOXYGEN
 206 GR_SET_MD_CPU
 207
 208 dnl Define where to look for cppunit includes and libs
 209 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 210 dnl Try using pkg-config first, then fall back to cppunit-config.
 211 PKG_CHECK_EXISTS(cppunit,
 212   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 213   [AM_PATH_CPPUNIT([1.9.14],[],
 214                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 215
 216 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 217 AC_SUBST(CPPUNIT_INCLUDES)
 218
 219 dnl see if GUILE is installed
 220 AC_PATH_PROG(GUILE,guile)
 221
 222 dnl
 223 dnl We require the boost headers, thread lib and date_time lib.
 224 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 225 dnl
 226 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 227 AX_BOOST_BASE([1.35])
 228
 229 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 230 AX_BOOST_THREAD
 231 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 232 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 233
 234 dnl
 235 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 236 dnl
 237 AX_BOOST_DATE_TIME
 238 dnl AX_BOOST_FILESYSTEM
 239 dnl AX_BOOST_IOSTREAMS
 240 dnl AX_BOOST_PROGRAM_OPTIONS
 241 dnl AX_BOOST_REGEX
 242 dnl AX_BOOST_SERIALIZATION
 243 dnl AX_BOOST_SIGNALS
 244 dnl AX_BOOST_SYSTEM
 245 dnl AX_BOOST_TEST_EXEC_MONITOR
 246 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 247 dnl AX_BOOST_WSERIALIZATION
 248
 249
 250 dnl If this is being done from a subversion tree, create variables
 251 GR_SUBVERSION
 252
 253 dnl Component specific configuration
 254 dnl The order of the GR_ macros determines the order of compilation
 255 dnl For -any- checks on $enable_all_components
 256 dnl use the following guidelines:
 257 dnl   yes : --enable-all-components was specified, so error out if any
 258 dnl         components do not pass configuration checks.
 259 dnl   no  : --disable-all-components was specified, so try to build the
 260 dnl         --enable'd components, and error out if any do not pass
 261 dnl         configuration checks.
 262 dnl   ""  : this option was not specified on the command line; try to
 263 dnl         build all components that are not --with'd, but don't
 264 dnl         error out if any component does not pass configuration checks.
 265 dnl
 266 dnl For each --enable-foo component, if that flag is not specified on
 267 dnl the command line, the related variable $enable_foo will be set to
 268 dnl $enable_all_components .
 269
 270 AC_ARG_ENABLE(
 271     [all-components],
 272     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 273 )
 274
 275 build_dirs="config"
 276 GRC_GRUEL                       dnl must come first
 277 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 278 GRC_GCELL
 279 GRC_GNURADIO_CORE
 280 GRC_PMT
 281 GRC_MBLOCK                      dnl this must come after GRC_PMT
 282 GRC_USRP
 283 GRC_GR_USRP                     dnl this must come after GRC_USRP
 284 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 285 GRC_GR_MSDD6000
 286 GRC_GR_AUDIO_ALSA
 287 GRC_GR_AUDIO_JACK
 288 GRC_GR_AUDIO_OSS
 289 GRC_GR_AUDIO_OSX
 290 GRC_GR_AUDIO_PORTAUDIO
 291 GRC_GR_AUDIO_WINDOWS
 292 GRC_GR_ATSC
 293 GRC_GR_COMEDI
 294 GRC_GR_CVSD_VOCODER
 295 GRC_GR_GPIO
 296 GRC_GR_GSM_FR_VOCODER
 297 GRC_GR_PAGER
 298 GRC_GR_RADAR_MONO
 299 GRC_GR_RADIO_ASTRONOMY
 300 GRC_GR_TRELLIS
 301 GRC_GR_VIDEO_SDL
 302 GRC_GR_WXGUI
 303 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 304 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 305 GRC_GNURADIO_EXAMPLES           dnl must come after all GRC_GR_*
 306 GRC_GRC
 307
 308 # Each component is now either to be built, was skipped, will be
 309 # included from pre-installed libraries and includes, or failed
 310 # dependencies.
 311 AC_SUBST([build_dirs], [$build_dirs])
 312 AC_SUBST([skipped_dirs], [$skipped_dirs])
 313 AC_SUBST([with_dirs], [$with_dirs])
 314
 315 # fix for older autotools that don't define "abs_top_YYY" by default
 316 AC_SUBST(abs_top_srcdir)
 317 AC_SUBST(abs_top_builddir)
 318
 319 # 'with' variables - the pre-installed libraries, includes, and paths
 320 # - must always come last in the lists, so they require special
 321 # treatment.
 322 AC_SUBST(with_INCLUDES)
 323 AC_SUBST(with_SWIG_INCLUDES)
 324 AC_SUBST(with_PYDIRPATH)
 325 AC_SUBST(with_SWIGDIRPATH)
 326 AC_SUBST(with_LIBDIRPATH)
 327
 328 # Local files tweaked by AC
 329 AC_CONFIG_FILES([\
 330     Makefile \
 331     run_tests.sh \
 332     config/Makefile \
 333 ])
 334
 335 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 336 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 337
 338 AC_OUTPUT
 339
 340 echo
 341 echo "*********************************************************************"
 342 echo The following GNU Radio components have been successfully configured:
 343 echo
 344 for dir in $build_dirs
 345 do
 346     echo $dir
 347 done
 348 echo
 349 echo You my now run the 'make' command to build these components.
 350 echo
 351 if test "$skipped_dirs" != ""; then
 352     echo "*********************************************************************"
 353     echo The following components were skipped either because you asked not
 354     echo to build them or they didn\'t pass configuration checks:
 355     echo
 356     for dir in $skipped_dirs
 357     do
 358         echo $dir
 359     done
 360     echo
 361     echo These components will not be built.
 362     echo
 363 fi
 364 if test "$with_dirs" != ""; then
 365     echo "*********************************************************************"
 366     echo The following components will be included from pre-installed
 367     echo libraries and includes:
 368     echo
 369     for dir in $with_dirs
 370     do
 371         echo $dir
 372     done
 373     echo
 374     echo These components will not be built.
 375     echo
 376 fi