git.gag.com Git - debian/gnuradio/blob - config/usrp_fusb_tech.m4

   1 dnl
   2 dnl Copyright 2003,2008 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GNU Radio
   5 dnl
   6 dnl GNU Radio is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3, or (at your option)
   9 dnl any later version.
  10 dnl
  11 dnl GNU Radio is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with GNU Radio; see the file COPYING.  If not, write to
  18 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  19 dnl Boston, MA 02110-1301, USA.
  20 dnl
  21
  22 # $1 is $enable_usrp:
  23 #   yes : do these tests
  24 #   no  : do not do these tests
  25 #   ""  : do these tests
  26
  27 AC_DEFUN([USRP_SET_FUSB_TECHNIQUE],[
  28   req_libusb1=no
  29   AC_ARG_WITH([fusb-tech],
  30               AC_HELP_STRING([--with-fusb-tech=OS],
  31                              [Set fast USB technique (default=auto)]),
  32               [cf_with_fusb_tech="$withval"],
  33               [cf_with_fusb_tech="$host_os"])
  34   if test [x]$1 != xno; then
  35       case "$cf_with_fusb_tech" in
  36         libusb1*)
  37           FUSB_TECH=libusb1
  38           req_libusb1=yes
  39           ;;
  40         linux*)
  41           AC_CHECK_HEADER([linux/usbdevice_fs.h],
  42                           [x_have_usbdevice_fs_h=yes],
  43                           [x_have_usbdevice_fs_h=no])
  44           if test x${x_have_usbdevice_fs_h} = xyes; then
  45               FUSB_TECH=linux
  46           else
  47               FUSB_TECH=generic
  48           fi
  49           ;;
  50         darwin*)
  51           FUSB_TECH=darwin
  52           ;;
  53         cygwin*|win*|mingw*)
  54           FUSB_TECH=win32
  55           ;;
  56         *bsd*)
  57           AC_MSG_CHECKING([for RA/WB])
  58           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <dev/usb/usb.h>]],
  59                                              [[struct usb_bulk_ra_wb_opt o;
  60                                                ioctl(0, USB_SET_BULK_RA, &o);]])],
  61                             [FUSB_TECH=ra_wb],
  62                             [FUSB_TECH=generic])
  63           ;;
  64         *)
  65           FUSB_TECH=generic
  66           ;;
  67       esac
  68
  69       AC_MSG_CHECKING([for fast usb technique to use])
  70       AC_MSG_RESULT($FUSB_TECH)
  71       AC_SUBST(FUSB_TECH)
  72   fi
  73
  74   AM_CONDITIONAL(FUSB_TECH_darwin,   test x$FUSB_TECH = xdarwin)
  75   AM_CONDITIONAL(FUSB_TECH_win32,    test x$FUSB_TECH = xwin32)
  76   AM_CONDITIONAL(FUSB_TECH_generic,  test x$FUSB_TECH = xgeneric)
  77   AM_CONDITIONAL(FUSB_TECH_linux,    test x$FUSB_TECH = xlinux)
  78   AM_CONDITIONAL(FUSB_TECH_libusb1,  test x$FUSB_TECH = xlibusb1)
  79   AM_CONDITIONAL(FUSB_TECH_ra_wb,    test x$FUSB_TECH = xra_wb)
  80 ])