git.gag.com Git - debian/gnuradio/blob - config/usrp_libusb.m4

   1 dnl Copyright 2003,2008,2009 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 # $1 is $req_libusb1:
  21 #   yes : check libusb-1.0
  22 #   no  : check libusb-0.12
  23 #   ""  : check libusb-0.12
  24
  25
  26 AC_DEFUN([USRP_LIBUSB], [
  27   dnl Use PKGCONFIG to check for packages first, then check to
  28   dnl make sure the USB_* variables work (whether from PKGCONFIG
  29   dnl or overridden by the user)
  30
  31   libusbok=no
  32   have_libusb1=no
  33   if test x$1 = xyes; then
  34     PKG_CHECK_MODULES(USB, libusb-1.0, [
  35       libusbok=yes
  36       have_libusb1=yes
  37       usb_header='libusb-1.0/libusb.h'
  38       usb_lib_func='libusb_bulk_transfer'
  39       usb_lib_name='usb-1.0'
  40     ])
  41   else
  42     dnl not using libusb1 (for now); see if legacy version is found.
  43     dnl it might be installed under the name either 'libusb' or
  44     dnl 'libusb-legacy', or just available via the
  45     dnl user's shell environment
  46
  47     dnl see if the pkgconfig module 'libusb' is available
  48     PKG_CHECK_MODULES(USB, libusb, [libusbok=yes], [libusbok=no])
  49     dnl PKG_CHECK_MODULES does not work correctly when embedded
  50     if test $libusbok = no; then
  51       dnl if not, see if the pkgconfig module 'libusb-legacy' is available
  52       PKG_CHECK_MODULES(USB, [libusb-legacy], [libusbok=yes], [libusbok=no])
  53     fi
  54     dnl set variables for further testing
  55     usb_header='usb.h'
  56     usb_lib_func='usb_bulk_write'
  57     usb_lib_name='usb'
  58   fi
  59   if test x$1 != xyes || test $have_libusb1 = yes; then
  60     dnl Either (1) libusb1 was specified and found; or
  61     dnl (2) libusb1 was not specified.
  62
  63     dnl Verify that $usb_header is a valid header, and if so,
  64     dnl then verify that $usb_lib_func can be found in the
  65     dnl library $usb_lib_name.
  66
  67     dnl If PKGCONFIG found variable USB_INCLUDEDIR, and it is
  68     dnl not empty, use it for checking for $usb_header.
  69     dnl Otherwise, maybe the user's shell environment is already
  70     dnl configured to find this header.
  71
  72     AC_LANG_PUSH(C)
  73     save_CPPFLAGS="$CPPFLAGS"
  74     if test x$USB_INCLUDEDIR != x; then
  75       USB_INCLUDES="-I$USB_INCLUDEDIR"
  76       CPPFLAGS="$CPPFLAGS $USB_INCLUDES"
  77       AC_SUBST(USB_INCLUDES)
  78     fi
  79     AC_CHECK_HEADERS([$usb_header], [], [libusbok=no])
  80     CPPFLAGS="$save_CPPFLAGS"
  81     AC_LANG_POP(C)
  82
  83     if test $libusbok = no; then
  84       AC_MSG_RESULT([USRP requires libusb header '$usb_header' which was not found or was not usable. See http://www.libusb.org])
  85     else
  86
  87       dnl found the header; now make sure the library is OK
  88       dnl On Darwin, need to include the IOKit library.
  89
  90       AC_LANG_PUSH(C)
  91       save_LIBS="$LIBS"
  92       case "$host_os" in
  93         darwin*)
  94           USB_LIBS="$USB_LIBS -lIOKit"
  95           ;;
  96         *) ;;
  97       esac
  98       LIBS="$LIBS $USB_LIBS"
  99       AC_CHECK_LIB([$usb_lib_name], [$usb_lib_func], [], [
 100         libusbok=no
 101         AC_MSG_RESULT([USRP requires library '$usb_lib_name' with function '$usb_lib_func', which was either not found or was not usable. See http://www.libusb.org])
 102       ])
 103       LIBS="$save_LIBS"
 104       AC_LANG_POP(C)
 105     fi
 106   fi
 107   if test $libusbok = yes; then
 108     AC_SUBST(USB_LIBS)
 109     ifelse([$2], , :, [$2])
 110   else
 111     USB_INCLUDES=
 112     USB_LIBS=
 113     ifelse([$3], , :, [$3])
 114   fi
 115 ])