git.gag.com Git - debian/gnuradio/blob - config/usrp_libusb.m4

   1 dnl Copyright 2003,2008,2009 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 # $1 is $req_libusb1:
  21 #   yes : check libusb-1.0
  22 #   no  : check libusb-0.12
  23 #   ""  : check libusb-0.12
  24
  25
  26 AC_DEFUN([USRP_LIBUSB], [
  27   dnl Use PKGCONFIG to check for packages first, then check to
  28   dnl make sure the USB_* variables work (whether from PKGCONFIG
  29   dnl or overridden by the user)
  30
  31   dnl do not use LDFLAGS, since PKGCONFIG will provide everything
  32   saved_LDFLAGS=${LDFLAGS}
  33   LDFLAGS=
  34   LIBUSB_PKG_CONFIG_NAME=
  35
  36   dnl loop over various possible 'libusb' PKGCONFIG names, and choose
  37   dnl the first one that meets both the user's selection (via
  38   dnl configure flags) as well as what is installed
  39
  40   dnl create the list of libusb PKGCONFIG modules to test
  41   libusb_list=''
  42   if test x$1 = xyes; then
  43     dnl libusb-1.0 was requested; just test for it
  44     libusb_list="libusb-1.0"
  45   else
  46     dnl test for legacy libusb only
  47     libusb_list="libusb libusb-legacy"
  48   fi
  49   for libusb_name in ${libusb_list}; do
  50     dnl clear internal variables
  51     libusbok=no
  52     have_libusb1=no
  53     usb_header=''
  54     usb_lib_func=''
  55     usb_lib_name=''
  56
  57     dnl start checks
  58     AC_MSG_NOTICE([Checking for LIBUSB version '${libusb_name}'])
  59     if test ${libusb_name} = "libusb-1.0"; then
  60       dnl see if the pkgconfig module is available
  61       PKG_CHECK_MODULES(USB, ${libusb_name}, [
  62         libusbok=yes
  63         have_libusb1=yes
  64         usb_header='libusb-1.0/libusb.h'
  65         usb_lib_func='libusb_bulk_transfer'
  66       ], [libusbok=no])
  67     else
  68       dnl see if the pkgconfig module is available
  69       PKG_CHECK_MODULES(USB, ${libusb_name}, [
  70         libusbok=yes
  71         usb_header='usb.h'
  72         usb_lib_func='usb_bulk_write'
  73       ], [libusbok=no])
  74     fi
  75     if test $libusbok = yes; then
  76       dnl PKGCONFIG found a version of LIBUSB.
  77       dnl Check it to make sure it meets enough criteria:
  78       dnl Verify that $usb_header is a valid header. If so, then
  79       dnl verify that $usb_lib_func can be found in the library
  80       dnl $usb_lib_name.  if so, verify that the symbol 'usb_debug' is
  81       dnl found in the library.
  82
  83       dnl Check for the header.  Similar to AC_CHECK_HEADERS,
  84       dnl but doesn't append to known \#defines.
  85       dnl If PKGCONFIG found variable USB_INCLUDEDIR, and it is
  86       dnl not empty, use it for checking for $usb_header.
  87       dnl Otherwise, maybe the user's shell environment is already
  88       dnl configured to find this header.
  89       AC_LANG_PUSH(C)
  90       save_CPPFLAGS="$CPPFLAGS"
  91       if test x$USB_INCLUDEDIR != x; then
  92         USB_INCLUDES="-I$USB_INCLUDEDIR"
  93         CPPFLAGS="$USB_INCLUDES"
  94       fi
  95       AC_MSG_CHECKING([$libusb_name for header $usb_header])
  96       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  97         #include "$usb_header"
  98         ]], [])],
  99         [libusbok=yes],[libusbok=no])
 100       AC_MSG_RESULT([$libusbok])
 101       CPPFLAGS="$save_CPPFLAGS"
 102       AC_LANG_POP(C)
 103
 104       if test $libusbok = yes; then
 105         dnl found the header; now make sure the library is OK
 106         dnl On Darwin, need to include the IOKit library.
 107
 108         AC_LANG_PUSH(C)
 109         save_LIBS="$LIBS"
 110         case "$host_os" in
 111           darwin*)
 112             USB_LIBS="$USB_LIBS -lIOKit"
 113             ;;
 114           *) ;;
 115         esac
 116         LIBS="$USB_LIBS"
 117
 118         dnl find the library link name
 119         usb_lib_name=`echo $USB_LIBS | sed -e "s@.*-l\(usb[[^ ]]*\).*@\1@"`
 120
 121         dnl Check for the function in the library.  Similar to
 122         dnl AC_CHECK_LIB, but doesn't append to known \#defines.
 123         AC_MSG_CHECKING([$libusb_name for function $usb_lib_func in library $usb_lib_name])
 124         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 125           #ifdef __cplusplus
 126           extern "C"
 127           #endif
 128           char $usb_lib_func ();
 129           ]], [[return $usb_lib_func ();]])],
 130           [libusbok=yes],[libusbok=no])
 131         AC_MSG_RESULT([$libusbok])
 132         case "$host_os" in
 133           cygwin* | mingw*)
 134             USB_LIBS="$LIBS"
 135             ;;
 136           *) ;;
 137         esac
 138         LIBS="$save_LIBS"
 139         AC_LANG_POP(C)
 140
 141         if test $libusbok = yes; then
 142           if test ${libusb_name} != "libusb-1.0"; then
 143             dnl PKGCONFIG found a legacy version of libusb; make sure the
 144             dnl variable _usb_debug is available in the found library
 145             AC_LANG_PUSH(C)
 146             save_CPPFLAGS="$CPPFLAGS"
 147             CPPFLAGS="$USB_INCLUDES"
 148             save_LIBS="$LIBS"
 149             LIBS="$USB_LIBS"
 150             AC_MSG_CHECKING([$libusb_name for symbol usb_debug in library $usb_lib_name])
 151             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 152               extern int usb_debug;]],
 153               [[usb_debug = 0;]])],
 154               [libusbok=yes],[libusbok=no])
 155             AC_MSG_RESULT([$libusbok])
 156             LIBS="$save_LIBS"
 157             CPPFLAGS="$save_CPPFLAGS"
 158             AC_LANG_POP(C)
 159           fi
 160         fi
 161       fi
 162     fi
 163     dnl if everything checks out OK, finish up
 164     if test $libusbok = yes; then
 165       LIBUSB_PKG_CONFIG_NAME="${libusb_name}"
 166       break
 167     else
 168       dnl something wasn't found in this LIBUSB version.
 169       dnl HACK: clear cache variables for header and library
 170       unset USB_INCLUDEDIR
 171       unset USB_INCLUDES
 172       unset USB_LIBS
 173       unset $as_ac_Header
 174       unset $as_ac_Lib
 175     fi
 176   done
 177
 178   if test $libusbok = yes; then
 179     dnl final error checking, mostly to create #define's
 180     AC_LANG_PUSH(C)
 181     save_CPPFLAGS="$CPPFLAGS"
 182     CPPFLAGS="$USB_INCLUDES"
 183     dnl Check for the header.
 184     AC_CHECK_HEADERS([$usb_header], [], [libusbok=no])
 185     CPPFLAGS="$save_CPPFLAGS"
 186     AC_LANG_POP(C)
 187
 188     if test $libusbok = no; then
 189       AC_MSG_RESULT([USRP requires libusb header '$usb_header' which was not found or was not usable. See http://www.libusb.org])
 190     else
 191       dnl check for the library (again)
 192       AC_LANG_PUSH(C)
 193       save_CPPFLAGS="$CPPFLAGS"
 194       CPPFLAGS="$USB_INCLUDES"
 195       save_LIBS="$LIBS"
 196       LIBS="$USB_LIBS"
 197       AC_CHECK_LIB([$usb_lib_name], [$usb_lib_func], [], [
 198         libusbok=no
 199         AC_MSG_RESULT([USRP requires library '$usb_lib_name' with function '$usb_lib_func', which was either not found or was not usable. See http://www.libusb.org])])
 200       LIBS="$save_LIBS"
 201       CPPFLAGS="$save_CPPFLAGS"
 202       AC_LANG_POP(C)
 203     fi
 204   fi
 205
 206   if test $libusbok = yes; then
 207     dnl success
 208     AC_MSG_NOTICE([Using LIBUSB version '${libusb_name}'])
 209     ifelse([$2], , :, [$2])
 210   else
 211     dnl not found; clear substitution variables
 212     LIBUSB_PKG_CONFIG_NAME=
 213     USB_INCLUDES=
 214     USB_LIBS=
 215     ifelse([$3], , :, [$3])
 216   fi
 217
 218   dnl create substitution variables
 219   AC_SUBST(USB_INCLUDES)
 220   AC_SUBST(USB_LIBS)
 221   AC_SUBST(LIBUSB_PKG_CONFIG_NAME)
 222
 223   dnl restore LDFLAGS
 224   LDFLAGS=${saved_LDFLAGS}
 225 ])