git.gag.com Git - debian/gnuradio/blob - config/grc_gr_qtgui.m4

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_DEFUN([GRC_GR_QTGUI],[
  21     GRC_ENABLE(gr-qtgui)
  22
  23     dnl Don't do gr-qtgui if gnuradio-core skipped
  24     GRC_CHECK_DEPENDENCY(gr-qtgui, gnuradio-core)
  25
  26     dnl If execution gets to here, $passed will be:
  27     dnl   with : if the --with code didn't error out
  28     dnl   yes  : if the --enable code passed muster and all dependencies are met
  29     dnl   no   : otherwise
  30
  31     PYTHON_CHECK_MODULE([PyQt4.QtCore], [PyQt4 for Qt4], \
  32         [passed=yes], [passed=no], \
  33         [PyQt4.QtCore.PYQT_VERSION >= 260000])
  34
  35     # Enable this if we want to test for PyQwt, too
  36     #PYTHON_CHECK_MODULE([PyQt4.Qwt5], [PyQwt5 for Qt4], \
  37     #   [passed=yes], [passed=no], \
  38     #   [PyQt4.Qwt5.QWT_VERSION >= 327000])
  39
  40 # Check for:
  41 #       QtOpenGL
  42 #       QtGui
  43 #       QtCore
  44 #       qwt
  45 #       qt4
  46
  47 # qt4-core, qt4-gui, qwt5-qt4, qwt5-qt4-dev, qt4-dev-tools
  48
  49     if test $passed = yes; then
  50         dnl Check for package qt or qt-mt, set QT_CFLAGS and QT_LIBS
  51         PKG_CHECK_MODULES(QTCORE, QtCore >= 4.2, [],
  52             [passed=no; AC_MSG_RESULT([gr-qtgui requires libQtCore >= 4.2.])])
  53         PKG_CHECK_MODULES(QTGUI, QtGui >= 4.2, [],
  54             [passed=no; AC_MSG_RESULT([gr-qtgui requires libQtGui >= 4.2.])])
  55         PKG_CHECK_MODULES(QTOPENGL, QtOpenGL >= 4.2, [],
  56             [passed=no; AC_MSG_RESULT([gr-qtgui requires libQtOpenGL >- 4.2.])])
  57
  58         dnl Fetch QWT variables
  59         GR_QWT([], [passed=no])
  60
  61         dnl Export the include dirs and libraries (note: QTOPENGL_LIBS includes links
  62         dnl to QtCore and QtGui libraries)
  63         QT_INCLUDES="$QWT_CFLAGS $QTCORE_CFLAGS $QTGUI_CFLAGS"
  64         QT_LIBS="$QWT_LIBS $QTOPENGL_LIBS"
  65
  66         dnl Build an includes variable specifically for running qmake by extracting
  67         dnl all includes from the QWT, without the -I;
  68         dnl qmake appends the -I when processing the project file INCLUDEPATH
  69         for i in $QWT_CFLAGS; do
  70             QMAKE_INCLUDES="$QMAKE_INCLUDES ${i##-I}"
  71         done
  72
  73         QT_MOC_EXEC=`pkg-config --variable=moc_location QtCore`
  74         QT_UIC_EXEC=`pkg-config --variable=uic_location QtCore`
  75
  76         AC_SUBST(QMAKE_INCLUDES)
  77         AC_SUBST(QT_INCLUDES)
  78         AC_SUBST(QT_LIBS)
  79         AC_SUBST(QT_MOC_EXEC)
  80         AC_SUBST(QT_UIC_EXEC)
  81     fi
  82
  83     AC_CONFIG_FILES([ \
  84         gr-qtgui/Makefile \
  85         gr-qtgui/src/Makefile \
  86         gr-qtgui/src/lib/Makefile \
  87         gr-qtgui/src/python/Makefile \
  88     ])
  89
  90     GRC_BUILD_CONDITIONAL(gr-qtgui)
  91 ])