git.gag.com Git - debian/gnuradio/blob - config/grc_gr_qtgui.m4

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_DEFUN([GRC_GR_QTGUI],[
  21     GRC_ENABLE(gr-qtgui)
  22
  23     dnl Don't do gr-qtgui if gnuradio-core skipped
  24     GRC_CHECK_DEPENDENCY(gr-qtgui, gnuradio-core)
  25
  26     dnl If execution gets to here, $passed will be:
  27     dnl   with : if the --with code didn't error out
  28     dnl   yes  : if the --enable code passed muster and all dependencies are met
  29     dnl   no   : otherwise
  30
  31
  32 # Check for:
  33 #       QtOpenGL
  34 #       QtGui
  35 #       QtCore
  36 #       qwt
  37 #       qwtplot3d
  38 #       qt4
  39
  40 # qt4-core, qt4-gui, qwt5-qt4, qwt5-qt4-dev, libqwtplot3d-qt4, libqwtplot3d-qt4-dev, qt4-dev-tools
  41
  42     if test $passed = yes; then
  43         dnl Check for package qt or qt-mt, set QT_CFLAGS and QT_LIBS
  44         PKG_CHECK_MODULES(QTCORE, QtCore >= 4.2, [],
  45             [passed=no; AC_MSG_RESULT([gr-qtgui requires libQtCore >= 4.2.])])
  46         PKG_CHECK_MODULES(QTGUI, QtGui >= 4.2, [],
  47             [passed=no; AC_MSG_RESULT([gr-qtgui requires libQtGui >= 4.2.])])
  48         PKG_CHECK_MODULES(QTOPENGL, QtOpenGL >= 4.2, [],
  49             [passed=no; AC_MSG_RESULT([gr-qtgui requires libQtOpenGL >- 4.2.])])
  50
  51         dnl Fetch QWT variables
  52         GR_QWT([], [passed=no])
  53
  54         dnl Process QWT Plot3D only if QWT passed
  55         if test "$passed" = "yes"; then
  56             GR_QWTPLOT3D([], [passed=no])
  57         fi
  58
  59         dnl Export the include dirs and libraries (note: QTOPENGL_LIBS includes links
  60         dnl to QtCore and QtGui libraries)
  61         QT_INCLUDES="$QWT_CFLAGS $QWTPLOT3D_CFLAGS $QTCORE_CFLAGS $QTGUI_CFLAGS"
  62         QT_LIBS="$QWT_LIBS $QWTPLOT3D_LIBS $QTOPENGL_LIBS"
  63
  64         dnl Build an includes variable specifically for running qmake by extracting
  65         dnl all includes from the QWT and QWTPLOT3D, without the -I;
  66         dnl qmake appends the -I when processing the project file INCLUDEPATH
  67         for i in $QWT_CFLAGS $QWTPLOT3D_CFLAGS; do
  68             QMAKE_INCLUDES="$QMAKE_INCLUDES ${i##-I}"
  69         done
  70
  71         QT_MOC_EXEC=`pkg-config --variable=moc_location QtCore`
  72         QT_UIC_EXEC=`pkg-config --variable=uic_location QtCore`
  73
  74         AC_SUBST(QMAKE_INCLUDES)
  75         AC_SUBST(QT_INCLUDES)
  76         AC_SUBST(QT_LIBS)
  77         AC_SUBST(QT_MOC_EXEC)
  78         AC_SUBST(QT_UIC_EXEC)
  79     fi
  80
  81     if test "$passed" = "no"; then
  82         AM_CONDITIONAL(BUILD_QT, false)
  83     else
  84         AM_CONDITIONAL(BUILD_QT, true)
  85     fi
  86
  87     AC_CONFIG_FILES([ \
  88         gr-qtgui/Makefile \
  89         gr-qtgui/src/Makefile \
  90         gr-qtgui/src/lib/Makefile \
  91         gr-qtgui/src/python/Makefile \
  92     ])
  93
  94     GRC_BUILD_CONDITIONAL(gr-qtgui)
  95 ])