git.gag.com Git - debian/gnuradio/blob - config/gr_set_md_cpu.m4

   1 dnl
   2 dnl Copyright 2003,2008,2009 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GNU Radio
   5 dnl
   6 dnl GNU Radio is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3, or (at your option)
   9 dnl any later version.
  10 dnl
  11 dnl GNU Radio is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with GNU Radio; see the file COPYING.  If not, write to
  18 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  19 dnl Boston, MA 02110-1301, USA.
  20 dnl
  21
  22 AC_DEFUN([_TRY_ADD_ALTIVEC],
  23 [
  24   LF_CHECK_CC_FLAG([-mabi=altivec -maltivec])
  25   LF_CHECK_CXX_FLAG([-mabi=altivec -maltivec])
  26 ])
  27
  28 AC_DEFUN([_FIND_ARM_ISA],
  29 [
  30   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
  31   [[#ifndef __ARM_ARCH_5__
  32     #error "Not armv5"
  33     #endif
  34   ]])],
  35     [is_armv5=yes],
  36     [is_armv5=no])
  37
  38   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
  39   [[#ifndef __ARM_ARCH_7A__
  40     #error "Not armv7-a"
  41     #endif
  42   ]])],
  43     [is_armv7_a=yes],
  44     [is_armv7_a=no])
  45
  46 ])
  47
  48 AC_DEFUN([GR_SET_MD_CPU],[
  49   AC_REQUIRE([AC_CANONICAL_HOST])
  50   AC_ARG_WITH(md-cpu,
  51         AC_HELP_STRING([--with-md-cpu=ARCH],[set machine dependent speedups (auto)]),
  52                 [cf_with_md_cpu="$withval"],
  53                 [cf_with_md_cpu="$host_cpu"])
  54
  55   case "$cf_with_md_cpu" in
  56    x86 | i[[3-7]]86)    MD_CPU=x86      MD_SUBCPU=x86 ;;
  57    x86_64)              MD_CPU=x86      MD_SUBCPU=x86_64 ;;
  58    powerpc*)            MD_CPU=powerpc ;;
  59    arm)
  60        _FIND_ARM_ISA
  61        if test $is_armv5 = yes; then MD_CPU=armv5;
  62        elif test $is_armv7_a = yes; then MD_CPU=armv7_a;
  63        else MD_CPU=generic; fi
  64        ;;
  65    *)                   MD_CPU=generic ;;
  66   esac
  67
  68   AC_ARG_ENABLE(altivec,
  69     AC_HELP_STRING([--enable-altivec],[enable altivec on PowerPC (yes)]),
  70     [ if test $MD_CPU = powerpc; then
  71         case "$enableval" in
  72           (no)  MD_CPU=generic ;;
  73           (yes) _TRY_ADD_ALTIVEC ;;
  74           (*) AC_MSG_ERROR([Invalid argument ($enableval) to --enable-altivec]) ;;
  75         esac
  76       fi],
  77     [ if test $MD_CPU = powerpc; then _TRY_ADD_ALTIVEC fi])
  78
  79
  80   AC_MSG_CHECKING([for machine dependent speedups])
  81   AC_MSG_RESULT($MD_CPU)
  82   AC_SUBST(MD_CPU)
  83   AC_SUBST(MD_SUBCPU)
  84
  85   AM_CONDITIONAL(MD_CPU_x86,     test "$MD_CPU" = "x86")
  86   AM_CONDITIONAL(MD_SUBCPU_x86_64,  test "$MD_SUBCPU" = "x86_64")
  87   AM_CONDITIONAL(MD_CPU_powerpc, test "$MD_CPU" = "powerpc")
  88   AM_CONDITIONAL(MD_CPU_armv5, test "$MD_CPU" = "armv5")
  89   AM_CONDITIONAL(MD_CPU_armv7_a, test "$MD_CPU" = "armv7_a")
  90   AM_CONDITIONAL(MD_CPU_generic, test "$MD_CPU" = "generic")
  91 ])