git.gag.com Git - debian/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright 1991, 1994-2010, 2013 Free Software Foundation, Inc.
   4
   5 # This file is part of GNU tar.
   6
   7 # GNU tar is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # GNU tar is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_INIT([GNU tar], [1.27.90], [bug-tar@gnu.org])
  21 AC_CONFIG_SRCDIR([src/tar.c])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_PREREQ([2.63])
  25 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz std-options silent-rules])
  26
  27 # Enable silent rules by default:
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC_STDC
  31 AC_EXEEXT
  32 AC_PROG_RANLIB
  33 AC_PROG_YACC
  34 gl_EARLY
  35
  36 AC_SYS_LARGEFILE
  37 AC_C_INLINE
  38
  39 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  40   sgtty.h string.h \
  41   sys/param.h sys/device.h sys/gentape.h \
  42   sys/inet.h sys/io/trioctl.h \
  43   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  44   unistd.h locale.h)
  45
  46 AC_CHECK_HEADERS([sys/buf.h], [], [],
  47 [#if HAVE_SYS_PARAM_H
  48 #include <sys/param.h>
  49 #endif])
  50
  51 AC_HEADER_MAJOR
  52
  53 AC_MSG_CHECKING([for st_fstype string in struct stat])
  54 AC_CACHE_VAL(diff_cv_st_fstype_string,
  55   [AC_TRY_COMPILE([#include <sys/types.h>
  56 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  57    diff_cv_st_fstype_string=yes,
  58    diff_cv_st_fstype_string=no)])
  59 AC_MSG_RESULT($diff_cv_st_fstype_string)
  60 if test $diff_cv_st_fstype_string = yes; then
  61   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  62     [Define if struct stat has a char st_fstype[] member.])
  63 fi
  64
  65 # even if we use gnulib's acl.h with integrated m4 file later on (used because
  66 # of very useful file_has_acl() function) we need following checks that restrict
  67 # tar to use POSIX.1e ACLs only.
  68 AC_ARG_WITH([posix-acls],
  69     AS_HELP_STRING([--without-posix-acls],
  70                    [do not use POSIX.1e access control lists]),
  71     [],
  72     [with_posix_acls=yes])
  73 if test "x$with_posix_acls" != "xno"; then
  74   AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acls=no])
  75   for tar_acl_func in acl_get_file acl_get_fd acl_set_file acl_set_fd \
  76                       acl_to_text acl_from_text; do \
  77     test "x$with_posix_acls" = xno && break
  78     AC_SEARCH_LIBS([$tar_acl_func], [acl pacl], [], [with_posix_acls=no])
  79   done
  80   if test "x$with_posix_acls" != xno; then
  81     AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
  82   fi
  83 else
  84   # disable acls in gnulib's checks
  85   export enable_acl=no
  86 fi
  87
  88 AC_TYPE_MODE_T
  89 AC_TYPE_PID_T
  90 AC_TYPE_OFF_T
  91 AC_TYPE_UID_T
  92 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  93                                    [Type of major device numbers.]))
  94 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  95                                    [Type of minor device numbers.]))
  96 AC_CHECK_TYPE(dev_t, unsigned)
  97 AC_CHECK_TYPE(ino_t, unsigned)
  98
  99 gt_TYPE_SSIZE_T
 100
 101 # gnulib modules
 102 gl_INIT
 103 # paxutils modules
 104 tar_PAXUTILS
 105
 106 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 107 # ------------------------------------------------
 108 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 109 # Otherwise, run RUN-IF-NOT-FOUND.
 110 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 111   [AC_PREPROC_IFELSE(
 112     [AC_LANG_PROGRAM(
 113       [[
 114 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 115 /* ok */
 116 #else
 117 # error "your version of gcc is older than $1.$2"
 118 #endif
 119       ]]),
 120     ], [$3], [$4])
 121   ]
 122 )
 123
 124 AC_ARG_ENABLE([gcc-warnings],
 125   [AS_HELP_STRING([--enable-gcc-warnings],
 126      [turn on many GCC warnings (for developers; best with GNU make)])],
 127   [case $enableval in
 128      yes|no) ;;
 129      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 130    esac
 131    gl_gcc_warnings=$enableval],
 132   [gl_gcc_warnings=no
 133    if test -d "$srcdir"/.git; then
 134      gl_GCC_VERSION_IFELSE([4], [6], [gl_gcc_warnings=yes])
 135    fi]
 136 )
 137
 138 if test "$gl_gcc_warnings" = yes; then
 139   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 140   AC_SUBST([WERROR_CFLAGS])
 141
 142   nw=
 143   # This, $nw, is the list of warnings we disable.
 144   nw="$nw -Wformat-nonliteral"      # warnings in Fedora 17 stdio.h
 145   nw="$nw -Wvla"                    # warnings in gettext.h
 146   nw="$nw -Wswitch-default"         # Too many warnings for now
 147   nw="$nw -Wunsafe-loop-optimizations" # It's OK to omit unsafe optimizations.
 148   nw="$nw -Winline"                 # It's OK to not inline.
 149   nw="$nw -Wstrict-overflow"        # It's OK to optimize strictly.
 150   nw="$nw -Wsuggest-attribute=pure" # Too many warnings for now.
 151
 152   gl_MANYWARN_ALL_GCC([ws])
 153   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 154   for w in $ws; do
 155     gl_WARN_ADD([$w])
 156   done
 157   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 158   gl_WARN_ADD([-Wno-type-limits])      # It's OK to optimize based on types.
 159   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 160   gl_WARN_ADD([-Wno-format-nonliteral])
 161
 162   gl_WARN_ADD([-fdiagnostics-show-option])
 163   gl_WARN_ADD([-funit-at-a-time])
 164
 165   AC_SUBST([WARN_CFLAGS])
 166
 167   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 168   AH_VERBATIM([FORTIFY_SOURCE],
 169   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 170       without upsetting glibc 2.15+. */
 171    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 172    # define _FORTIFY_SOURCE 2
 173    #endif
 174   ])
 175   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 176
 177   # Use a slightly smaller set of warning options for lib/.
 178   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 179   nw=
 180   nw="$nw -Wmissing-prototypes"
 181   nw="$nw -Wunused-macros"
 182   #
 183   # These are for argp.
 184   nw="$nw -Wmissing-field-initializers"
 185   nw="$nw -Wshadow"
 186   #
 187   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 188
 189   # This is also for argp.
 190   gl_WARN_ADD([-Wno-missing-field-initializers], [GNULIB_WARN_CFLAGS])
 191
 192   AC_SUBST([GNULIB_WARN_CFLAGS])
 193
 194   # For gnulib-tests, the set is slightly smaller still.
 195   nw=
 196   # It's not worth being this picky about test programs.
 197   nw="$nw -Wsuggest-attribute=const"
 198   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 199                          [$GNULIB_WARN_CFLAGS], [$nw])
 200   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 201 fi
 202
 203 TAR_HEADERS_ATTR_XATTR_H
 204
 205 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
 206
 207 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 208 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 209 AC_CHECK_DECLS([time],,, [#include <time.h>])
 210
 211 AC_REPLACE_FUNCS(waitpid)
 212
 213 AC_ARG_VAR([RSH], [Configure absolute path to default remote shell binary])
 214 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 215   [if test -n "$RSH"; then
 216     tar_cv_path_RSH=$RSH
 217   else
 218     tar_cv_path_RSH=no
 219     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 220         /usr/bin/nsh /usr/bin/rcmd
 221     do
 222       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 223       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 224       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 225       if test -f $ac_file; then
 226         if (test -h $ac_file) 2>/dev/null; then
 227           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 228         else
 229           tar_cv_path_RSH=$ac_file
 230           break
 231         fi
 232       fi
 233     done
 234   fi])
 235 if test $tar_cv_path_RSH = no; then
 236   AC_CHECK_HEADERS(netdb.h)
 237 else
 238   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 239     [Define to the full path of your rsh, if any.])
 240 fi
 241
 242 TAR_COMPR_PROGRAM(compress)
 243 TAR_COMPR_PROGRAM(gzip)
 244 TAR_COMPR_PROGRAM(bzip2)
 245 TAR_COMPR_PROGRAM(lzip)
 246 TAR_COMPR_PROGRAM(lzma)
 247 TAR_COMPR_PROGRAM(lzop)
 248 TAR_COMPR_PROGRAM(xz)
 249
 250 AC_MSG_CHECKING(for default archive format)
 251
 252 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 253            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 254
 255 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 256   DEFAULT_ARCHIVE_FORMAT="GNU"
 257 fi
 258 case $DEFAULT_ARCHIVE_FORMAT in
 259   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 260   *) AC_MSG_ERROR(Invalid format name);;
 261 esac
 262 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 263   [By default produce archives of this format])
 264 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 265
 266 AC_MSG_CHECKING(for default archive)
 267
 268 AC_ARG_VAR([DEFAULT_ARCHIVE],
 269            [Set the name of the default archive (default: -)])
 270 if test -z "$DEFAULT_ARCHIVE"; then
 271   DEFAULT_ARCHIVE=-
 272 else
 273   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 274     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 275   fi
 276   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 277   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 278   # FIXME: Rearrange, here.
 279   case $DEFAULT_ARCHIVE in
 280     *[[0-7][lmh]])
 281       AC_DEFINE(DENSITY_LETTER, 1,
 282         [Define to 1 if density may be indicated by [lmh] at end of device.])
 283       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 284       ;;
 285     *[[0-7]])
 286       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 287       ;;
 288     *)
 289       device_prefix=
 290       ;;
 291   esac
 292   case "$device_prefix" in
 293     ?*)
 294       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 295         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 296       ;;
 297   esac
 298 fi
 299 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 300   [Define to a string giving the full name of the default archive file.])
 301 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 302
 303 AC_ARG_VAR([DEFAULT_BLOCKING],
 304            [Define default blocking factor (default: 20)])
 305 AC_MSG_CHECKING(for default blocking)
 306 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 307 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 308   [Define to a number giving the default blocking size for archives.])
 309 AC_MSG_RESULT($DEFAULT_BLOCKING)
 310
 311 AC_MSG_CHECKING(for default quoting style)
 312
 313 m4_define([QUOTING_STYLES],dnl
 314           [literal|shell|shell-always|c|escape|locale|clocale])
 315 DEFAULT_QUOTING_STYLE="escape"
 316 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 317            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 318
 319 case $DEFAULT_QUOTING_STYLE in
 320 QUOTING_STYLES) ;;
 321 *)  AC_MSG_ERROR(Invalid quoting style);;
 322 esac
 323 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 324 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 325 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 326   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 327
 328 # Iconv
 329 AM_ICONV
 330 AC_CHECK_HEADERS(iconv.h)
 331 AC_CHECK_TYPE(iconv_t,:,
 332               AC_DEFINE(iconv_t, int,
 333                         [Conversion descriptor type]),
 334               [
 335 #ifdef HAVE_ICONV_H
 336 # include <iconv.h>
 337 #endif
 338 ])
 339
 340 # Gettext.
 341 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 342 AM_GNU_GETTEXT_VERSION([0.16])
 343
 344 # Initialize the test suite.
 345 AC_CONFIG_TESTDIR(tests)
 346 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 347 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 348
 349 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 350 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 351 AC_ARG_ENABLE(backup-scripts,
 352               AC_HELP_STRING([--enable-backup-scripts],
 353                              [Create and install backup and restore scripts]),
 354               [case $enableval in
 355                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 356                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 357                     ;;
 358                esac])
 359
 360 AC_SUBST(BACKUP_SED_COND)
 361 if date +%Y-%m-%d 2>/dev/null >&2; then
 362         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 363 else
 364         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 365 fi
 366
 367 AC_OUTPUT([Makefile\
 368            doc/Makefile\
 369            gnu/Makefile\
 370            lib/Makefile\
 371            po/Makefile.in\
 372            scripts/Makefile\
 373            rmt/Makefile\
 374            src/Makefile])